Подмодульная процедура на C-совместимом языке Fortran с bind (C) сообщает об ошибке при компиляции с помощью gfortran

Question

Рассмотрим следующий модуль Fortran Foo_mod и его подмодуль Foo_smod,

module CallbackInterface_mod

    abstract interface
        function getLogFunc4C_proc(ndim,Point) result(logFunc) bind(C)
            use, intrinsic :: iso_c_binding, only : c_int32_t, c_double, c_int
            integer(c_int32_t), intent(in)  :: ndim
            real(c_double), intent(in)      :: Point(ndim)
            real(c_double)                  :: logFunc
        end function getLogFunc4C_proc
    end interface

end module CallbackInterface_mod

!***********************************************************************************************************************************
!***********************************************************************************************************************************

module Foo_mod

    interface
    module subroutine runFoo4C(ndim, getLogFuncFromC, inputString, inputStringLen) bind(C, name="runFoo")
        use, intrinsic :: iso_c_binding, only: c_int32_t, c_char, c_funptr, c_f_procpointer, c_size_t
        use CallbackInterface_mod, only: getLogFunc4C_proc
        implicit none
        integer(c_int32_t) , intent(in)                         :: ndim
        character(len=1, kind=c_char), dimension(*), intent(in) :: inputString
        integer(c_size_t) , intent(in)                          :: inputStringLen
        type(c_funptr), intent(in), value                       :: getLogFuncFromC
    end subroutine runFoo4C
    end interface

contains

    subroutine runFoo(ndim, getLogFunc, string)
        use CallbackInterface_mod, only: getLogFunc4C_proc
        use, intrinsic :: iso_fortran_env, only: RK => real64
        implicit none
        integer :: ndim
        procedure(getLogFunc4C_proc)    :: getLogFunc
        character(*), intent(in)        :: string
        real(RK)                        :: Point(ndim)
        character(:), allocatable       :: mystring
        Point = [1._RK,1._RK]
        write(*,*) "Hi again, this is a call from inside runFoo!"
        write(*,*) "getLogFunc(2,[1,1]) = ", getLogFunc(ndim,Point)
        write(*,*) "string = ", string
    end subroutine

end module Foo_mod

!***********************************************************************************************************************************
!***********************************************************************************************************************************

submodule (Foo_mod) Foo_smod

contains

    module subroutine runFoo4C(ndim, getLogFuncFromC, InputString, inputStringLen) bind(C, name="runFoo")

        use, intrinsic :: iso_c_binding, only: c_double, c_int32_t, c_char, c_funptr, c_f_procpointer, c_size_t
        use CallbackInterface_mod, only: getLogFunc4C_proc
        implicit none
        integer(c_int32_t) , intent(in)                         :: ndim
        character(len=1, kind=c_char), dimension(*), intent(in) :: InputString
        integer(c_size_t) , intent(in)                          :: inputStringLen
        type(c_funptr), intent(in), value                       :: getLogFuncFromC
        procedure(getLogFunc4C_proc), pointer                   :: getLogFunc
        real(c_double)                                          :: Point(ndim)
        character(:), allocatable                               :: inputString4tran
        integer                                                 :: i

        write(*,*) "InputString: ", InputString(1:inputStringLen)
        allocate( character(len=inputStringLen) :: inputString4tran )
        do i=1,inputStringLen
            inputString4tran(i:i) = InputString(i)
        end do
        write(*,*) "inputString4tran: ", inputString4tran

        ! associate the input C procedure pointer to a Fortran procedure pointer
        call c_f_procpointer(cptr=getLogFuncFromC, fptr=getLogFunc)
        Point = [1._c_double, 1._c_double]
        write(*,*) "getLogFunc(ndim=2, [1._c_double, 1._c_double]): ", getLogFunc( ndim, Point )

        call runFoo(ndim, getLogFunc, inputString4tran)

    end subroutine runFoo4C

end submodule Foo_smod

Теперь этот код кажется мне совершенно надежным модулем Fortran, и он действительно компилируется и успешно связывается сПрограммы на Си через Intel Fortran Compiler 2018, как на Windows, так и на Linux, и работают правильно.Однако при компиляции с помощью gfortran 7.3.0 выдается следующая ошибка:

gfortran -c ../Foo_mod.f90
../Foo_mod.f90:54:18:

submodule (Foo_mod) Foo_smod
                1
Error: BIND(C) attribute at (1) can only be used for variables or common blocks

Проблема может быть решена, если я удалю атрибут bind(c) из интерфейса совместимой подпрограммы runFoo4C() в модулеFoo_mod, подобно следующему,

...
module subroutine runFoo4C(ndim, getLogFuncFromC, inputString, inputStringLen) ! bind(C, name="runFoo")
...

Однако компилятор Intel Fortran будет потом жаловаться на несовместимость интерфейса подпрограммы в модуле Foo_mod и реализацию подпрограммы в подмодуле Foo_smod.Мне кажется, это больше похоже на ошибку в GFORTRAN, чем на ошибку программирования.Но ваши комментарии приветствуются, прежде чем я сообщу об этом.

Answer 1

Мне совершенно ясно, что это ошибка gfortran, связанная с подмодулями.Поскольку это довольно недавнее добавление функции, не удивительно, что здесь и там могут быть ошибки.

Я прокомментирую, что, задавая такой вопрос здесь, мы настоятельно рекомендуем указать Minimal, Полный и проверяемый пример Поскольку вы не показываете модуль, с которым работает подмодуль, мы не можем сами проверить проблему без лишней дополнительной работы.