YUV шейдер для Unity?

Question

У меня есть некоторые (правильные, плоские) текстуры YUV в Unity, и я просто хочу увидеть их для использования разработчиками.

Есть ли на самом деле работающий шейдер YUV для Unity (их вариант языка шейдеров), работающий вокруг??

Концептуально достаточно просто конвертировать из YUV в RGB ... но немного сложновато.

Answer 1

YUV в RGB-шейдер:

 Shader "Hidden/YUVtoRGB"
    {
        Properties
        {
            _MainTex ("Texture", 2D) = "white" {}
        }
        SubShader
        {
            // No culling or depth
            Cull Off ZWrite Off ZTest Always

            Pass
            {
                CGPROGRAM
                #pragma vertex vert
                #pragma fragment frag

                #include "UnityCG.cginc"

                struct appdata
                {
                    float4 vertex : POSITION;
                    float2 uv : TEXCOORD0;
                };

                struct v2f
                {
                    float2 uv : TEXCOORD0;
                    float4 vertex : SV_POSITION;
                };

                v2f vert (appdata v)
                {
                    v2f o;
                    o.vertex = UnityObjectToClipPos(v.vertex);
                    o.uv = v.uv;
                    return o;
                }

                sampler2D _MainTex;


                fixed3 YUVtoRGB(fixed3 c)
                {
                    fixed3 rgb;
                    rgb.r = c.x + c.z * 1.13983;
                    rgb.g = c.x + dot(fixed2(-0.39465, -0.58060), c.yz);
                    rgb.b = c.x + c.y * 2.03211;
                    return rgb;
                }

                fixed4 frag (v2f i) : SV_Target
                {
                    fixed4 yuv = tex2D(_MainTex, i.uv);
                    fixed4 rgb = fixed4(YUVtoRGB(yuv.rgb), yuv.a);
                    return rgb;
                }
                ENDCG
            }
        }
    }

Answer 2

Просто ради ответа,

Вы можете очень просто использовать только Y канал YUV,

и вы получите точно монохромную версию изображения.

Итак, в абстрактных терминах псевдокода, просто сделайте что-то вроде этого ...

uint32_t grayscale_from_y(uint8_t y)
    {
        // when we want to show a YUV texture on screen
        // for checking during development,
        // you can be super lazy and just feed
        // the "Y" to RGB upstream,
        // set R G and B to the Y value, something like this:

        uint32_t r = y;
        uint32_t g = y;
        uint32_t b = y;
        return r + (g << 8) + (b << 16) + 0xff000000;
        // (alpha is one there)
    }

это может кому-то помочь!