Как переопределить пользовательские процедуры ввода / вывода? - PullRequest
Новая
       68

Как переопределить пользовательские процедуры ввода / вывода?

0 голосов
/ 07 июня 2018

У меня есть абстрактный класс с моими методами чтения / записи для неформатированных двоичных потоков.У меня также есть некоторые классы, унаследованные от абстрактного, и некоторые из них имеют дополнительные компоненты, которые я также хотел бы сериализовать.

Итак, я хочу, чтобы первый набор методов служил поведением по умолчанию, а методы, переопределяющие его внутри унаследованных классов, использовались только этими конкретными классами.

У меня естьпопытался реализовать это так: 

module m
    implicit none

    type, abstract :: a
        integer, public :: num
    contains
        procedure :: write_a
        procedure :: read_a

        generic            :: write(unformatted) => write_a
        generic            :: read(unformatted)  => read_a
    end type a

    type, extends(a) :: b
        integer, public :: num2
    contains
        procedure :: write_b
        procedure :: read_b

        generic :: write(unformatted) => write_b
        generic :: read(unformatted) => read_b
   end type b

    type, extends(a) :: c
    end type c

contains

    subroutine write_a(this, unit, iostat, iomsg)
        class(a), intent(in)    :: this
        integer, intent(in)         :: unit
        integer, intent(out)        :: iostat
        character(*), intent(inout) :: iomsg

        write(unit, iostat=iostat, iomsg=iomsg) this%num
    end subroutine write_a

    subroutine read_a(this, unit, iostat, iomsg)
        class(a), intent(inout) :: this
        integer, intent(in)         :: unit
        integer, intent(out)        :: iostat
        character(*), intent(inout) :: iomsg

        read(unit, iostat=iostat, iomsg=iomsg) this%num
    end subroutine read_a

    subroutine write_b(this, unit, iostat, iomsg)
        class(b), intent(in)    :: this
        integer, intent(in)         :: unit
        integer, intent(out)        :: iostat
        character(*), intent(inout) :: iomsg

        write(unit, iostat=iostat, iomsg=iomsg) this%num, this%num2
    end subroutine write_b

    subroutine read_b(this, unit, iostat, iomsg)
        class(b), intent(inout) :: this
        integer, intent(in)         :: unit
        integer, intent(out)        :: iostat
        character(*), intent(inout) :: iomsg

        read(unit, iostat=iostat, iomsg=iomsg) this%num, this%num2
    end subroutine read_b
end module m

program mwe
    use m

    implicit none

    class(a), allocatable :: o1, o2, o3

    o1 = b(1,2)
    o2 = c(3)

    open(123, file='test5.dat', form='unformatted')
        write(123) o1
    close(123)

    allocate(b :: o3)

    open(123, file='test5.dat', form='unformatted')
        read(123) o3
    close(123)

    write(*,*) o3%num, o3%num2
end program mwe

Но я получаю следующее сообщение об ошибке: 

test5.f90(29): error #8638: The type/rank signature for arguments of this specific subroutine is identical to another specific subroutine that shares the same defined I/O.   [WRITE_A]
    subroutine write_a(this, unit, iostat, iomsg)
---------------^
test5.f90(86): error #6460: This is not a field name that is defined in the encompassing structure.   [NUM2]
    write(*,*) o3%num, o3%num2
--------------------------^

Мне кажется, что, как метод write в классе aне может быть переопределеноКак я могу это правильно реализовать?

1 Ответ

0 голосов
/ 07 июня 2018

Это не проблема, связанная исключительно с определенными процедурами ввода / вывода, но более широко используются общие привязки и процедуры с привязкой к типу.

Ваш тип b имеет процедуры с привязкой к типу, как будто (через расширение) это было определено как 

type b
  integer, public :: num, num2
 contains
    procedure :: write_a, write_b
    procedure :: read_a, read_b
    generic   :: write(unformatted) => write_a, write_b
    generic   :: read(unformatted)  => read_a, read_n
end type

Связывания write_a и write_b действительно неоднозначны (как и read_a и read_b).[Подробнее об этом в другом месте.]

Вам действительно не нужны эти write_a и read_a привязки, поэтому вместо них они должны быть переопределены: 

type, abstract :: a
    integer, public :: num
 contains
    procedure :: write => write_a
    procedure :: read => read_a

    generic   :: write(unformatted) => write
    generic   :: read(unformatted)  => read
end type a

type, extends(a) :: b
    integer, public :: num2
 contains
    procedure :: write => write_b
    procedure :: read => read_b
end type b

Здесь write и read привязки типа b имеют приоритет над привязками типа a.Общая привязка write(unformatted) и read(unformatted) сохраняет сопоставление с привязками (теперь переопределенными) в b.

...