Запрос на обновление MS Access на основе номера индекса и других критериев - PullRequest
Новая
       17

Запрос на обновление MS Access на основе номера индекса и других критериев

0 голосов
/ 12 мая 2018

У меня есть функция, которую я пытаюсь выполнить для базы данных, над которой я работаю для своей работы. Я не самый опытный с Access, поэтому я прошу прощения, если я не формулирую это наилучшим образом.

Я пытаюсь создать запрос / макрос, который будет имитировать поведение, как показано

enter image description here

и приведем к этому:

enter image description here

Логика следующая

1) для каждой записи - взять LEN строки в StdName. Возьмите это количество символов и ОБНОВИТЕ это в поле Имя. Остальные символы после LEN перемещаются в поле 'SuffixString'

2) для каждой записи - подсчитать количество вхождений строки в поле 'StdName' для любых записей ПО ИЛИ ПЕРЕД индексным номером и ОБНОВИТЬ поле 'Имя' с тем, что там уже есть, и объединить с "_n где n - вхождение

пример: индекс 1 - имеет одно вхождение 'Car1' в поле StdName между записью 1 и записью 1. для индекса 1 'Имя' изменяется на Car1_1

пример: индекс 2 - имеет два вхождения «Car1» в поле StdName между записью 1 и записью 2. для индекса 2 «Имя» изменяется на Car1_2

пример: индекс 6 - имеет одно вхождение 'Car3' в поле StdName между записью 1 и записью 6. для индекса 6 'Имя' изменяется на Car3_1

Можно ли что-то подобное сделать с помощью запроса доступа? Я никогда раньше не разрабатывал в Access, и мой начальник действительно хочет, чтобы эта функция оставалась внутри доступа, а не превращалась в out of excel.

(У меня есть шаг 1, настроенный таким образом, чтобы позже ввести в логику, когда StdName не совпадает с Name. Пример: «Car1_1» для Name и StdName «Car2». Я понимаю, что мог бы просто объединить StdName с функцией на шаге 2 в этот пример я описал, но у меня есть реальная цель сделать это таким образом)

Это будет сделано в формате MDB

Спасибо

1 Ответ

0 голосов
/ 12 мая 2018

Вы можете использовать мою функцию RowCounter : 

SELECT RowCounter(CStr([Index]),False,[StdName])) AS RowID, *
FROM YourTable
WHERE (RowCounter(CStr([Index]),False) <> RowCounter("",True));

или 

SELECT [StdName] & "_" & CStr(RowCounter(CStr([Index]),False,[StdName]))) AS RankedName, *
FROM YourTable
WHERE (RowCounter(CStr([Index]),False) <> RowCounter("",True));

Изменить - до обновить : 

UPDATE s_before
SET [Name] = [StdName] & "_" & CStr(RowCounter(CStr([Index]),False,[StdName])) 
WHERE (RowCounter(CStr([Index]),False) <> RowCounter("",True));

Код: 

Public Function RowCounter( _
  ByVal strKey As String, _
  ByVal booReset As Boolean, _
  Optional ByVal strGroupKey As String) _
  As Long

' Builds consecutive RowIDs in select, append or create query
' with the possibility of automatic reset.
' Optionally a grouping key can be passed to reset the row count
' for every group key.
'
' Usage (typical select query):
'   SELECT RowCounter(CStr([ID]),False) AS RowID, *
'   FROM tblSomeTable
'   WHERE (RowCounter(CStr([ID]),False) <> RowCounter("",True));
'
' Usage (with group key):
'   SELECT RowCounter(CStr([ID]),False,CStr[GroupID])) AS RowID, *
'   FROM tblSomeTable
'   WHERE (RowCounter(CStr([ID]),False) <> RowCounter("",True));
'
' The Where statement resets the counter when the query is run
' and is needed for browsing a select query.
'
' Usage (typical append query, manual reset):
' 1. Reset counter manually:
'   Call RowCounter(vbNullString, False)
' 2. Run query:
'   INSERT INTO tblTemp ( RowID )
'   SELECT RowCounter(CStr([ID]),False) AS RowID, *
'   FROM tblSomeTable;
'
' Usage (typical append query, automatic reset):
'   INSERT INTO tblTemp ( RowID )
'   SELECT RowCounter(CStr([ID]),False) AS RowID, *
'   FROM tblSomeTable
'   WHERE (RowCounter("",True)=0);
'
' 2002-04-13. Cactus Data ApS. CPH
' 2002-09-09. Str() sometimes fails. Replaced with CStr().
' 2005-10-21. Str(col.Count + 1) reduced to col.Count + 1.
' 2008-02-27. Optional group parameter added.
' 2010-08-04. Corrected that group key missed first row in group.

  Static col      As New Collection
  Static strGroup As String

  On Error GoTo Err_RowCounter

  If booReset = True Then
    Set col = Nothing
  ElseIf strGroup <> strGroupKey Then
    Set col = Nothing
    strGroup = strGroupKey
    col.Add 1, strKey
  Else
    col.Add col.Count + 1, strKey
  End If

  RowCounter = col(strKey)

Exit_RowCounter:
  Exit Function

Err_RowCounter:
  Select Case Err
    Case 457
      ' Key is present.
      Resume Next
    Case Else
      ' Some other error.
      Resume Exit_RowCounter
  End Select

End Function
...