Преобразование первой строчной буквы в заглавную, а остальные буквы в нижнем регистре с двумя разделителями - PullRequest
Новая
       15

Преобразование первой строчной буквы в заглавную, а остальные буквы в нижнем регистре с двумя разделителями

0 голосов
/ 20 января 2019

Я начал изучать XSLT, немного застрял при написании функций xslt для преобразования из нижнего регистра в верхний и верхний регистр в нижний регистр в xslt

Я много пробовал, написав разныеxslt работает, но я думаю, что некоторые, где я делаю ошибку в моем коде 

<xsl:template name="ConvertXmlStyleToCamelCase">

    <xsl:param name="occupation"/>

    <xsl:template match="node()"/>
    <xsl:variable name="uppercase" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'" />
    <xsl:variable name="lowercase" select="'abcdefghijklmnopqrstuvwxyz'" />

    <xsl:param name="delimiter" select='/'/>
    <xsl:param name="delimiter2" select= "' '"/>

    <xsl:if test="not($occupation = '')" >
        <xsl:choose>
            <xsl:when test="contains($occupation, $delimiter)">
                <xsl:variable name="word" select="substring-before(concat($occupation, $delimiter), $delimiter)"></xsl:variable>
                <xsl:if test="$word">
                    <xsl:value-of select="translate(substring($word, 1, 1), $lowercase, $uppercase)"/>
                    <xsl:value-of select="translate(substring($word,2), $uppercase, $lowercase)"/>
                </xsl:if>
            </xsl:when>


            <xsl:when test="contains( $occupation, $delimiter)">
                <xsl:value-of select="$delimiter"/>
                <!-- Recursive call to template to translate the text after delimeter -->
                <xsl:call-template name="ConvertXmlStyleToCamelCase">
                        <xsl:with-param name="occupation"  select="substring-after($occupation, $delimiter)"/>
                </xsl:call-template>
            </xsl:when>

            <xsl:when test="contains($occupation, $delimiter2)">
                <xsl:variable name="word2" select="substring-before(concat($occupation, $delimiter2), $delimiter2)"></xsl:variable>
                <xsl:if test="$word2">
                    <xsl:value-of select="translate(substring($word2, 1, 1), $lowercase, $uppercase)"></xsl:value-of>
                    <xsl:value-of select="translate(substring($word2, 2), $uppercase, $lowercase)"/>
                </xsl:if>
            </xsl:when>

            <xsl:when test="contains($occupation, $delimiter2)">
                <xsl:value-of select="$delimiter2"/>
                <!-- Recursive call to template to translate the text after delimeter2 -->
                <xsl:call-template name="ConvertXmlStyleToCamelCase">
                    <xsl:with-param name="occupation"  select="substring-after($occupation, $delimiter2)"/>
                </xsl:call-template>
            </xsl:when>
        </xsl:choose>
    </xsl:if>

    <xsl:if test="not($occupation = $delimiter and $delimiter2)">
        <xsl:value-of select="substring(occupation, 1, 1)"/>
        <xsl:value-of select="translate(substring(occupation, 2), $uppercase, $lowercase)"/>
    </xsl:if>

</xsl:template>

, будут иметь любое значение из следующих значений

1.SELF / EMPLOYED 2.SKILL TRADE 3.ПРАВИТЕЛЬСТВО

Ожидаемый результат, как показано ниже

  1. Самостоятельно / Занято
  2. Торговля умениями
  3. Правительство

Но фактическоерезультат

  1. Самостоятельная занятость
  2. Навыки / торговля
  3. Правительство

Ответы [ 2 ]

0 голосов
/ 21 января 2019

