Есть ли хороший способ получить флажок три состояния в flex?

Question

Я хорошо порылся в сети и не могу найти никаких примеров флажка с тремя состояниями. Он не поддерживается в SDK, и я не могу найти примеров в Интернете.

Я бы подумал, что это обычная проблема, прежде чем приступить к написанию своей собственной, кто-нибудь знает о хорошем компоненте флажка flex-tri-state где-то, что я могу использовать :)

Приветствия

Jawache.

Answer 1

Пример публикации здесь в Flex Cookbook. Вы можете легко создать свой собственный компонент из этого кода.

Answer 2

Для других, кто сталкивался с этим позже, я создал свой собственный компонент, который просто скрывает флажок для третьего состояния и заменяет его изображением, похожим на флажок в третьем состоянии. Это действительно легко реализовать:

<?xml version="1.0" encoding="utf-8"?>
<s:Group xmlns:fx="http://ns.adobe.com/mxml/2009" 
        xmlns:s="library://ns.adobe.com/flex/spark" 
        xmlns:mx="library://ns.adobe.com/flex/mx">

<fx:Script>
    <![CDATA[
        public static const BOX_CHECKED:int = 1;
        public static const BOX_REJECTED:int = -1;
        public static const BOX_UNCHECKED:int = 0;
        [Bindable] public var boxVisible:Boolean = true;
        [Bindable] public var enum_id:int = -1;
        protected function checkbox_clickHandler(event:MouseEvent):void
        {
            if(!checkbox.selected)
                boxVisible = false;             
        }

        protected function image_clickHandler(event:MouseEvent):void
        {
            boxVisible = true;              
        }

        public function set label(str:String):void {
            checkbox.label = str;
            xLabel.text = str;
        }

        public function get boxState():int {
            if(checkbox.selected)
                return BOX_CHECKED;
            else if(redX.visible)
                return BOX_REJECTED;

            return BOX_UNCHECKED;
        }
    ]]>
</fx:Script>

<fx:Declarations>
    <!-- Place non-visual elements (e.g., services, value objects) here -->
</fx:Declarations>
<s:CheckBox id="checkbox" click="checkbox_clickHandler(event)" visible="{boxVisible}" includeInLayout="{boxVisible}"/>
<s:HGroup>
    <s:Image id="redX" source="@Embed('assets/icons/redX.png')"
         width="16" height="16"
         click="image_clickHandler(event)" 
         visible="{!boxVisible}" includeInLayout="{!boxVisible}"/>
    <s:Label id="xLabel" visible="{!boxVisible}" includeInLayout="{!boxVisible}" paddingTop="4"/>
</s:HGroup>

</s:Group>

Answer 3

Вот моя собственная версия, вдохновленная Джеймсом. Вы можете включить / отключить tristate, чтобы получить классический флажок с тем же компонентом, и используемый механизм немного отличается, с меньшим количеством шаблонов. Встроенное изображение здесь . Используйте на свой страх и риск! :)

<?xml version="1.0" encoding="utf-8"?>
<s:Group xmlns:fx="http://ns.adobe.com/mxml/2009" 
         xmlns:s="library://ns.adobe.com/flex/spark" 
         xmlns:mx="library://ns.adobe.com/flex/mx"
         creationComplete="init()">

    <fx:Script>
        <![CDATA[
            import mx.events.FlexEvent;

            // STATES :
            /** The intermediate state value. */
            public static const INTERMEDIATE:int = -1;
            /** The unchecked state value. */
            public static const UNCHECKED:int = 0;
            /** The checked state value. */
            public static const CHECKED:int = 1;


            // TRISTATE :
            private var _isTristate:Boolean;
            /** Whether this checkbox is tristate or a normal checkbox. */
            [Bindable] public function get isTristate():Boolean { return _isTristate; }
            public function set isTristate(value:Boolean):void {
                _isTristate = value;
                if(!_isTristate && state == INTERMEDIATE) 
                    state = UNCHECKED;
            }


            // LABEL :
            /** The checkbox label. */
            [Bindable] public var label:String;


            // STATE CHANGE :

            private var _state:int;
            /** The current state of the box. */
            public function get state():int { return _state; }
            public function set state(value:int):void {
                _state = value;
                switch(_state) {
                    case INTERMEDIATE:
                        if(!_isTristate)
                            throw new Error("Setting state to INTERMEDIATE on a non tristate checkbox !");
                        tristateImg.visible = true;
                        checkbox.selected = false;
                        break;

                    case UNCHECKED:
                        tristateImg.visible = false;
                        checkbox.selected = false;
                        break;

                    case CHECKED:
                        tristateImg.visible = false;
                        checkbox.selected = true;
                        break;
                }
            }

            /**
             * Simply sets the state according to the current state.
             */
            protected function changeState(ev:Event):void {
                if(isTristate) ev.preventDefault();
                switch(state) {
                    case INTERMEDIATE: state = CHECKED; break;
                    case UNCHECKED: state = isTristate ? INTERMEDIATE : CHECKED; break;
                    case CHECKED: state = UNCHECKED; break;
                }
            }

            /**
             * Initial state.
             */
            protected function init():void {
                state = UNCHECKED;
            }

        ]]>
    </fx:Script>

    <fx:Declarations>
        <!-- Place non-visual elements (e.g., services, value objects) here -->
    </fx:Declarations>

    <s:layout>
        <s:BasicLayout />
    </s:layout>

    <s:CheckBox id="checkbox" label="{label}"
                change="changeState(event)"/>
    <s:Image id="tristateImg"
             mouseEnabled="false" mouseChildren="false"
             source="@Embed('assets/icons/tristate_checkbox.png')"
             x="2" y="5" />

</s:Group>

Answer 4

Взгляните на http://srinichekuri.wordpress.com/2011/05/20/3-state-checkbox-for-headerrenderer-in-datagrid/.

У него есть код для флажка состояния 3.