Qt: Как получить снимок QQuickItem, исключив его дочерний QQuickItems из полученного результата - PullRequest
Новая
       34

Qt: Как получить снимок QQuickItem, исключив его дочерний QQuickItems из полученного результата

0 голосов
/ 05 июля 2018

Мой вопрос является продолжением этой дискуссии .

Да . Следующий способ grabToImage может дать мне снимок любого конкретного QQuickItem, как parent_rect ниже. 

Rectangle {
    id: parent_rect
    width: 400
    height: 400

    Rectangle {
        id: child_rect1
        width: parent.width/4
        height: parent.height/4
    }

    Rectangle {
        id: child_rect2
        width: parent.width/4
        height: parent.height/4
    }
}
// ...
parent_rect.grabToImage(function(result) {
                       result.saveToFile("something.png");
                   });

Проблема:
Но этот grabToImage дает мне снимок всех его потомков, а именно child_rect1 и child_rect2.

Вопрос:
Как получить снимок parent_rect только без добавления дочерних элементов в возвращаемый результат?

1 Ответ

0 голосов
/ 05 июля 2018

Одно из возможных решений - спрятать детей, а затем восстановить видимость.

Пример: 

import QtQuick 2.9
import QtQuick.Window 2.2

Window {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    function grabWithoutChildren(item, filename){
        var isVisibleList = []
        var i
        for(i in item.children){
            isVisibleList[i] = item.children[i].visible
            item.children[i].visible = false
        }

        item.grabToImage(function(result) {
            result.saveToFile(filename)
            for(i in item.children){
                 item.children[i].visible = isVisibleList[i]
            }
        })
    }

    Rectangle {
        id: parent_rect
        width: 400
        height: 400
        color: "red"

        Rectangle {
            id: child_rect1
            width: parent.width/4
            height: parent.height/4
            color: "blue"
        }

        Rectangle {
            id: child_rect2
            x: 10
            y: 10
            width: parent.width/4
            height: parent.height/4
            color: "green"

            Rectangle{
                x:50
                y:50
                width: 100
                height: 100
                color: "white"
            }
        }
    }

    Component.onCompleted: grabWithoutChildren(parent_rect, "something.png")
}
...