Узел смешанного контента XSLT

Question

У меня довольно глупый вопрос. Как я могу убедиться, что мой XML-узел со смешанным содержимым не перепутан? У меня есть, скажем, структура XML, похожая на это.

<root>
 <book>
  <title>Stuff</title>
  <description> This book is <i>great</i> if you need to know about stuff.
                I suggest <link ref="Things">this one</link> if you need to know
                about things. </description>
 </book>
 [other books]
</root> 

Мне нужно, чтобы конечный контент выглядел следующим образом

<h1>List of books</h1>
<h2><a name="Stuff"/>Stuff</h2>
<p> This book is <i>great</i> if you need to know about stuff.
    I suggest <a href="#Things">this one</a> if you need to know
    about things. </p>

Но я не могу извлечь части текстового узла, я всегда хватаю все это. Я использую ось потомка. Любая подсказка, что я делаю не так?

Вот мой xslt:

<xsl:template match="description/*">
    <xsl:for-each select="following-sibling::*">
            <xsl:choose>
            <xsl:when test="name(.)='link'">
                <a href="{@ref}"><xsl:value-of select="."/></a>
            </xsl:when>
            <xsl:when test="name(.)='em'">
                <em><xsl:value-of select="."/></em>
            </xsl:when>
            <xsl:otherwise><p><xsl:value-of select="."/></p></xsl:otherwise>    
        </xsl:choose>
    </xsl:for-each>
  </xsl:template>

Обратите внимание, что вложенный XML и полученный HTML являются лишь примерами, для ясности мне приходится иметь дело с большей структурой, в которую я не заключаю.

Answer 1

<xsl:apply-templates> ваш друг:

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:output method="html" />

  <xsl:template match="root">
    <h1>List of books</h1>
    <xsl:apply-templates />
  </xsl:template>

  <!-- a <book> consists of its <title> and <description> -->
  <xsl:template match="book">
    <xsl:apply-templates select="title" />
    <xsl:apply-templates select="description" />
  </xsl:template>

  <!-- <title> is turned into a <h2> -->
  <xsl:template match="title">
    <h2>
      <a name="{.}"/>
      <xsl:value-of select="." />
    </h2>
  </xsl:template>

  <!-- <description> is turned into a <p> -->
  <xsl:template match="description">
    <p>
      <xsl:apply-templates />
    </p>
  </xsl:template>

  <!-- default rule: copy any node beneath <description> -->
  <xsl:template match="description//*">
    <xsl:copy>
      <xsl:copy-of select="@*" />
      <xsl:apply-templates />
    </xsl:copy>
  </xsl:template>

  <!-- override rule: <link> nodes get special treatment -->
  <xsl:template match="description//link">
    <a href="#{@ref}">
      <xsl:apply-templates />
    </a>
  </xsl:template>

  <!-- default rule: ignore any unspecific text node -->
  <xsl:template match="text()" />

  <!-- override rule: copy any text node beneath description -->
  <xsl:template match="description//text()">
    <xsl:copy-of select="." />
  </xsl:template>

</xsl:stylesheet>

Следующие выходные данные генерируются для вашего входного XML ( Примечание: я передал его через приборку для удобства чтения. В процессе был удален нерелевантный пробел ):

<h1>List of books</h1>
<h2><a name="Stuff">Stuff</h2>
<p>This book is <i>great</i> if you need to know about stuff. I
suggest <a href="#Things">this one</a> if you need to know about
things.</p>

Answer 2

<root>
 <book>
  <title>Stuff</title>
  <description><![CDATA[
      This book is <i>great</i> if you need to know about stuff.
      I suggest <link ref="Things">this one</link> if you need to know
      about things.
  ]]></description>
 </book>
 [other books]
</root>