Формула для расчета начисленной квартальной надбавки на основе продолжительности трудоустройства

Question

Сотрудники получают определенную сумму надбавки за каждый квартал года, которая накапливается в течение года и сбрасывается каждый новый год.Сумма, которую они получают каждый квартал, определяется тем, как долго они были заняты.

YEARS EMPLOYED | $ PER QUARTER
<1 | $0
>=1 | $37.5
>=3 | $66.66
>=5 | $100

Используя только одну контрольную ячейку (дата найма в ячейке O1), я пытаюсь выяснить, как поставитьФормула вместе, которая будет отображать сумму всех квартальных сумм, начисленных в этом году на сегодняшний деньследующий уровень), все предыдущие кварталы за год должны оставаться на своих ранее назначенных суммах, например:

Если ДАТА НАПРАВЛЕНИЯ 16 апреля 2015 года:

QUARTER | YEARS HIRED | QUARTERLY ALLOWANCE
Q1 | 2.71 | $37.5
Q2 | 2.96 | $37.5
Q3 | 3.21 | $66.66
Q4 | 3.46 | $66.66

Если СЕГОДНЯДАТА - 21 мая 2018 года, общая сумма пособия на сегодняшний день = 75 долларов США (Q1 + Q2)

Если ДЕНЬ СЕГОДНЯ - 7 октября 2018 года, общая сумма пособия на дату = 208,32 доллара США (Q1 + Q2 + Q3 +Q4)

Как это можно сделать с помощью одной формулы, используя только дату проката в ячейке O1?

Answer 1

Я думаю, что самый простой способ получить количество нанятых полных лет - использовать Datedif:

=DATEDIF(O$1,DATE(YEAR(P$1),RIGHT(A2)*3-2,1),"Y")

, помещенный в (скажем) E2, где текущая дата находится в P1 и начинается список кварталов.в A2

Затем выполняется поиск, чтобы получить пособие, рассчитанное в первый день каждого квартала:

=LOOKUP(E2,{0,1,3,5},{0,37.5,66.66,100})

, и, наконец, проверка, чтобы узнать, включен или нет первый день кварталатекущая дата:

=P1>=DATE(YEAR(P1),MONTH(RIGHT(A2)*3-2),1)

Тогда вы можете получить сумму от

=SUMPRODUCT(F2:F5*G2:G5)

Или вы можете объединить все это в одну большую формулу типа массива:

=SUMPRODUCT((P1>=DATE(YEAR(P1),{1,4,7,10},1))*LOOKUP(DATEDIF(O1,DATE(YEAR(P1),{1,4,7,10},1),"Y"),{0,1,3,5},{0,37.5,66.66,100}))