Как удалить дубликаты из одного столбца Power Query, не удаляя записи строк?

Question

У меня есть объединенный запрос, в котором мне нужно удалить дубликаты для моего столбца «Счет-фактура + налог», не удаляя всю строку для этого дубликата.Мне просто нужно удалить дубликаты значений для этого одного столбца.Как видно из рисунка ниже, я пытаюсь удалить повторяющиеся значения из столбца «Счет-фактура + налог».Но мне нужно сохранить строку, просто удалите дублирующиеся значения, например, я выделил ниже то, что должно быть удалено, все, что не выделено, должно остаться.Я также добавил свой код к этому пункту под картинкой.

let
Order = Order,
Source = Sql.Database("jansql01", "mas500_app"),
dbo_vdvInvoiceLine = Source{[Schema="dbo",Item="vdvInvoiceLine"]}[Data],
#"Removed Other Columns" = Table.SelectColumns(dbo_vdvInvoiceLine,{"Description", "ItemID", "STaxClassID", "ExtAmt", "FreightAmt", "TranID", "TradeDiscAmt", "FormattedGLAcctNo", "Segment1", "Segment2", "Segment3", "SalesOrder", "CustID", "CustName", "TranDate", "PostDate", "City", "StateID", "ItemClassID", "UseTaxRate", "ReleaseSO", "Job Number"}),
#"Filtered Rows" = Table.SelectRows(#"Removed Other Columns", each Text.Contains([SalesOrder], Order)),
#"Added Material Column" = Table.AddColumn(#"Filtered Rows", "Material", each if [ItemClassID] <> "INSTALLATION" then [ExtAmt] else 0),
#"Added Installation Column" = Table.AddColumn(#"Added Material Column", "Installation", each if [ItemClassID] = "INSTALLATION" then [ExtAmt] else 0),
#"Merged Queries" = Table.NestedJoin(#"Added Installation Column",{"TranID"},vdvInvoice,{"TranID"},"vdvInvoice",JoinKind.LeftOuter),
#"Expanded vdvInvoice" = Table.ExpandTableColumn(#"Merged Queries", "vdvInvoice", {"STaxAmt"}, {"vdvInvoice.STaxAmt"}),
#"Extracted Date" = Table.TransformColumns(#"Expanded vdvInvoice",{{"TranDate", DateTime.Date, type date}, {"PostDate", DateTime.Date, type date}}),
#"Added Invoice+Tax" = Table.AddColumn(#"Extracted Date", "Invoice+Tax", each [TranID]&Number.ToText([vdvInvoice.STaxAmt]))

in
#"Added Invoice+Tax"

Answer 1

Вот еще один подход, просто для черта:

После вашей строки, которая говорит, #"Added Invoice+Tax" = Table.AddColumn(#"Extracted Date", "Invoice+Tax", each [TranID]&Number.ToText([vdvInvoice.STaxAmt])), добавьте запятую, а затем вместо

in
#"Removed Columns"

добавьтеthis:

#"Grouped Rows" = Table.Group(#"Added Invoice+Tax", {"Invoice+Tax"}, {{"AllData", each Table.FromColumns({[Installation],[vdvInvoice.STaxAmt],{[#"Invoice+Tax"]{0}}},{"Installation", "vdvInvoice.STaxAmt", "Invoice+Tax"}), type table}}),
#"Removed Other Columns2" = Table.SelectColumns(#"Grouped Rows",{"AllData"}),
#"Expanded AllData" = Table.ExpandTableColumn(#"Removed Other Columns2", "AllData", {"Installation", "vdvInvoice.STaxAmt", "Invoice+Tax"}, {"Installation", "vdvInvoice.STaxAmt", "Invoice+Tax"})
in
#"Expanded AllData"

