Получение отдельных значений компонентов массива производного типа с помощью процедуры типа - PullRequest
Новая
       9

Получение отдельных значений компонентов массива производного типа с помощью процедуры типа

0 голосов
/ 26 апреля 2018

Моя IDE - это Code :: Blocks 17.2 с компилятором GFortran 6.3.1

Код: 

MODULE CLASS_BRANCHES

IMPLICIT NONE

  TYPE , PUBLIC :: TS_SHIR

    PRIVATE

      COMPLEX , ALLOCATABLE :: Y_BRA (:)

    CONTAINS

      PROCEDURE , PUBLIC :: CALCULATION_TS_SHIR => CALCULATION_DATA_TS_SHIR
!      PROCEDURE , PUBLIC :: TAKE_Y_BRA => TAKE_DATA_Y_BRA

  END TYPE TS_SHIR

  PRIVATE :: CALCULATION_DATA_TS_SHIR
!  PRIVATE :: TAKE_DATA_Y_BRA

CONTAINS

SUBROUTINE CALCULATION_DATA_TS_SHIR( THIS , N_BRA )

  IMPLICIT NONE

  CLASS ( TS_SHIR ) , INTENT( INOUT ) :: THIS
  INTEGER , INTENT ( IN ) :: N_BRA
  INTEGER :: I , ALLOC_ERR

  IF ( .NOT. ALLOCATED ( THIS%Y_BRA ) ) ALLOCATE ( THIS%Y_BRA ( N_BRA ) , STAT = ALLOC_ERR )

  IF ( ALLOC_ERR .NE. 0 ) STOP ("MEMORY ALLOCATION PROBLEM - THIS%Y_BRA!")

  DO I = 1 , N_BRA

     THIS%Y_BRA(I) = CMPLX ( 11 + I , 12 + I )

  END DO

RETURN
END SUBROUTINE CALCULATION_DATA_TS_SHIR

!FUNCTION TAKE_DATA_Y_BRA ( THIS ) RESULT ( DATA_Y_BR )
!
!    IMPLICIT NONE
!
!    CLASS ( TS_SHIR ) :: THIS
!    COMPLEX :: DATA_Y_BR
!
!    DATA_Y_BR = THIS%Y_BRA
!
!RETURN
!END FUNCTION TAKE_DATA_Y_BRA

END MODULE CLASS_BRANCHES

PROGRAM TYPE_ALLOCATABLE_ARRAY

USE , NON_INTRINSIC :: CLASS_BRANCHES

IMPLICIT NONE

INTEGER :: I , J
INTEGER , PARAMETER :: N_BRANCHES = 5 , N_CALCULATIONS = 6
CHARACTER( 250 ) , DIMENSION ( N_CALCULATIONS ) :: UN_NAME
CHARACTER(*) , PARAMETER :: UN_FMT = '("OUTPUT_",I2.2,".TXT")'  

CLASS ( TS_SHIR ) , POINTER :: P_BRA
TYPE ( TS_SHIR ) , DIMENSION ( N_CALCULATIONS ) , TARGET :: BRANCHES  

LOOP_00: DO I = 1 , N_CALCULATIONS

            P_BRA => BRANCHES(I)

            CALL P_BRA%CALCULATION_TS_SHIR( N_BRANCHES )

            WRITE( UN_NAME(I) , UN_FMT ) I

            OPEN ( 15 , FILE = UN_NAME(I) , STATUS = 'UNKNOWN' , ACTION = 'WRITE' )

              DO J = 1 , N_BRANCHES

                 WRITE( 15 , * ) J ! HOW TO WRITE VALUES OF Y_GRA( N_BRA ) WITH MEMBER FUNCTION OF TYPE TS_SHIR???

              END DO

            CLOSE ( 15 , STATUS = 'KEEP')

         END DO LOOP_00

END PROGRAM TYPE_ALLOCATABLE_ARRAY

Я очень новичок в объектно-ориентированном программировании на Фортране, поэтому мне нуженобъяснение получения значений Type приватный член (выделяемый массив) с помощью публичной процедуры TAKE_Y_BRA.Я поставил под комментарий тело функции TAKE_Y_BRA, потому что я получил его сообщение: Incompatible ranks 0 and 1 in assignment в строке, где находится эта команда: DATA_Y_BR = THIS%Y_BRA Есть ли какое-то решение для этого, или у меня совершенно неправильный подход для такого рода вычислений с производнымтипы?

1 Ответ

0 голосов
/ 26 апреля 2018

Либо вернуть весь массив 

FUNCTION TAKE_DATA_Y_BRA ( THIS ) RESULT ( DATA_Y_BR )
   CLASS ( TS_SHIR ) :: THIS
   COMPLEX :: DATA_Y_BR(SIZE(THIS%Y_BRA))

   DATA_Y_BR = THIS%Y_BRA
END FUNCTION TAKE_DATA_Y_BRA

Или вернуть один элемент по индексу J

FUNCTION TAKE_DATA_Y_BRA_J ( THIS, J ) RESULT ( DATA_Y_BR )
   CLASS ( TS_SHIR ) :: THIS
   INTEGER, INTENT(IN) :: J
   COMPLEX :: DATA_Y_BR

   DATA_Y_BR = THIS%Y_BRA(J)
END FUNCTION TAKE_DATA_Y_BRA_J

Обратите внимание, что вам не нужны implicit none и return. Будьте лаконичны. Ваш код трудно читать! Используйте маленькие заглавные буквы для лучшей читаемости.

...