Как автоматически сохранять файлы при потере фокуса в Emacs - PullRequest
Новая
       23

Как автоматически сохранять файлы при потере фокуса в Emacs

19 голосов
/ 05 августа 2009

Можно ли настроить Emacs, чтобы он сохранял все файлы, когда окно emacs проигрывает фокус?

Ответы [ 5 ]

25 голосов
/ 20 ноября 2013

Я добавил фокус-крючки в Gnu Emacs 24.4.

Они называются focus-in-hook и focus-out-hook.

Вы можете добавить 

(defun save-all ()
  (interactive)
  (save-some-buffers t))

(add-hook 'focus-out-hook 'save-all)

в ваш файл .emacs, и он должен сохранить все файлы при потере фокуса.

10 голосов
/ 17 декабря 2012

Я использую это, оно будет работать, только если emacs работает под X (как это, вероятно, будет в Ubuntu). 

(when
   (and (featurep 'x) window-system)
 (defvar on-blur--saved-window-id 0 "Last known focused window.")
 (defvar on-blur--timer nil "Timer refreshing known focused window.")
 (defun on-blur--refresh ()
   "Runs on-blur-hook if emacs has lost focus."
   (let* ((active-window (x-window-property
                          "_NET_ACTIVE_WINDOW" nil "WINDOW" 0 nil t))
          (active-window-id (if (numberp active-window)
                                active-window
                              (string-to-number
                               (format "%x00%x"
                                       (car active-window)
                                       (cdr active-window)) 16)))
          (emacs-window-id (string-to-number
                            (frame-parameter nil 'outer-window-id))))
     (when (and
            (= emacs-window-id on-blur--saved-window-id)
            (not (= active-window-id on-blur--saved-window-id)))
       (run-hooks 'on-blur-hook))
     (setq on-blur--saved-window-id active-window-id)
     (run-with-timer 1 nil 'on-blur--refresh)))
 (add-hook 'on-blur-hook #'(lambda () (save-some-buffers t)))
 (on-blur--refresh))
2 голосов
/ 10 августа 2009

[…] функция, о которой я говорю, от Книжники. Это очень удобно, когда редактирование HTML и тому подобное, вы не придется нажимать C-x C-s, вы просто измените окно и проверьте ваш браузер.

В этом случае, вместо переключения на приложение браузера, прикажите Emacs загрузить приложение браузера (C-c C-v или M-x browse-url-of-buffer). С помощью этого метода вы можете написать свою собственную функцию, которая сохраняет буфер, и затем запускает браузер, например: 

(defun my-browse-url-of-buffer ()
  "Save current buffer and view its content in browser."
  (interactive)
  (save-buffer)
  (browse-url-of-buffer))

И подключите его к удобной привязке.

Или вы все равно можете использовать html-autoview-mode, который каждый раз, когда вы сохраняете буфер, автоматически загружает файл в ваш любимый браузер.

2 голосов
/ 05 августа 2009

Не уверен, что это то, что вы хотите. 

(defun dld-deselect-frame-hook ()
  (save-some-buffers 1))

(add-hook 'deselect-frame-hook 'dld-deselect-frame-hook)

От: http://www.dribin.org/dave/blog/archives/2003/09/10/emacs/

РЕДАКТИРОВАТЬ: кажется, работает только в XEmacs

1 голос
/ 08 августа 2009

Вы можете использовать `автосохранение-интервал ', чтобы сохранить каждый набранный n символов. Мой установлен на 100. Так примерно каждые 2-3 строки кода, может быть?

auto-save-interval является переменной определено в `C исходном коде '. Его ценность это 100

Документация: * Количество входных событий между автосохранениями. Ноль означает отключить автосохранение по количеству символов набран.

Вы можете настроить эту переменную.

Это не отвечает на ваш первоначальный вопрос; это просто способ достичь чего-то похожего.

...