Я не буду использовать слово «проще».Но более алгоритмически, да, это возможно.Вы будете очень рады узнать, что в официальной документации Adobe есть пример , как воспроизводить последовательность звуков .Позволяет адаптировать его к вашим потребностям.
Во-первых, вам нужно разработать звуковой кэш, чтобы вы могли получить звук по значению символа.
package
{
import flash.media.Sound;
import flash.events.Event;
public class SoundCache
{
static private var loadingPlan:int;
static private var completeHandler:Function;
static private var hash:Object = new Object;
// This method will return a Sound object by character value.
static public function find(name:String):Sound
{
return hash[name];
}
static public function startEngine(handler:Function):void
{
loadingPlan = 12;
completeHandler = handler;
for (var i:int = 0; i < 10; i++)
loadSound(i + "", i + "");
loadSound("+", "plus");
loadSound("-", "minus");
}
static private function loadSound(name:String, fileName:String):void
{
var aSound:Sound = new Sound;
hash[name] = aSound;
aSound.addEventListener(Event.COMPLETE, onLoaded);
aSound.load(FilePath + "speech/" + fileName + ".mp3");
}
static private function onLoaded(e:Event):void
{
var aSound:Sound = e.target as Sound;
aSound.removeEventListener(Event.COMPLETE, onLoaded);
loadingPlan--;
if (loadingPlan == 0)
{
if (completeHandler != null)
{
completeHandler();
completeHandler = null;
}
}
}
}
}
Итак, в начале вашего приложения вывызов:
import SoundCache;
SoundCache.startEngine(onCache);
function onCache():void
{
trace("All sounds are loaded!");
}
Когда все звуки загружены и готовы, вы можете использовать их для воспроизведения звуковых последовательностей.Давайте разработаем последовательность игрока.
package
{
import SoundCache;
import flash.events.Event;
import flash.media.Sound;
import flash.media.SoundChannel;
public class SequencePlayer
{
// A list of active sequence players. If you don't keep
// their references while they are playing,
// Garbage Collector might go and get them.
static private var list:Array = new Array;
static public function play(sequence:String):void
{
// Sanity check.
if (!sequence)
{
trace("There's nothing to play!");
return;
}
var aSeq:SequencePlayer = new SequencePlayer;
list.push(aSeq);
aSeq.sequence = sequence;
aSeq.playNext();
}
// *** NON-STATIC PART *** //
private var sequence:String;
private var channel:SoundChannel;
private function playNext():void
{
var aChar:String;
var aSound:Sound;
// While there are still characters in the sequence,
// search for sound by the first character.
// If there's no such sound - repeat.
while (sequence)
{
// Get a sound from the cache by single character.
aChar = sequence.charAt(0);
aSound = SoundCache.find(aChar);
// Remove the first character from the sequence.
sequence = sequence.substr(1);
// Stop searching if there is a valid next sound.
if (aSound) break;
}
if (aSound)
{
// If there is a valid Sound object to play, then play it
// and subscribe for the relevant event to move to the
// next sound when this one is done playing.
channel = aSound.play();
channel.addEventListener(Event.SOUND_COMPLETE, onSound);
}
else
{
// If sequence is finished and there's no valid
// sound to play, remove this sequence player
// from the keepalive list and forget about it.
var anIndex:int = list.indexOf(this);
if (anIndex > -1) list.splice(anIndex, 1);
}
}
// Event.SOUND_COMPLETE handler.
private function onSound(e:Event):void
{
// Sanity checks.
if (!channel) return;
if (e.target != channel) return;
// Release the current SoundChannel object.
channel.removeEventListener(Event.SOUND_COMPLETE, onSound);
channel = null;
// Move on to the next sound if any.
playNext();
}
}
}
Хотя все это пока может показаться пугающим, мы почти закончили.На этом этапе все, что вам нужно сделать для воспроизведения случайной последовательности звуков, - это вызвать метод SequencePlayer.play (...) .Все вышеперечисленные ужасы сводят вашу проблему к следующему:
import SequencePlayer;
// It will ignore the space charaters so it's fine.
SequencePlayer.play(" 5 + 0 ");
Пожалуйста, имейте в виду, что хотя я пытался предоставить вам хорошо документированное и рабочее решение, я на самом деле никогда не проверял его, так что простите мне случайную опечаткуесли есть.