Пользовательская цель CMake не создается - PullRequest
Новая
       29

Пользовательская цель CMake не создается

0 голосов
/ 06 мая 2018

Я строю две цели, используя: 

add_library(tgt1 SHARED a.cpp)
add_library(tgt2 SHARED b.cpp)

После того, как оба построены, мне нужно выполнить шаг после сборки, который зависит от обеих целей. Я пробовал много комбинаций из следующего, но безуспешно: 

add_custom_target(final_tgt DEPENDS tgt1 tgt2)
add_custom_command(TARGET final_tgt POST_BUILD COMMAND <command> ARGS <args>)

Конечная цель просто не будет собрана, даже если ее build.make содержит пользовательскую команду.

Пытался использовать ВСЕ для пользовательской цели, однако попытайтесь сначала создать ее, пропустив первые цели.

И я не могу использовать add_library или add_executable для конечной цели, поскольку они требуют указания исходных файлов.

Как правильно это сделать?

===================================

Редактировать: ниже приведен минимальный проверяемый исходный код. Он пытается скомпилировать код (для Mac) в двух архитектурах и в качестве пост-сборки создать универсальный двоичный файл с использованием lipo: 

cmake_minimum_required(VERSION 2.8)
set(icpc_req_path "/usr/local/bin/icpc-16.0.146")

set(CMAKE_CXX_COMPILER "${icpc_req_path}")

project("CMakeTest")
set(SOURCE_FILES a.cpp)

set (TARGET_NAME "TGT")
set(TARGETS "")
set(ARCHITECTURES i386 x86_64)

foreach(ar ${ARCHITECTURES})
    set(CMAKE_CXX_FLAGS_RELEASE "")
    set(CMAKE_CXX_FLAGS_DEBUG "")
    set(CMAKE_CXX_FLAGS "")

    add_library(TGT_${ar} SHARED ${SOURCE_FILES})
    set_target_properties(${TARGET_NAME}_${ar}
        PROPERTIES COMPILE_FLAGS "-arch ${ar} -xSSE3")
    set_target_properties(${TARGET_NAME}_${ar}
        PROPERTIES LINK_FLAGS "-arch ${ar}")
    set(TARGETS "${TARGETS};lib${TARGET_NAME}_${ar}.dylib")
endforeach(ar)

message("Targets: ${TARGETS}")
add_custom_target(${TARGET_NAME} DEPENDS ${TARGETS})
add_custom_command(TARGET ${TARGET_NAME} POST_BUILD
     COMMAND "lipo"
     ARGS "-create" ${TARGETS} "-output" "${TARGET_NAME}.dylib")

А содержимое a.cpp: 

int main(){}

Ответы [ 2 ]

0 голосов
/ 07 мая 2018

У меня работает следующий пример.

Две цели, независимые друг от друга. Одна настраиваемая цель в зависимости от обоих. 

add_library(Big SHARED ${SOURCES_BIG})
add_library(Foo SHARED ${SOURCES_FOO})

add_custom_target(pack ALL
    COMMAND ${CMAKE_COMMAND} -E md5sum ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_SHARED_LIBRARY_PREFIX}Big${CMAKE_SHARED_LIBRARY_SUFFIX}
    COMMAND ${CMAKE_COMMAND} -E md5sum ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_SHARED_LIBRARY_PREFIX}Foo${CMAKE_SHARED_LIBRARY_SUFFIX}
    DEPENDS Big Foo
    COMMENT Build target pack
)

Примечание. Вычисление хэша кода просто показывает, перестраиваются ли цели при изменениях.

0 голосов
/ 07 мая 2018

add_custom_command поставляется в двух вариантах: создание новых выходных данных и воздействие на отдельные цели. Docs

Какую команду вы вызываете? Это каким-либо образом дает результаты (новые файлы и т. Д.)? Если это так, используйте add_custom_command вот так: 

add_custom_command(
  OUTPUT <output-file>
  DEPENDS tgt1 tgt2
  COMMAND <command>
  ARGS <args>
  COMMENT "Running  <command> on targets tgt1 and tgt2."
)

При использовании второго варианта add_custom_command, который не имеет аргумента OUTPUT, поскольку он изменяет <target> как шаг POST_BUILD (или предварительная сборка, предварительная ссылка), требуется одна цель. Итак, какой из tgt1 и tgt2 будет изменен вашим <command>?

Предположим, что tgt1 изменяется на шаге POST_BUILD, а tgt2 остается без изменений. Тогда вы можете сделать это так: 

add_library(tgt2 SHARED b.cpp)

add_library(tgt1 SHARED a.cpp)
add_custom_command(
  TARGET tgt1 POST_BUILD
  COMMAND <command>
  ARGS <args>
)
add_dependencies(tgt1 tgt2) # tgt1 depends on tgt2 because
# POST_BUILD-step is just the final step to build 'tgt1'
# NOTE: It is incorrect to modify 'tgt2' as POST_BUILD step for tgt1.
#       So this example expects no changes to tgt2 in add_custom_command.

- РЕДАКТИРОВАТЬ после более подробной информации, указанной в вопросе:

Рабочий пример

CMakeLists.txt 

# I don't have 'icpc' and could not find it easily available for macOS.
# Instead, let's create a file "TGT" where contents are the two hashes of the two
# libraries, like done in 'Th.Thielemann's answer.
cmake_minimum_required(VERSION 3.10)
project(q50198141)

add_library(Big SHARED library1.cpp)
add_library(Foo SHARED library2.cpp)

add_custom_command(OUTPUT combined
    COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/combine.sh
    ARGS $<TARGET_FILE:Big> $<TARGET_FILE:Foo> combined
    DEPENDS Big Foo combine.sh
    COMMENT Build output 'combined'
)
add_custom_target(run_combined ALL DEPENDS combined)

combined.sh (Убедитесь, что вы исключительный!) 

#!/bin/bash

# Hardcoded for q50198141    
# Args: In1 In2 Out
md5sum $1 $2 > $3
...