Есть ли способ экспортировать весь ноутбук в разные части - PullRequest
Новая
       13

Есть ли способ экспортировать весь ноутбук в разные части

0 голосов
/ 04 января 2019

Я ищу возможность экспортировать один блокнот evernote в разные части, например:

Notebook = Eingang (2000Notes)

Экспорт в возможно

  • Eingang1.enex (500Notes)
  • Eingang2.enex (500 нот)
  • Eingang3.enex (500Notes)
  • Eingang3.enex (500Notes)

Поскольку обработка (т. Е. Импорт в Onenote) часто дает сбой, потому что в файлах ENEX слишком много или слишком много заметок. Может быть, есть какой-то сценарий или что-то еще, что будет работать. Только ручной экспорт не является правильным способом, потому что у меня есть записные книжки с записью 14k +. Я надеюсь, что мое намерение становится ясным. Спасибо заранее за вашу помощь.

1 Ответ

0 голосов
/ 04 января 2019

Если вы работаете на Mac, в словаре AppleScript Evernote есть глагол export, с помощью которого вы можете создать инструмент. Вот несколько не элегантный, но функциональный AppleScript, который сделает то, что вам нужно, просто отредактировав размер пакета, имя записной книжки и путь, по которому вы хотите получить файлы ENEX: 

tell application "Evernote"
    # Set batch size, notebook to export, and destination path
    set batchSize to 500
    set theNotebookName to "MyNotebook"
    set theExportFolder to "/tmp"

    # Enumerate the notes into batches and export them
    set theNotebook to the first notebook whose name is theNotebookName
    set theNotes to the notes in theNotebook
    set currentBatchIndex to 0
    set currentNoteIndex to 1
    repeat until currentNoteIndex = (count of theNotes)
        # Collect up to batchSize notes
        set thisExportBatch to {}
        repeat until ((count of thisExportBatch) = batchSize or (currentNoteIndex = (count of theNotes)))
            set currentItem to theNotes's item currentNoteIndex
            set thisExportBatch to thisExportBatch & {currentItem}
            set currentNoteIndex to currentNoteIndex + 1
        end repeat
        # Export this batch. Set the destination path to where you want them.
        set exportPath to (theExportFolder & "/" & theNotebookName & currentBatchIndex & ".enex")
        export thisExportBatch to exportPath
        set currentBatchIndex to (currentBatchIndex + 1)
    end repeat
end tell

Я не уверен, что эквивалент будет в Windows, но я ожидаю, что есть какой-то эквивалентный способ его автоматизации.

...