Загрузите несколько файлов с документом XSL и сохраните их в отдельных переменных - PullRequest
Новая
       24

Загрузите несколько файлов с документом XSL и сохраните их в отдельных переменных

0 голосов
/ 09 октября 2018

Я написал небольшое XSL-преобразование для объединения нескольких XML-документов в один файл.Для этого я использую функцию document().В настоящее время мое решение работает нормально, но я спрашиваю себя, есть ли более элегантный способ сделать это.

Есть ли другой способ загрузить несколько файлов и сохранить каждый из них в переменной, а затем обработать эти несколькопеременные в xsl:copy-of?

Вот пример моего текущего XSL-преобразования (XSLT является частью XPROC-конвейера, а первый файл загружается в конвейер): 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:tei="http://www.tei-c.org/ns/1.0"
xmlns="http://www.w3.org/1999/xhtml" exclude-result-prefixes="#all">




<!-- Laden der übrigen TEI-Dateien -->
<xsl:variable name="Fig2" select="document('2_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig3" select="document('3_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig4" select="document('4_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig5" select="document('5_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig6" select="document('6_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig7" select="document('7_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig8" select="document('8_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig9" select="document('9_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig10" select="document('10_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig11" select="document('11_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig12" select="document('12_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig13" select="document('13_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig14" select="document('14_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig15" select="document('15_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig16" select="document('16_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig17" select="document('17_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig18" select="document('18_Figuration_transformiert.xml', tei:TEI)"/>
<xsl:variable name="Fig19" select="document('19_Figuration_transformiert.xml', tei:TEI)"/>


<xsl:template match="/">
    <html>
        <xsl:copy-of select="."/>
        <xsl:copy-of select="$Fig2"/>
        <xsl:copy-of select="$Fig3"/>  
        <xsl:copy-of select="$Fig4"/>
        <xsl:copy-of select="$Fig5"/>
        <xsl:copy-of select="$Fig6"/>
        <xsl:copy-of select="$Fig7"/>
        <xsl:copy-of select="$Fig8"/>
        <xsl:copy-of select="$Fig9"/>
        <xsl:copy-of select="$Fig10"/>
        <xsl:copy-of select="$Fig11"/> 
        <xsl:copy-of select="$Fig12"/>
        <xsl:copy-of select="$Fig13"/>
        <xsl:copy-of select="$Fig14"/>
        <xsl:copy-of select="$Fig15"/>
        <xsl:copy-of select="$Fig16"/>
        <xsl:copy-of select="$Fig17"/>
        <xsl:copy-of select="$Fig18"/>
        <xsl:copy-of select="$Fig19"/>
      </html>
</xsl:template>

</xsl:stylesheet>

Ответы [ 3 ]

0 голосов
/ 09 октября 2018

Если процессор XProc использует Saxon 9 в качестве процессора XSLT 2, то вы также можете попробовать использовать функции collection, которые запрашивают, используя, например, <xsl:copy-of select="collection(concat(base-uri(), '?select=*_Figuration_transformiert.xml'))"/> вместо всех отдельных copy-of инструкций.

См. http://saxonica.com/html/documentation9.8/sourcedocs/collections.html.

0 голосов
/ 09 октября 2018

Вы спрашиваете: есть ли другой способ загрузить несколько файлов и сохранить каждый из них в переменной, а затем обработать эти несколько переменных в xsl: copy-of?

Ну, нет: если вы хотите 18 переменных, каждый из которых содержит один файл, тогда вам понадобится 18 объявлений переменных.Но вы можете добиться того же эффекта, не имея 18 переменных.

Во-первых, вам вообще не нужны никакие переменные, поскольку каждая из них используется только один раз.Вы можете просто вставить их все (заменить ссылку на переменную $Fig6 на выражение, используемое для инициализации переменной Fig6).

Во-вторых, если URI всегда будут систематически называться так, то вы неНе нужно их прописывать: вы можете поместить имена в одну переменную 

<xsl:variable name="figs" select="(2 to 18)!(. || '_Figuration_transformiert.xml')"/>

, а затем заменить ссылку на $Fig6 ссылкой на $figs[6].И, конечно же, вам не нужно прописывать $figs[1], $figs[2] и т. Д .: вы можете обрабатывать их все в цикле.

(Приведенное выше объявление переменной является синтаксисом XSLT 3.0, но вы можетедобиться того же в XSLT 2.0 с немного большим количеством кода).

0 голосов
/ 09 октября 2018

В соответствии с этим (документ XML, который вы используете в качестве входных данных, здесь не имеет значения): 

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:tei="http://www.tei-c.org/ns/1.0"
xmlns="http://www.w3.org/1999/xhtml" exclude-result-prefixes="#all">

    <xsl:param name="files" select="'1_Figuration_transformiert.xml;2_Figuration_transformiert.xml;...'" />

    <xsl:template match="/">
        <html>
            <xsl:for-each select="tokenize($files, ';')">
                <xsl:copy-of select="document(.)/*" />
            </xsl:for-each>
        </html>
    </xsl:template>

</xsl:stylesheet>

Фактический список имен файлов предназначен для передачи извне, а не жесткимзакодированы.Это облегчает интеграцию в пакетные процессы.

Вы можете варьировать подход.Например,

  • Если все документы имеют одинаковый суффикс, вы можете составить список номеров и использовать
    document(concat(., '_Figuration_transformiert.xml')).
  • Если имеется фиксированное количество документов и пробелов в числах нет, вы можете использовать
    <xsl:for-each select="1 to 19">.
  • Если начало и конец цикла являются переменными,вы можете сделать для них <xsl:param> и использовать
    <xsl:for-each select="$start to $end">.
...