Конкретное значение массива xslt - PullRequest
Новая
       10

Конкретное значение массива xslt

0 голосов
/ 25 июня 2018

Я хотел бы применить шаблон, в котором указанный элемент содержит значение массива с префиксом некоторой константы. 

<xsl:variable name="coreTables"
              select="('TAB1', 'TAB2')" />
<xsl:template match="node()[not(self::*)]">
    <xsl:copy>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*">
    <xsl:element name="{local-name()}">
        <xsl:apply-templates select="node()|@*"/>
    </xsl:element>
</xsl:template>

<xsl:template match="@*">
    <xsl:attribute name="{local-name()}">
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

<xsl:template match="databaseChangeLog">
    <xsl:comment> CORE TABLES </xsl:comment>
    <xsl:apply-templates select="changeSet[createTable/@tableName=$coreTables]"/>
    <xsl:comment> CORE SEQUENCES </xsl:comment>
    <xsl:apply-templates select="changeSet[createSequence/@sequenceName='SEQ_'[$coreTables]]"/>
</xsl:template>

это образец xml: 

<?xml version="1.1" encoding="UTF-8" standalone="no"?>
<databaseChangeLog xmlns="http://www.liquibase.org/xml/ns/dbchangelog"
                   xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
                   xsi:schemaLocation="http://www.liquibase.org/xml/ns/dbchangelog
                   http://www.liquibase.org/xml/ns/dbchangelog/dbchangelog-3.6.xsd
                   http://www.liquibase.org/xml/ns/dbchangelog">

    <changeSet id="1" author="a">
        <createTable tableName="TAB1">
            <column></column>
        </createTable>
    </changeSet>

    <changeSet id="1-1" author="a">
        <createSequence sequenceName="SEQ_TAB1" />
    </changeSet>
    <changeSet id="4" author="A">
        <createTable tableName="TAB4">
            <column></column>
        </createTable>
    </changeSet>
</databaseChangeLog>

То есть с последним apply-templates я бы хотел сопоставить все узлы createSequence, где атрибут sequenceName равен SEQ_ + value of some coreTables. Но я не знаю, как написать этот выбор, или если это возможно, как это.

Я использую xslt 2 и саксонский 9.8he.

1 Ответ

0 голосов
/ 25 июня 2018

Есть несколько способов сделать это. Вот пара ... 

<xsl:apply-templates 
     select="changeSet[createSequence/@sequenceName = (for $i in $coreTables return concat('SEQ_', $i))]"/>

<xsl:apply-templates 
     select="changeSet[createSequence[starts-with(@sequenceName, 'SEQ_') and substring-after(@sequenceName, 'SEQ_') = $coreTables]]"/>
...