TEXTJOIN для xl2010 / xl2013 с критериями

Question

У меня есть 2 рабочих листа.Первый лист содержит около 100 строк, но нас интересует только столбец Y. Ячейки в столбце Y содержат смесь пустых ячеек (""), текста и чисел и ячеек, в которых отображается # N / A.Аналогично изображению, но с большим набором данных.

Во 2-й рабочей таблице есть ячейка, которую я хотел бы захватить ячейкис «текстами и числами» и отображать каждую запись в отдельной строке в одной и той же ячейке (например, если было 12 из 100 ячеек с «текстами и числами», то я хотел бы отобразить эту информацию в конкретной ячейке в2-й лист. Вот так:

Я пробовал что-то подобное, но, кажется, захватывает только 1-ую строку текста (например, заголовокстрока):

=IFERROR(INDEX('1Comms'!Y:Y,MATCH(TRUE,'1Comms'!Y:Y<>"",0)),"")

Есть ли способ пропустить название?

Что я делаю не так и есть ли способ сделать это?

Answer 1

Эта пользовательская функция TextJoinIfs (также известная как UDF) обеспечивает базовую функциональность TEXTJOIN для версий Excel 2003 - 2013, а также расширенную функциональность для всех версий, добавляя дополнительный контроль ошибок, уникальность, сортировку и параметр.условий для простых критериев.

Этот код UDF TextJoinIfs находится в листе кодов общедоступного модуля;например, Book1 - Module1 (код).

Option Explicit

Public Function TextJoinIfs(delim As String, iOptions As Long, iIgnoreHeaderRows As Long, _
                            rng As Range, ParamArray pairs()) As Variant
    'TEXTJOINIFS - Basic TEXTJOIN functionality for XL2003-XL2013 versions
    '              Expanded TEXTJOINIFS functionality for all versions
    ' =TextJoinIfs(<delimiter>, <options>, <header_rows>, <string_range>, [criteria_range1, criteria1], [criteria_range2, criteria2], …)
    '        OPTIONS
    '     +2 Include blanks
    '     +4 Include worksheet errrors
    '     +8 Unique list
    '     +16 Sort ascending (cannot be used with 17)
    '     +17 Sort descending (cannot be used with 16)

    If Not CBool(UBound(pairs) Mod 2) Then
        TextJoinIfs = CVErr(xlErrValue)
        Exit Function
    End If

    Dim i As Long, j As Long, a As Long, arr As Variant
    Dim bIncludeBlanks As Boolean, bIncludeErrors As Boolean, bUniqueList As Boolean
    Dim bSorted As Boolean, bDescending As Boolean

    bIncludeBlanks = CBool(2 And iOptions)
    bIncludeErrors = CBool(4 And iOptions)
    bUniqueList = CBool(8 And iOptions)
    bSorted = CBool(16 And iOptions)
    bDescending = CBool(1 And iOptions)

    Set rng = Intersect(rng, rng.Parent.UsedRange.Offset(iIgnoreHeaderRows - rng.Parent.UsedRange.Rows(1).Row + 1, 0))

    With rng
        ReDim arr(.Cells.Count)
        If Not IsMissing(pairs) Then
            For i = LBound(pairs) To UBound(pairs) Step 2
                Set pairs(i) = pairs(i).Resize(rng.Rows.Count, rng.Columns.Count).Offset(iIgnoreHeaderRows, 0)
            Next i
        End If

        For j = 1 To .Cells.Count
            If CBool(Len(.Cells(j).Text)) Or bIncludeBlanks Then
                If Not IsError(.Cells(j)) Or bIncludeErrors Then
                    If IsError(Application.Match(.Cells(j).Text, arr, 0)) Or Not bUniqueList Then
                        If IsMissing(pairs) Then
                            arr(a) = .Cells(j).Text
                            a = a + 1
                        Else
                            For i = LBound(pairs) To UBound(pairs) Step 2
                                If Not CBool(Application.CountIfs(pairs(i).Cells(j), pairs(i + 1))) Then Exit For
                            Next i
                            If i > UBound(pairs) Then
                                arr(a) = .Cells(j).Text
                                a = a + 1
                            End If
                        End If
                    End If
                End If
            End If
        Next j
    End With

    ReDim Preserve arr(a - 1)

    If bSorted Then
        Dim tmp As String
        For i = LBound(arr) To UBound(arr) - 1
            For j = i + 1 To UBound(arr)
                If CBool(LCase(CStr(arr(i))) < LCase(CStr(arr(j))) And bDescending) Xor _
                   CBool(LCase(CStr(arr(i))) > LCase(CStr(arr(j))) And Not bDescending) Then
                    tmp = arr(j): arr(j) = arr(i): arr(i) = tmp
                End If
            Next j
        Next i
    End If

    TextJoinIfs = Join(arr, delim)
End Function

Синтаксис:

=TextJoinIfs(<delimiter>, <options>, <header_rows>, <string_range>, [criteria_range1, criteria1], [criteria_range2, criteria2], …)

Документация

Пример 1

Простая операция TextJoin, отбрасывающая пробелы иошибки, сохраняя только уникальные строки.Объединяется с разделителем перевода строки (vbLF), но игнорирует первые две строки заголовка и сортируется по возрастанию.

=textjoinifs(CHAR(10), 24, 2, A:A)

Пример 2

Расширенная операция TextJoinIfs, отбрасывающая пробелы и ошибки, сохраняя только уникальные строки.Объединенный с точкой с запятой / пробелом.Один набор условий диапазона и критериев.

=textjoinifs("; ", 8, 0, B:B, A:A, A2)

Пример 3

Расширенная операция TextJoinIfs, отбрасывающая пробелы и ошибки.Объединяется с запятой / пробелом.Несколько пар условий с использованием математических сравнений.

=textjoinifs(", ", 0, 0, B:B, A:A, ">="&D2, A:A, "<="&E2)

---

_{Большое спасибо Lorem Ipsum Generator для образца строки содержимого.}