Случайные числа VBA производят повторяющуюся последовательность через равные промежутки времени - PullRequest
Новая
       19

Случайные числа VBA производят повторяющуюся последовательность через равные промежутки времени

0 голосов
/ 04 сентября 2018

Этот код должен генерировать последовательность из 10 000 случайных чисел в VBA. По какой-то причине я могу создать только уникальную последовательность длиной 5842, а затем она повторяется. Но, и это самая странная часть, каждый раз, когда я запускаю код, последовательность начинается в другом месте. Например, в одном прогоне элементы, следующие за элементом 2660, являются такими же, как элементы, следующие за элементом 8502 (8502-2660 = 5842). При следующем запуске я получаю последовательность, которая повторяет следующие элементы 3704 и 9546 (9546-3704 = 5842). И так далее. 

Function NormRand() As Double
' NormRand returns a randomly distributed drawing from a
' standard normal distribution i.e. one with:
' Average = 0 and Standard Deviation = 1.0
Dim fac As Double, rsq As Double, v1 As Double, v2 As Double
Static flag As Boolean, gset As Double

' Each pass through the calculation of the routine produces
'  two normally-distributed deviates, so we only need to do
'  the calculations every other call. So we set the flag
'  variable (to true) if gset contains a spare NormRand value.
If flag Then
    NormRand = gset
    ' Force calculation next time.
    flag = False
Else
    ' Don't have anything saved so need to find a pair of values
    ' First generate a co-ordinate pair within the unit circle:
    Do
        v1 = 2 * Rnd - 1#
        v2 = 2 * Rnd - 1#
        rsq = v1 * v1 + v2 * v2
    Loop Until rsq <= 1#

    ' Do the Math:
    fac = Sqr(-2# * Log(rsq) / rsq)

    ' Return one of the values and save the other (gset) for next time:
    NormRand = v2 * fac
    gset = v1 * fac
    flag = True
End If

End Function

1 Ответ

0 голосов
/ 04 сентября 2018

По какой-то причине я могу создать только уникальную последовательность длины 5842, а затем повторяется. Но, и это самая странная часть, каждый Когда я запускаю код, последовательность начинается в другом месте

Это разработано и хорошо известно - вот почему генерация чисел помечена псевдослучайно , а не случайно.

Кстати, я заметил, что вы умножаете два значения. Это может быть не очень хорошая идея - как уже упоминалось здесь .

В вашей функции вы можете попробовать заменить Rnd на RndDbl: 

Public Function RndDbl(Optional ByRef Number As Single) As Double

    ' Exponent to shift the significant digits of a single to
    ' the least significant digits of a double.
    Const Exponent  As Long = 7

    Dim Value       As Double

    ' Generate two values like:
    '   0.1851513
    '   0.000000072890967130661
    ' and add these.
    Value = CDbl(Rnd(Number)) + CDbl(Rnd(Number) * 10 ^ -Exponent)

    RndDbl = Value

End Function

, а затем измените код, включив динамическое начальное число, вызвав Timer: 

Do
    v1 = 2 * RndDbl(-Timer) - 1#
    v2 = 2 * RndDbl(-Timer) - 1#
    rsq = v1 + v2
Loop Until rsq <= 1#

Сгенерированные значения все еще не будут истинно случайными, но не должны принимать форму повторяющейся последовательности.

...