XSLT 1.0 для каждого, если вывод - PullRequest
Новая
       10

XSLT 1.0 для каждого, если вывод

0 голосов
/ 06 ноября 2018

Я знаю, что xslt 1.0 был сделан до смерти, однако, я потратил значительное время на поиск ответа на мою проблему. Я видел следующие вопросы:

XSLT для каждого вывода таблицы циклов XSLT 1.0 Группировать по

Я стараюсь учить себя как можно лучше, но время уходит от меня, и мне нужно, чтобы все заработало.

В любом случае, я реализовал то, что считал решением, и понял, что некоторые из моих XML имеют дублированные имена для каждого и, следовательно, вывод перемещается в следующий столбец. Мне нужно, чтобы Visio был в столбце Visio (или заголовке таблицы), а Project - в столбце Project и т. Д.

Вот мой пример XML 

    <?xml version="1.0" standalone="yes"?>
<Root>
<v_Add_Remove_Programs>
        <ResourceID>12345678</ResourceID>
        <GroupID>5</GroupID>
        <ProdID0>Office14.PRJSTD</ProdID0>
        <DisplayName0>Microsoft Project Standard 2010</DisplayName0>
        <InstallDate0></InstallDate0>
        <Publisher0>Microsoft Corporation</Publisher0>
        <Version0>14.0.7015.1000</Version0>
    </v_Add_Remove_Programs>
    <v_Add_Remove_Programs>
        <ResourceID>12345678</ResourceID>
        <GroupID>152</GroupID>
        <ProdID0>{90140000-003A-0000-0000-0000000FF1CE}</ProdID0>
        <DisplayName0>Microsoft Office Project Standard 2010</DisplayName0>
        <InstallDate0>20180219</InstallDate0>
        <Publisher0>Microsoft Corporation</Publisher0>
        <Version0>14.0.7015.1000</Version0>
    </v_Add_Remove_Programs>
    <v_Add_Remove_Programs>
        <ResourceID>12345678</ResourceID>
        <GroupID>330</GroupID>
        <ProdID0>Office15.VISSTD</ProdID0>
        <DisplayName0>Microsoft Visio Standard 2013</DisplayName0>
        <InstallDate0></InstallDate0>
        <Publisher0>Microsoft Corporation</Publisher0>
        <Version0>15.0.4569.1506</Version0>
    </v_Add_Remove_Programs>
    <v_Add_Remove_Programs>
        <ResourceID>12345678</ResourceID>
        <GroupID>331</GroupID>
        <ProdID0>{90150000-0053-0000-0000-0000000FF1CE}</ProdID0>
        <DisplayName0>Microsoft Visio Standard 2013</DisplayName0>
        <InstallDate0>20171225</InstallDate0>
        <Publisher0>Microsoft Corporation</Publisher0>
        <Version0>15.0.4569.1506</Version0>
    </v_Add_Remove_Programs>
    <v_Add_Remove_Programs>
        <ResourceID>12345678</ResourceID>
        <GroupID>4</GroupID>
        <ProdID0>Office14.PRJSTD</ProdID0>
        <DisplayName0>Microsoft Project Standard 2010</DisplayName0>
        <InstallDate0></InstallDate0>
        <Publisher0>Microsoft Corporation</Publisher0>
        <Version0>14.0.7015.1000</Version0>
    </v_Add_Remove_Programs>
</Root>

Вот мой XSLT 

    <?xml version = "1.0" encoding = "UTF-8"?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:template match="/">
      <html>
         <body>
            <h2>Add Remove Software</h2>
            <table border="1">
               <tr bgcolor="#9acd32">
                  <th>Visio</th>
                  <th>Project</th>
               </tr>
               <xsl:for-each select="//v_Add_Remove_Programs">
                  <xsl:variable name="DispName" select="DisplayName0" />
                  <xsl:if test="contains($DispName, 'Visio Standard') or 
            contains($DispName, 'Visio Professional')">
                     <td>
                        <xsl:value-of select="$DispName"/>
                     </td>
                  </xsl:if>
                  <xsl:if test="contains($DispName, 'Project Standard')">
                     <td>
                        <xsl:value-of select="$DispName"/>
                     </td>
                  </xsl:if>
               </xsl:for-each>
            </table>
         </body>
      </html>
   </xsl:template>
