Отображение уникальных значений в xslt версии 1

Question

Может кто-нибудь помочь мне, плз, получить отдельные значения идентификатора атрибута в узле INDIC?

Объяснение:

Я использую версию xslt 1.

• Вот так выглядит мой xml:

  <Results><Result>
      <INDICS>
          <INDIC ID="I000207" LIB="A"/>
          <INDIC ID="I000208" LIB="B"/>
          <INDIC ID="I999999" LIB="C"/>
      </INDICS>
  </Result>
  <Result>
      <INDICS>
          <INDIC ID="I000207" LIB="A"/>
          <INDIC ID="I000208" LIB="B"/>
          <INDIC ID="I999999" LIB="C"/>
      </INDICS>
  </Result>
  

вот так выглядит мой шаблон, мой шаблон отображает все идентификаторы

     <xsl:template match="/">
<xsl:variable name="INDICS" select="//INDIC"/>
     <PRODUITS>
     <INDICS>
     <xsl:for-each select="//Results/Result/INDICS/INDIC/@ID">
     <INDIC ID= "{.}" LIB="{$INDICS[@ID=current()]/@LIB}" />
     </xsl:for-each>
     </INDICS>
     </PRODUITS>
     </xsl:template>

вывод, который я получаю:

<PRODUITS>
<INDICS>
<INDIC ID="I000207" LIB="A"/>
<INDIC ID="I000208" LIB="B"/>
<INDIC ID="I999999" LIB="C"/>
<INDIC ID="I000207" LIB="A"/>
<INDIC ID="I000208" LIB="B"/>
<INDIC ID="I999999" LIB="C"/>
 <INDICS/>
</PRODUITS>

вывод, который я пытаюсь получить:

<PRODUITS>
<INDICS>
<INDIC ID="I000207" LIB="A"/>
<INDIC ID="I000208" LIB="B"/>
<INDIC ID="I999999" LIB="C"/>
 <INDICS/>
</PRODUITS>

большое спасибо.

Answer 1

Другая возможность, используемая в связанных вопросах, - это использование xsl:key и функции generate-id(). Это вариант так называемого Muenchian Grouping.

<xsl:key name="values" match="INDIC" use="@ID"/>

<xsl:template match="/">
    <PRODUITS>
        <INDICS>
            <xsl:for-each select="//Results/Result/INDICS/INDIC[generate-id() = generate-id(key('values',@ID)[1])]">
                <INDIC ID= "{@ID}" LIB="{@LIB}" />
            </xsl:for-each>
        </INDICS>
    </PRODUITS>
</xsl:template>

Answer 2

Вы можете сделать это, надеюсь, этот код поможет вам решить вашу проблему:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="1.0">

    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <Results>
            <Result>
                <INDICS>
                    <xsl:for-each select="//INDIC">
                        <xsl:variable name="c-id" select="@ID"/>
                        <xsl:choose>
                            <xsl:when test="$c-id = ancestor::Result/following-sibling::Result/INDICS/INDIC/@ID"/>
                            <xsl:otherwise>
                                <INDIC ID= "{@ID}" LIB="{@LIB}" />
                            </xsl:otherwise>
                        </xsl:choose>
                    </xsl:for-each>
                </INDICS>
            </Result>
        </Results>
    </xsl:template>

</xsl:stylesheet>