Сравнение таблицы HDB - PullRequest
Новая
       7

Сравнение таблицы HDB

0 голосов
/ 24 апреля 2018

Размещение этого вопроса в Q & A-style .

Почему логическое совпадение двух идентичных таблиц (одна из которых выбрана из HDB) генерирует 0b, а не 1b? 

q)trade:trade2:`sym`time xasc ([] sym:5?`apple`google;time:5?.z.t;price:100+5?1.)

q).Q.dpft[`:tmp;.z.d-1;`sym;`trade]
`trade

Загрузить HDB 

\l tmp/
q)hist:select from trade where date=.z.d-1
q)hist
date       sym    time         price   
---------------------------------------
2018.04.23 apple  02:31:39.330 100.2392
2018.04.23 apple  04:25:17.604 100.1508
2018.04.23 apple  07:57:14.764 100.2782
2018.04.23 google 02:59:16.636 100.1567
2018.04.23 google 14:35:31.860 100.9785

q)(`date xcols update date:.z.d-1 from trade2)
date       sym    time         price   
---------------------------------------
2018.04.23 apple  02:31:39.330 100.2392
2018.04.23 apple  04:25:17.604 100.1508
2018.04.23 apple  07:57:14.764 100.2782
2018.04.23 google 02:59:16.636 100.1567
2018.04.23 google 14:35:31.860 100.9785

Сравнение таблиц создает ложь (0b) 

q)(`date xcols update date:.z.d-1 from trade2)~hist
0b

1 Ответ

0 голосов
/ 24 апреля 2018

Несоответствие связано с типом столбца sym (20h) таблицы, выбранной из HDB. 

\l tmp/
q)hist:select from trade where date=.z.d-1
q)type exec sym from hist
20h
q)type exec sym from trade2
11h
q)type exec value sym from hist
11h

Хотя он выглядит в точности как символ, но имеет новый тип 20h, что-то похожее на следующее (из Kx wiki) 

q)type `city$10?city:`london`paris`rome
21h

Использование value с sym для получения желаемого результата: 

q)(`date xcols update date:.z.d-1 from trade2)~update value sym from hist
1b
...