Правильное использование логических языков в качестве инструмента - PullRequest
Новая
       47

Правильное использование логических языков в качестве инструмента

0 голосов
/ 24 мая 2018

Меня интересует философия программирования «используй правильный инструмент для работы», и у меня есть проблема, которая, я думаю, может быть решена с помощью логического программирования.Я имею в виду это наивно, потому что я не занимался логическим программированием и просто собираюсь учиться.Но, находясь на стадии, когда я все еще пытаюсь понять концепции и словарный запас, я надеялся на какое-то экспертное направление, прежде чем стать слишком глубоким.

Что привлекло меня к идее использования логического программирования, так это мои смутные знания об идее «объединения», но я подумал о том, чтобы использовать его так, что я не уверен, что это идиоматично или правильно.Учитывая два объекта (или деревья), я хочу сравнить два для равенства через их свойства (или листья), и что я хочу вернуть, это некоторое понятие «разности» - то есть, учитывая способы, которыми эти два объекта являются не отличается, какие изменения нужно было бы сделать в одном из них, чтобы эти два понятия были равны?

Например, скажем, у меня есть два объекта chair и stool.Предположим, что каждый состоит из списка свойств или атрибутов, я хотел бы построить систему, которая может возвращать что-то по принципу «стул и стул будут равны, если бы legCount табурета были 4 и hasBack были быtrue «.

По какой-то причине семантически я представляю это как некий остаток, например, chair минус stool равен единице leg.Не уверен, полезно это или нет ...

Я могу придумать несколько глупых способов сделать это с помощью императивного кода и несколько более элегантных способов сделать это, используя функциональные приемы, но я догадывался, что логическое программирование можетбыть особенно подходящим для этого.Спасибо за любую мудрость о том, какие направления изучать, очень важно!

1 Ответ

0 голосов
/ 25 мая 2018

Возможно, вы хотите взглянуть на «Наименьшее общее обобщение» или «анти-объединение» из литературы ILP:

Вот несколько слайдов: http://soft.vub.ac.be/~cderoove/declarative_programming/decprog7.pdf

Использованиекод из просто логической главы 9 http://people.cs.bris.ac.uk/~flach/SL/SL.pdf:

:-op(600,xfx,'<-').

anti_unify(Term1,Term2,Term):-
    anti_unify(Term1,Term2,Term,[],S1,[],S2).

anti_unify(Term1,Term2,Term1,S1,S1,S2,S2):-
    Term1 == Term2,!.
anti_unify(Term1,Term2,V,S1,S1,S2,S2):-
    subs_lookup(S1,S2,Term1,Term2,V),!.
anti_unify(Term1,Term2,Term,S10,S1,S20,S2):-
    nonvar(Term1),nonvar(Term2),
    functor(Term1,F,N),functor(Term2,F,N),!,
    functor(Term,F,N),
    anti_unify_args(N,Term1,Term2,Term,S10,S1,S20,S2).
anti_unify(T1,T2,V,S10,[T1<-V|S10],S20,[T2<-V|S20]).



anti_unify_args(0,Term1,Term2,Term,S1,S1,S2,S2).
anti_unify_args(N,Term1,Term2,Term,S10,S1,S20,S2):-
    N>0, N1 is N-1,
    arg(N,Term1,Arg1),
    arg(N,Term2,Arg2),
    arg(N,Term,Arg),
    anti_unify(Arg1,Arg2,Arg,S10,S11,S20,S21),
    anti_unify_args(N1,Term1,Term2,Term,S11,S1,S21,S2).

subs_lookup([T1<-V|Subs1],[T2<-V|Subs2],Term1,Term2,V):-
    T1 ==Term1,
    T2 ==Term2,!.
subs_lookup([S1|Subs1],[S2|Subs2],Term1,Term2,V):-
   subs_lookup(Subs1,Subs2,Term1,Term2,V).

Тогда вы можете запросить: 

?- anti_unify(object(type=chair,legs=4,hasback=true,color=red),object(type=stool,legs=3,hasback=false,color=red),T,[],S1,[],S2).
T = object(type=_1838, legs=_1808, hasback=_1778, color=red),
S1 = [chair<-_1838, 4<-_1808, true<-_1778],
S2 = [stool<-_1838, 3<-_1808, false<-_1778] .

, который дает вам термин, который является наименее общим обобщением наших двух объектов наряду с подстановкамивы бы сделали, чтобы вернуть предметы.

...