Как использовать переменную в шаблоне соответствия xslt - PullRequest
Новая
       55

Как использовать переменную в шаблоне соответствия xslt

0 голосов
/ 21 марта 2020

Мне нужно использовать переменную в сопоставлении шаблона в xslt, но я преобразовал сопоставление шаблона в переменную. Я получил синтаксическую ошибку.

Это мой оригинальный xslt 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
<xsl:template match="/name/name[not(telephoneNav/detail/action = 'A') and not(telephoneNav/detail/action = 'S')]"/>
<xsl:template match="detail[not(action = 'A') and not(action = 'S')]"/>
</xsl:stylesheet>

Это мой xslt, который был преобразован в переменную в шаблонном совпадении. 

 <?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        version="1.0">
      <xsl:variable name="actionXpath1" select="'/name/name[not(telephoneNav/detail/action = &apos;A&apos;) and not(telephoneNav/detail/action = &apos;S&apos;)]'" />
      <xsl:variable name="actionXpath2" select="'detail[not(action = &apos;A&apos;) and not(action = &apos;S&apos;)]'" />
      <xsl:template match="@* | node()">
        <xsl:copy>
          <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
      </xsl:template>
      <xsl:template match="$actionXpath1"/>
      <xsl:template match="$actionXpath2"/>
    </xsl:stylesheet>

вот так https://xsltfiddle.liberty-development.net/3MvmXiw

1 Ответ

1 голос
/ 21 марта 2020

В XSLT 3 с использованием статических c параметров и _match в качестве атрибута тени вы можете использовать 

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0">
  <xsl:param name="actionXpath1" static="yes" select="'/name/name[not(telephoneNav/detail/action = &quot;A&quot;) and not(telephoneNav/detail/action = &quot;S&quot;)]'" />
  <xsl:param name="actionXpath2" static="yes" select="'detail[not(action = &quot;A&quot;) and not(action = &quot;S&quot;)]'" />
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template _match="{$actionXpath1}"/>
  <xsl:template _match="{$actionXpath2}"/>
</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/3MvmXiw/1

Так что вам нужно использовать процессор XSLT 3, и вам нужно использовать его таким образом, чтобы можно было задавать параметры stati c, т.е. использовать API, специализированный для XSLT 3, для поддержки установки таких параметров перед компиляцией таблицы стилей.

...