Как я могу скопировать и вставить ряд таблиц в Word? - PullRequest
Новая
       26

Как я могу скопировать и вставить ряд таблиц в Word?

4 голосов
/ 16 сентября 2009

РЕДАКТИРОВАТЬ: Если у вас есть пример в VBA, я возьму его. Я просто пытаюсь понять, как использовать объект Range с коллекцией Tables для копирования и вставки нескольких таблиц без зацикливания. Другими словами, как я могу указать диапазон 1..lastTable, используя коллекцию Tables? Если я увижу работающий пример VBA, я поработаю над преобразованием VBA -> Perl.

Я пытаюсь использовать модуль Perl Win32 :: OLE (через превосходную книгу Дэйва Рота), чтобы автоматизировать пару задач, которые мне нужно многократно выполнять в некоторых документах Word. Тем не менее, книга (и большинство веб-примеров) имеет тенденцию использовать Excel для примеров, поэтому я не уверен, как эффективно копировать и вставлять объект коллекции Tables.

Вот фрагмент моего кода: 

my $originalDoc = $MSWord->Documents->Open('C:\Perl\testDocument.doc');
my $newDoc = $MSWord->Documents->Add;
my $selection = $MSWord->Selection(); # this may be spurious

my $Count = int( $originalDoc->Tables()->{Count} );
my $range = $originalDoc->Tables()->Range( { Start => $originalDoc->Tables(1)->{Range}->{Start},
                                             End   => $originalDoc->Tables($Count)->{Range}->{End}
                                           } );
$range->Copy();
$newDoc->Range()->Paste();

В исходном коде использовались параграфы, а не таблицы, поэтому я предполагаю, что некоторые ошибки являются артефактами этого кода (или, скорее всего, моим непониманием этого кода).

1 Ответ

5 голосов
/ 20 сентября 2009

Копирование и вставка таблиц по одной за раз может быть предпочтительнее: 

#!/usr/bin/perl

use strict;
use warnings;

use File::Spec::Functions qw( catfile );

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Word';
$Win32::OLE::Warn = 3;

my $word = get_word();
$word->{Visible} = 1;

my $doc = $word->{Documents}->Open(catfile $ENV{TEMP}, 'test.doc');
my $newdoc = $word->Documents->Add;

my $n_tables = $doc->Tables->Count;

for my $table_i ( 1 .. $n_tables ) {

    my $table = $doc->Tables->Item($table_i);
    $table->Select;
    $word->Selection->Copy;

    my $end = $newdoc->GoTo(wdGoToLine, wdGoToLast);
    $end->InsertBefore("\n");
    $end = $newdoc->GoTo(wdGoToLine, wdGoToLast);
    $end->Select;

    $word->Selection->Paste;
}

$doc->Close(0);
$newdoc->SaveAs('test-output.doc');

sub get_word {
    my $word;
    eval {
        $word = Win32::OLE->GetActiveObject('Word.Application');
    };

    die "$@\n" if $@;

    unless(defined $word) {
        $word = Win32::OLE->new('Word.Application', sub { $_[0]->Quit })
            or die "Oops, cannot start Word: ",
                   Win32::OLE->LastError, "\n";
    }
    return $word;
}
...