Не могли бы вы иметь более двух разделителей в будущем?Если это так, попробуйте этот XSLT, который можно легко расширить, чтобы иметь больше разделителей (одного символа).Просто измените параметры delimiters в шаблоне ConvertXmlStyleToCamelCase. 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="item">
        <item>
            <xsl:call-template name="ConvertXmlStyleToCamelCase" />
        </item>
    </xsl:template>

    <xsl:template name="ConvertXmlStyleToCamelCase">
        <xsl:param name="text" select="."/>
        <xsl:param name="delimiters" select="' /'"/>

        <xsl:variable name="upper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
        <xsl:variable name="lower" select="'abcdefghijklmnopqrstuvwxyz'"/>
        <xsl:variable name="nextDelimiter" select="substring(translate($text, translate($text, $delimiters, ''), ''), 1, 1)" />
        <xsl:variable name="string" select="substring-before(concat($text, ' '), substring(concat($nextDelimiter, ' '), 1, 1))" />

        <xsl:message terminate="no">Next delimiter is <xsl:value-of select="$nextDelimiter" /></xsl:message>

        <xsl:value-of select="translate(substring($string, 1, 1), $lower, $upper)"/>
        <xsl:value-of select="translate(substring($string, 2), $upper, $lower)"/>

        <xsl:if test="$nextDelimiter">
            <xsl:value-of select="$nextDelimiter" />
            <xsl:call-template name="ConvertXmlStyleToCamelCase">
                <xsl:with-param name="text" select="substring-after($text, $nextDelimiter)"/>
                <xsl:with-param name="delimiters" select="$delimiters"/>  
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

См. Его в действии на http://xsltfiddle.liberty -development.net / gWvjQeR , где я использовал третий разделительв качестве примера.

Применительно к двойному переводу цель этого - найти следующий разделитель в строке.Для этого (в XSLT 1.0) вам необходимо удалить все символы, которые не являются разделителями.Выполнение translate($text, $delimiters, '') удаляет все разделители и возвращает все символы, которые не являются разделителями.Если вы затем примените этот результат к исходной строке, у вас останутся только разделители.Первый символ будет следующим разделителем.

0 голосов
/ 20 января 2019

Как я уже упоминал в комментарии, ваш код не воспроизводится.Из результатов, о которых вы сообщаете, становится ясно, что ваш второй разделитель не применяется.AFAICT, это потому, что вы сначала проверяете наличие 1-го разделителя - и если вы его обнаружите, вы не потрудитесь проверить, существует ли 2-й разделитель до 1-го.

Рассмотрим следующий пример (адаптированный из Преобразование первой буквы строки в заглавную в xslt ):

XML 

<input>
    <item>Self/Employed</item>
    <item>Skill Trade</item>
    <item>Government</item>
    <item>a combi/na/tion of various de/limi/ters</item>
</input>

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/input">
    <output>
        <xsl:for-each select="item">
            <caps>
                <xsl:call-template name="capitalize">
                    <xsl:with-param name="text" select="."/>
                </xsl:call-template>
            </caps>
        </xsl:for-each>
    </output>
</xsl:template>

<xsl:template name="capitalize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="' '"/>

    <xsl:variable name="upper-case" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
    <xsl:variable name="lower-case" select="'abcdefghijklmnopqrstuvwxyz'"/>

    <xsl:variable name="word" select="substring-before(concat($text, $delimiter), $delimiter)" />
    <xsl:choose>
        <xsl:when test="$delimiter=' '">
            <!-- tokenize word by 2nd delimiter -->
            <xsl:call-template name="capitalize">
                <xsl:with-param name="text" select="$word"/>
                <xsl:with-param name="delimiter" select="'/'"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <!-- capitalize word -->
            <xsl:value-of select="translate(substring($word, 1, 1), $lower-case, $upper-case)"/>    
            <xsl:value-of select="translate(substring($word, 2), $upper-case, $lower-case)"/>
        </xsl:otherwise>
    </xsl:choose>
    <xsl:if test="contains($text, $delimiter)">
        <xsl:value-of select="$delimiter"/>
        <!-- recursive call -->
        <xsl:call-template name="capitalize">
            <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            <xsl:with-param name="delimiter" select="$delimiter"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

Результат 

<?xml version="1.0" encoding="UTF-8"?>
<output>
  <caps>Self/Employed</caps>
  <caps>Skill Trade</caps>
  <caps>Government</caps>
  <caps>A Combi/Na/Tion Of Various De/Limi/Ters</caps>
</output>
...