Изменить непрозрачность в HSB Colormode - PullRequest
Новая
       70

Изменить непрозрачность в HSB Colormode

0 голосов
/ 12 ноября 2018

Я пытаюсь изменить непрозрачность своих мазков, но не уверен, как это сделать в цветном режиме HSB. Или, если я переключусь в режим RGB, как я могу изменить цвет с течением времени?

Вот мой код: (Любая помощь будет оценена) 

float rainbow=0;
int dir=1;

void setup() {
  size(600, 600);
  background(0);
  colorMode(HSB, 255);
 } 

void draw() {
  if ( rainbow < 255 && dir==1) {
     rainbow++;
  }

  if ( rainbow > 0 && dir==-1) {
    rainbow--;
  }

  if ( rainbow == 255) {
    dir*= -1;
  }

  if ( rainbow == 0) {
    dir*= -1;
  }

  stroke(rainbow, 255, 200);
  line(mouseX,mouseY,width/2,height/2); 

  if (mousePressed){
  stroke(rainbow, 255, 200);
  line(mouseX,mouseY,0,mouseX);
  }

  if (mousePressed){
  stroke(rainbow, 100, 200);
  line(mouseX,mouseY,600,mouseX);
  }
}

1 Ответ

0 голосов
/ 12 ноября 2018

Вы можете дать функциям stroke() или fill() четвертый параметр для непрозрачности. Вот простой пример: 

void setup(){
  size(500, 500);
  colorMode(HSB, 255);
  background(255);
}

void draw(){
  fill(0, 255, 200, 100);
  ellipse(mouseX, mouseY, 20, 20);
}

Обратите внимание, что вы также можете использовать режим RGB и со временем изменять аргументы R, G и B. Это будет немного сложнее, чем циклическое переключение значений HSB, но вы можете создать любой шаблон, который захотите. Вот простой пример: 

float r = 0;
float g = 0;
float b = 0;

float deltaR = 1;
float deltaG = 2;
float deltaB = 4;

void setup(){
  size(500, 500);
  background(255);
}

void draw(){

  r += deltaR;
  g += deltaG;
  b += deltaB;

  if(r < 0 || r > 255){
    deltaR *= -1;
    r = constrain(r, 0, 255);
  }

  if(g < 0 || g > 255){
   deltaG *= -1;
   g = constrain(g, 0, 255);
  }

  if(b < 0 || b > 255){
    deltaB *= -1;
    b = constrain(b, 0, 255);
  }

  fill(r, g, b);
  ellipse(mouseX, mouseY, 20, 20);
}
...