</xsl:stylesheet>

Это вывод, который я желаю.

ID ресурса | Visio | Проект
12345678 | Microsoft Visio Standard 2013 | Microsoft Project Standard 2013

Большое спасибо заранее, действительно ценю это.

Ответы [ 2 ]

0 голосов
/ 06 ноября 2018

Похоже, вы хотите сгруппировать по ResourceID. В этом случае прочтите Muenchian Grouping . В этом случае вы определяете свой ключ следующим образом: 

<xsl:key name="resources" match="v_Add_Remove_Programs" use="ResourceID" />

И чтобы получить отдельные ResourceID элементы, которые представляют ваши строки, сделайте это ... 

<xsl:for-each select="v_Add_Remove_Programs[generate-id() = generate-id(key('resources', ResourceID)[1])]">

Но у вас есть дополнительное усложнение, так как похоже, что вам также необходимо получить отдельные программы в каждом ресурсе. Итак, вам нужно выполнить вторую группировку с помощью этого ключа ... 

<xsl:key name="resourceNames" match="v_Add_Remove_Programs" use="concat(ResourceID, '|', DisplayName0)" />

И чтобы получить отдельные программы для определенного типа, сделайте это .. 

<xsl:for-each select="key('resources', ResourceID)
    [generate-id() = generate-id(key('resourceNames', concat(ResourceID, '|', DisplayName0))[1])] 
    [starts-with(DisplayName0, $type)]">

Попробуйте этот XSLT, который вы можете увидеть в действии на http://xsltfiddle.liberty -development.net / 6qVRKxa 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="html" indent="yes" html-version="5"/>

  <xsl:key name="resources" match="v_Add_Remove_Programs" use="ResourceID" />
  <xsl:key name="resourceNames" match="v_Add_Remove_Programs" use="concat(ResourceID, '|', DisplayName0)" />

  <xsl:template match="Root">
    <table>
      <tr>
        <th>Resource ID</th>
        <th>Visio</th>
        <th>Project</th>
      </tr>
      <xsl:for-each select="v_Add_Remove_Programs[generate-id() = generate-id(key('resources', ResourceID)[1])]">
        <tr>
          <td>
            <xsl:value-of select="ResourceID" />
          </td>
          <td>
            <xsl:call-template name="resourceList">
              <xsl:with-param name="type" select="'Microsoft Visio'" />
            </xsl:call-template>
          </td>
          <td>
            <xsl:call-template name="resourceList">
              <xsl:with-param name="type" select="'Microsoft Project'" />
            </xsl:call-template>
          </td>
        </tr>
      </xsl:for-each>
    </table>
  </xsl:template>

  <xsl:template name="resourceList">
    <xsl:param name="type" />
    <xsl:for-each select="key('resources', ResourceID)
        [generate-id() = generate-id(key('resourceNames', concat(ResourceID, '|', DisplayName0))[1])] 
        [starts-with(DisplayName0, $type)]">
      <xsl:value-of select="DisplayName0" />
      <br />
    </xsl:for-each>    
  </xsl:template>
</xsl:stylesheet>
0 голосов
/ 06 ноября 2018

Я предполагаю, что вы хотите сделать что-то вроде:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/Root">
    <html>
        <body>
            <h2>Add Remove Software</h2>
            <table border="1">
                <tr bgcolor="#9acd32">
                    <th>Visio</th>
                    <th>Project</th>
                </tr>
                <xsl:for-each select="v_Add_Remove_Programs">
                    <tr>
                        <td>
                            <xsl:value-of select="DisplayName0[contains(., 'Visio Standard') or 
            contains(., 'Visio Professional')]"/>
                        </td>
                        <td>
                            <xsl:value-of select="DisplayName0[contains(., 'Project Standard')]"/>
                        </td>
                    </tr>
                </xsl:for-each>
            </table>
        </body>
    </html>
</xsl:template>

</xsl:stylesheet>

Учитывая ваш пример ввода, (обработанный) вывод будет:

enter image description here

...