Power BI - добавление / вычитание рабочего времени с помощью DAX - PullRequest
Новая
       12

Power BI - добавление / вычитание рабочего времени с помощью DAX

0 голосов
/ 08 января 2019

У меня есть две таблицы.

Календарь Таблица 

Date       Holiday
1/1/2019   Yes
1/2/2019   No
1/3/2019   No
1/4/2019   Yes
1/5/2019   No
1/6/2019   Yes
1/7/2019   No
.
.

Таблица данных 

 Request #   CreatedDateTime           ClosedDateTime
    A1          1/2/2019 7:15:00 AM    1/4/2019 7:15:00 AM
    A2          1/2/2019 5:15:00 AM    1/5/2019 7:15:00 AM
    A3          1/1/2019 7:45:00 AM    1/6/2019 7:15:00 AM

Рабочие часы с 7 утра до 6 вечера

Если запрос создается в нерабочее время, то билет переносится на следующий доступный рабочий час. В таблице «Календарь» указаны рабочие и нерабочие дни.

CreatedDateTime_Updated дает ожидаемый результат. 

Request #   CreatedDateTime          CreatedDateTime_Updated
A1          1/2/2019 7:15:00 AM      1/2/2019 7:15:00 AM
A2          1/2/2019 5:15:00 AM      1/2/2019 7:00:00 AM
A3          1/1/2019 7:45:00 AM      1/2/2019 7:00:00 AM

Теперь я пытаюсь добавить 33 рабочих часа в этот столбец CreatedDateTime_Updated и вызвать его как DueDateTime 

Request #   CreatedDateTime_Updated  DueDateTime
A1          1/2/2019 7:15:00 AM      1/7/2019 7:15:00 AM 
A2          1/2/2019 7:00:00 AM      1/5/2019 6:00:00 PM
A3          1/2/2019 7:00:00 AM      1/5/2019 6:00:00 PM

Подобно преобразованию столбца CreateDateTime, ClosedDateTime также необходимо преобразовать. но к предыдущему рабочему часу, если он закрыт в нерабочее время. 

Request #   ClosedDateTime             ClosedDateTime_Updated
    A1      1/4/2019 7:15:00 AM        1/3/2019 6:00:00 PM  
    A2      1/5/2019 7:15:00 AM        1/5/2019 7:15:00 AM
    A3      1/6/2019 7:15:00 AM        1/5/2019 6:00:00 AM

Пожалуйста, объясните это в единичных шагах, чтобы при необходимости можно было изменить формулу.

Спасибо.

1 Ответ

0 голосов
/ 08 января 2019

Сначала создайте пару вычисляемых столбцов в вашей календарной таблице: 

WorkHours = IF('Calendar'[Holiday] = "Yes", 0, 11)

и 

CumulativeHours =
CALCULATE(
    SUM('Calendar'[WorkHours]),
    ALL('Calendar'),
    'Calendar'[Date] <= EARLIER('Calendar'[Date])
)

Я использовал расчетный столбец CreatedDateTime_Updated

CreatedDateTime_Updated =
VAR NextWorkDay =
    CALCULATE (
        MIN ( 'Calendar'[Date] ),
        FILTER ( 'Calendar', 'Calendar'[Date] >= Data[CreatedDateTime].[Date] ),
        'Calendar'[Holiday] = "No"
    )
RETURN
    IF (
        HOUR ( Data[CreatedDateTime] ) < 7
            || NextWorkDay > Data[CreatedDateTime].[Date],
        NextWorkDay + TIME ( 7, 0, 0 ),
        Data[CreatedDateTime]
    )

для создания столбца DueDateTime: 

DueDateTime =
VAR CurrentCumulative =
    LOOKUPVALUE (
        'Calendar'[CumulativeHours],
        'Calendar'[Date], Data[CreatedDateTime_Updated].[Date] - 1
    )
VAR HoursIntoDay =
    ROUND (
           24 * ( Data[CreatedDateTime_Updated] - Data[CreatedDateTime_Updated].[Date] )
            - 7,
        2
    )
VAR DueDate =
    CALCULATE (
        MIN ( 'Calendar'[Date] ),
        FILTER (
            'Calendar',
            'Calendar'[CumulativeHours] >= CurrentCumulative + HoursIntoDay + 33
        )
    )
RETURN
    IF ( HoursIntoDay > 0, DueDate + ( 7 + HoursIntoDay ) / 24, DueDate + 18 / 24 )

Я постараюсь объяснить детали, когда у меня будет время.

...