SAS: создать график с логарифмическим соотношением - PullRequest
Новая
       27

SAS: создать график с логарифмическим соотношением

0 голосов
/ 19 января 2019


У меня есть две переменные: цена и карат. Для регрессии я решил, что я должен взять журнал обеих переменных. Теперь я пытаюсь построить график цены в каратах с кривой, которая показывает логарифмическую зависимость. Как я могу создать такой график в SAS? Спасибо.

Я попробовал следующий код, но у меня нет ничего для смещения, потому что у меня нет ничего для смещения. Тем не менее, я не могу получить 95% доверительные интервалы без них. 

 proc genmod data=diamonds; 
 model Price = Carat / dist=poisson link=log; 
 effectplot / clm moff; 
 run;

1 Ответ

0 голосов
/ 19 января 2019

Я не эксперт GenMod, но, возможно, более простой SGPLOT преобразований журнала будет работать.

В этом примере кода показаны графики для линейного и логарифмического преобразований. 

data prices; * https://www.creditdonkey.com/diamond-prices.html;
input carat price; 
logcarat = log(carat);
logprice = log(price);
datalines;
0.4 890
0.5 1520
0.75 2940
1 5810
1.5 10610
2 19520
run;

title "SGPLOT scatter with linear axes";
proc sgplot data=prices;
  scatter x=carat y=price;
run; 

title "SGPLOT Scatter with log axes";
proc sgplot data=prices;
  scatter x=carat y=price;
  xaxis type=log;
  yaxis type=log;
run; 

title "SGPLOT Linear Regression";
proc sgplot data=prices;
  reg x=carat y=price / CLM CLI;
run; 

title "SGPLOT Linear Regression of Log of variables";
proc sgplot data=prices;
  reg x=logcarat y=logprice / CLM CLI;
run; 

title "GenMod Effect Plot";
proc genmod data=prices;
  model price=carat;
  effectplot / clm; 
run;

title "GenMod Carat=Price (Poisson)";
proc genmod data=prices;
  model price=carat / dist=poisson;
  effectplot / clm; 
run;

title;

Example Plots

...