XSL Заменить элемент, разделив его значения

Question

У меня есть следующий XML, который содержит детали заказа в одном элементе.

<?xml version="1.0" encoding="UTF-8"?>
<MESSAGE xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <MESSAGE_ID>361155</MESSAGE_ID>
    <NAME>Header123</NAME>
    <HEADERS>
        <HEADER>
            <ACTION_COUNT>1</ACTION_COUNT>
            <ACTION_DESC>
                <DAILY_LOAD>
                    <LOAD_NO>1</LOAD_NO>
                    <CUSTOMER_NO>09656951</CUSTOMER_NO>
                    <REFERENCE xsi:nil="1"/>
                    <SERIAL>450255470000403803</SERIAL>
                    <ORDERS>
                        <ORDER>
                            <ITEM>5000128762885</ITEM>
                            <DETAILS>4582;Robert and Co;8;5526;SWD</DETAILS>
                            <EMP_NO>13</EMP_NO>
                            <USE_BY_DATE>20110611</USE_BY_DATE>
                            <DEPOT>5000128910035</DEPOT>
                        </ORDER>
                        <ORDER>
                            <ITEM>5000128853613</ITEM>
                            <DETAILS>5000;Anne and Co;9;2020;ATM</DETAILS>
                            <EMP_NO>5</EMP_NO>
                            <USE_BY_DATE>20110613</USE_BY_DATE>
                            <DEPOT>5000128910035</DEPOT>
                        </ORDER>
                    </ORDERS>
                </DAILY_LOAD>
            </ACTION_DESC>
        </HEADER>
    </HEADERS>
    <LIST_ID>23689</LIST_ID>
    <TRAILER>TEST_NEEDED</TRAILER>
</MESSAGE>

Мне нужно преобразовать его в следующий формат.(только раздел DAILY_LOAD> ORDERS должен быть изменен, как показано ниже)

.....
     <ORDERS>
        <ORDER>
            <ITEM>5000128762885</ITEM>
            <ORDER_NO>4582</ORDER_NO>
            <CUSTOMER>Robert and Co</CUSTOMER>
            <NO_OF_ITEMS>8</NO_OF_ITEMS>
            <TOTAL>5526</TOTAL>
            <LOCATION>SWD</LOCATION>
            <EMP_NO>13</EMP_NO>
            <USE_BY_DATE>20110611</USE_BY_DATE>
            <DEPOT>5000128910035</DEPOT>
        </ORDER>
        <ORDER>
            <ITEM>5000128853613</ITEM>
            <ORDER_NO>5000</ORDER_NO>
            <CUSTOMER>Anne and Co</CUSTOMER>
            <NO_OF_ITEMS>9</NO_OF_ITEMS>
            <TOTAL>2020</TOTAL>
            <LOCATION>ATM</LOCATION>
            <EMP_NO>5</EMP_NO>
            <USE_BY_DATE>20110613</USE_BY_DATE>
            <DEPOT>5000128910035</DEPOT>
        </ORDER>
    </ORDERS>
.....

Преобразованный XML не содержит, но разделен на CUSTOMER, NO_OF_ITEMS, TOTAL и LOCATION.Любое предложение или помощь будут высоко оценены.Заранее спасибо.

Answer 1

XSLT 1.0

Использование шаблона tokenizeString , как предлагается в блоге Heber.it .Я изменил код для создания разных имен тегов в зависимости от уровня рекурсии (ORDER_NO, CUSTOMER, NO_OF_ITEMS и т. Д.).

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:template match="/">
    <xsl:apply-templates/>
  </xsl:template>

  <!-- replaces order nodes -->
  <xsl:template match="ORDER">
    <ORDER>
      <xsl:call-template name="tokenizeString">
        <xsl:with-param name="list" select="./DETAILS"/>
        <xsl:with-param name="delimiter" select="';'"/>
        <xsl:with-param name="level" select="1"/>
      </xsl:call-template> 
    </ORDER>
  </xsl:template>

  <!-- copy everything that doesn't match another template -->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- template to tokenize strings -->
  <xsl:template name="tokenizeString">
    <!--passed template parameter -->
    <xsl:param name="list"/>
    <xsl:param name="delimiter"/>
    <xsl:param name="level"/>
    <xsl:choose>
      <xsl:when test="contains($list, $delimiter)">
        <xsl:choose>
          <xsl:when test="$level = 1">
            <ITEM>
              <xsl:value-of select="ITEM"/>
            </ITEM>
            <ORDER_NO>
              <xsl:value-of select="substring-before($list,$delimiter)"/>
            </ORDER_NO>
          </xsl:when>
          <xsl:when test="$level = 2">
            <CUSTOMER>
              <xsl:value-of select="substring-before($list,$delimiter)"/>
            </CUSTOMER>
          </xsl:when>
          <xsl:when test="$level = 3">
            <NO_OF_ITEMS>
              <xsl:value-of select="substring-before($list,$delimiter)"/>
            </NO_OF_ITEMS>
          </xsl:when>
          <xsl:when test="$level = 4">
            <TOTAL>
              <xsl:value-of select="substring-before($list,$delimiter)"/>
            </TOTAL>
          </xsl:when>
        </xsl:choose>
        <xsl:call-template name="tokenizeString">
          <!-- store anything left in another variable -->
          <xsl:with-param name="list" select="substring-after($list,$delimiter)"/>
          <xsl:with-param name="delimiter" select="$delimiter"/>
          <xsl:with-param name="level" select="$level + 1"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:choose>
          <xsl:when test="$list = ''">
            <xsl:text/>
          </xsl:when>
          <xsl:otherwise>
            <LOCATION>
              <xsl:value-of select="$list"/>
            </LOCATION>
            <EMP_NO>
              <xsl:value-of select="EMP_NO"/>
            </EMP_NO>
            <USE_BY_DATE>
              <xsl:value-of select="USE_BY_DATE"/>
            </USE_BY_DATE>
            <DEPOT>
              <xsl:value-of select="DEPOT"/>
            </DEPOT>            
          </xsl:otherwise>
        </xsl:choose>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

XSLT 2.0

Использование tokenize Функция, которую вы можете сделать это:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:template match="/">
    <xsl:apply-templates/>
  </xsl:template>
  <!-- this template replaces order nodes -->
  <xsl:template match="ORDER">
    <ORDER>
      <xsl:variable name="fields" select="tokenize(DETAILS, ';')"/>
      <ITEM>
        <xsl:value-of select="ITEM"/>
      </ITEM>
      <ORDER_NO>
        <xsl:value-of select="$fields[position()=1]"/>
      </ORDER_NO>
      <CUSTOMER>
        <xsl:value-of select="$fields[position()=2]"/>
      </CUSTOMER>
      <NO_OF_ITEMS>
        <xsl:value-of select="$fields[position()=3]"/>
      </NO_OF_ITEMS>
      <TOTAL>
        <xsl:value-of select="$fields[position()=4]"/>
      </TOTAL>
      <LOCATION>
        <xsl:value-of select="$fields[position()=5]"/>
      </LOCATION>
      <EMP_NO>
        <xsl:value-of select="EMP_NO"/>
      </EMP_NO>
      <USE_BY_DATE>
        <xsl:value-of select="USE_BY_DATE"/>
      </USE_BY_DATE>
      <DEPOT>
        <xsl:value-of select="DEPOT"/>
      </DEPOT>
    </ORDER>
  </xsl:template>
  <!-- this template copies everything that doesn't match another template -->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>