Как отсортировать список по версиям - PullRequest
Новая
       4

Как отсортировать список по версиям

0 голосов
/ 01 декабря 2018

Можно ли отсортировать номера версий с помощью xslt таким образом, чтобы не использовать странные вычисления и манипуляции со строками?

У меня есть список, похожий на этот: 

<?xml version="1.0"?>
<list>
  <directory mtime="2018-08-23T09:40:02Z">2.12.01</directory>
  <directory mtime="2018-11-19T15:04:06Z">2.12.02</directory>
  <directory mtime="2018-09-05T14:07:04Z">3.0.0</directory>
  <directory mtime="2018-10-08T07:14:02Z">3.0.1</directory>
  <directory mtime="2018-11-29T17:06:58Z">3.0.12</directory>
  <directory mtime="2018-11-13T11:34:26Z">2.99.99</directory>
  <directory mtime="2018-11-29T17:06:58Z">latest</directory>
</list>

И яхотел бы отсортировать его по номерам версий, чтобы, например, 3.0.0 был до версии 2.99.99.Вот как я это решил, вроде: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">

<html>
<body>
    <table border="0">
    <tr bgcolor="#9acd32">
        <th>name</th>
        <th>date</th>
    </tr>
    <xsl:for-each select="list/*">
        <xsl:sort select="(number(substring-before(., '.')) * 10000) + (number(substring-before(substring(., number(string-length(substring-before(., '.'))+2), 6), '.')) * 10) + (number(substring-after(substring(., number(string-length(substring-before(., '.'))+2), 6), '.')))" data-type="number" order="descending" />

        <xsl:variable name="name">
            <xsl:value-of select="."/>
        </xsl:variable>
        <xsl:variable name="date">
            <xsl:value-of select="substring(@mtime,9,2)"/>-<xsl:value-of select="substring(@mtime,6,2)"/>-<xsl:value-of select="substring(@mtime,1,4)"/><xsl:text> </xsl:text>
            <xsl:value-of select="substring(@mtime,12,2)"/>:<xsl:value-of select="substring(@mtime,15,2)"/>:<xsl:value-of select="substring(@mtime,18,2)"/>
        </xsl:variable>

        <tr>
             <td><a href="{$name}"><xsl:value-of select="."/></a></td>
             <td><xsl:value-of select="$date"/></td>
        </tr>
    </xsl:for-each>
    </table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>

То, что он делает, это делится на.и преобразование его в число и вычисление первого числа с 10000, второго с 10 и сложение их до одного числа, которое можно отсортировать.

1 Ответ

0 голосов
/ 01 декабря 2018

Вот как я бы переписал вашу попытку:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="utf-8" indent="yes"/>

<xsl:template match="/list">
    <html>
        <body>
            <table>
                <tr>
                    <th>name</th>
                    <th>date</th>
                </tr>
                <xsl:for-each select="directory">
                    <xsl:sort select="substring-before(., '.')" data-type="number" order="descending"/>
                    <xsl:sort select="substring-before(substring-after(., '.'), '.')" data-type="number" order="descending"/>
                    <xsl:sort select="substring-after(substring-after(., '.'), '.')" data-type="number" order="descending"/>
                    <tr>
                        <td>
                            <a href=".">
                                <xsl:value-of select="."/>
                            </a>
                        </td>
                        <td>
                            <xsl:value-of select="substring(@mtime, 9, 2)"/>
                            <xsl:text>-</xsl:text>
                            <xsl:value-of select="substring(@mtime, 6, 2)"/>
                            <xsl:text>-</xsl:text>
                            <xsl:value-of select="substring(@mtime, 1, 4)"/>
                            <xsl:text> </xsl:text>
                            <xsl:value-of select="substring(@mtime, 12, 8)"/>
                        </td>
                    </tr>
                </xsl:for-each>
            </table>
        </body>
    </html> 
</xsl:template>

</xsl:stylesheet>
...