Тестовое выражение XSLT для проверки уровня URL - PullRequest
Новая
       7

Тестовое выражение XSLT для проверки уровня URL

0 голосов
/ 12 декабря 2018

Учитывая следующие URL-адреса, как определить, сколько уровней находится на глубине пути?

https://example.com/{product}/
https://example.com/(product}/{vendor}
https://example.com/{product}/{vendor}/{location}

Это переменные строки: product, vendor, location

У меня есть этот код, который я использую для путей с постоянными значениями: 

<xsl:variable name="itemURL">
  <xsl:value-of select="sitemap:loc"/>
</xsl:variable>

<td>
  <xsl:if test="contains($itemURL, '/Section/')">
    <xsl:attribute  name="class">section</xsl:attribute>
  </xsl:if>
  <xsl:if test="contains($itemURL, '/Category/')">
    <xsl:attribute  name="class">category</xsl:attribute>
  </xsl:if>
  <xsl:if test="contains($itemURL, '/Product/')">
    <xsl:attribute  name="class">product</xsl:attribute>
  </xsl:if>-->
  <a href="{$itemURL}">
    <xsl:value-of select="sitemap:loc"/>
  </a>
</td>

CSS для этих простых констант: 

.section {
    font-weight: 600;    
}

.category {
    font-weight: 500;
    padding-left: 15px;
}

.product {
    padding-left: 30px;
    font-style: italic;
}

Что я хочу сделать, это сделать отступ или добавить маркер или что-то с помощью css позже, когда список URL перейдет на другой уровень.По сути, я хочу вложить это так, чтобы людям было легче читать.Должен ли я использовать регулярные выражения здесь или есть лучший способ, который чистый XSLT?

1 Ответ

0 голосов
/ 13 декабря 2018

Рассмотрим следующий пример:

XML 

<root>
    <URL>https://example.com</URL>
    <URL>https://example.com/product</URL>
    <URL>https://example.com/product/vendor</URL>
    <URL>https://example.com/product/vendor/location</URL>
</root>

XSLT 1.0 

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/root">
    <results>
        <xsl:for-each select="URL">
            <xsl:variable name="path" select="substring-after(., 'https://example.com')" />
            <xsl:variable name="slashes" select="translate($path, translate($path, '/', ''), '')"/>
            <result>
                <xsl:value-of select="translate($slashes, '/', '•')"/>  
                <xsl:value-of select="$path"/>  
            </result>
        </xsl:for-each>
    </results>
</xsl:template>

</xsl:stylesheet>

Результат 

<?xml version="1.0" encoding="UTF-8"?>
<results>
  <result/>
  <result>•/product</result>
  <result>••/product/vendor</result>
  <result>•••/product/vendor/location</result>
</results>

Или:

XSLT 1.0 

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/root">
    <results>
        <xsl:for-each select="URL">
            <xsl:variable name="path" select="substring-after(., 'https://example.com')" />
            <xsl:variable name="count-slashes" select="string-length(translate($path, translate($path, '/', ''), ''))"/>
            <result>
                <xsl:attribute name="class">
                    <xsl:choose>
                        <xsl:when test="$count-slashes=1">product</xsl:when>
                        <xsl:when test="$count-slashes=2">vendor</xsl:when>
                        <xsl:when test="$count-slashes=3">location</xsl:when>
                        <xsl:otherwise>URL</xsl:otherwise>
                    </xsl:choose>
                </xsl:attribute>
                <xsl:value-of select="."/>  
            </result>
        </xsl:for-each>
    </results>
</xsl:template>

</xsl:stylesheet>

Результат 

<?xml version="1.0" encoding="UTF-8"?>
<results>
  <result class="URL">https://example.com</result>
  <result class="product">https://example.com/product</result>
  <result class="vendor">https://example.com/product/vendor</result>
  <result class="location">https://example.com/product/vendor/location</result>
</results>
...