Что делает строка #Grouped Rows выше, так это то, что она группируется по Invoice + Tax, с вложенной таблицей для каждого Invoice + Tax из столбцов исходной таблицы. Но впри создании каждой вложенной таблицы, когда она извлекает все строки установки и vdvInvoice.STaxAmt, связанные с каждым счетом-фактурой + налогом из исходной таблицы, она извлекает только первую строку-счет-фактуру + налогсвязанный с каждым счетом-фактурой + налогом из исходной таблицы. Table.FromColumns({[Installation],[vdvInvoice.STaxAmt],{[#"Invoice+Tax"]{0}}}... в основном говорит о том, чтобы получить все строки в столбцах Installation и vdvInvoice.STaxAmt, и только элемент списка 0 (строка 1) списка, который фактически является столбцом Invoice + Tax.

Полный запрос: Ваш начальный запрос, который вы указали выше с добавлением моей маленькой части, будет:

let
Order = Order,
Source = Sql.Database("jansql01", "mas500_app"),
dbo_vdvInvoiceLine = Source{[Schema="dbo",Item="vdvInvoiceLine"]}[Data],
#"Removed Other Columns" = Table.SelectColumns(dbo_vdvInvoiceLine,{"Description", "ItemID", "STaxClassID", "ExtAmt", "FreightAmt", "TranID", "TradeDiscAmt", "FormattedGLAcctNo", "Segment1", "Segment2", "Segment3", "SalesOrder", "CustID", "CustName", "TranDate", "PostDate", "City", "StateID", "ItemClassID", "UseTaxRate", "ReleaseSO", "Job Number"}),
#"Filtered Rows" = Table.SelectRows(#"Removed Other Columns", each Text.Contains([SalesOrder], Order)),
#"Added Material Column" = Table.AddColumn(#"Filtered Rows", "Material", each if [ItemClassID] <> "INSTALLATION" then [ExtAmt] else 0),
#"Added Installation Column" = Table.AddColumn(#"Added Material Column", "Installation", each if [ItemClassID] = "INSTALLATION" then [ExtAmt] else 0),
#"Merged Queries" = Table.NestedJoin(#"Added Installation Column",{"TranID"},vdvInvoice,{"TranID"},"vdvInvoice",JoinKind.LeftOuter),
#"Expanded vdvInvoice" = Table.ExpandTableColumn(#"Merged Queries", "vdvInvoice", {"STaxAmt"}, {"vdvInvoice.STaxAmt"}),
#"Extracted Date" = Table.TransformColumns(#"Expanded vdvInvoice",{{"TranDate", DateTime.Date, type date}, {"PostDate", DateTime.Date, type date}}),
#"Added Invoice+Tax" = Table.AddColumn(#"Extracted Date", "Invoice+Tax", each [TranID]&Number.ToText([vdvInvoice.STaxAmt])),
#"Grouped Rows" = Table.Group(#"Added Invoice+Tax", {"Invoice+Tax"}, {{"AllData", each Table.FromColumns({[Installation],[vdvInvoice.STaxAmt],{[#"Invoice+Tax"]{0}}},{"Installation", "vdvInvoice.STaxAmt", "Invoice+Tax"}), type table}}),
#"Removed Other Columns2" = Table.SelectColumns(#"Grouped Rows",{"AllData"}),
#"Expanded AllData" = Table.ExpandTableColumn(#"Removed Other Columns2", "AllData", {"Installation", "vdvInvoice.STaxAmt", "Invoice+Tax"}, {"Installation", "vdvInvoice.STaxAmt", "Invoice+Tax"})
in
#"Expanded AllData"

Answer 2

Я не могу придумать причину, чтобы сделать это, но если вы действительно хотите, замените два нижних ряда на

#"Added Index" = Table.AddIndexColumn(#"Added Invoice+Tax", "Index", 0, 1),
#"Added Custom" = Table.AddColumn(#"Added Index", "Invoice+Tax2", each if [Index]=0 then [#"Invoice+Tax"] else if #"Added Index"{[Index]-1}[#"Invoice+Tax"]=[#"Invoice+Tax"] then null else [#"Invoice+Tax"]),
#"Removed Columns" = Table.RemoveColumns(#"Added Custom",{"Index"})
in
#"Removed Columns"