Вывод результатов регрессии SAS для достижения превосходства на одном листе

Question

Я хочу вывести свой результат регрессии SAS в Excel.
Код:

proc import datafile = 'cmds.csv'
out = Work.cmds
dbms = CSV;
run; 

ODS TAGSETS.EXCELXP 
file="dt.xls";
STYLE = STATISTICAL;

proc sort data=Work.Cmds out=Work.Cmds;
by year;
run;

proc reg data=Work.Cmds outest=want tableout;
by year;
model Investment = Size Growth_New Leverage complex Deficit pc_income_NEW Density/hcc adjrsq ;
ods output parameterestimates=want2;
run;

ODS TAGSETS.EXCELXP CLOSE;

Хотя он успешно создает файл Excel, он содержит много листов.Я хочу создать все вещи на одном листе.Как я могу это сделать?

Answer 1

Существуют опции в наборах тегов, в частности sheet_interval.Чтобы все переходили на одну страницу, задайте для параметра «Интервал листа» значение none.

ODS TAGSETS.EXCELXP file="dt.xls" STYLE = STATISTICAL options (sheet_interval='none');

Однако TAGSETS.EXCELXP создает файл XML, а не файл Excel.Если у вас SAS 9.4 TS1M4 +, я бы порекомендовал ODS EXCEL.

ods excel file="dt.xlsx" style=statistical options (sheet_interval = 'none');

Список всех опций для ODS TAGSETS.EXCELXP приведен здесь: https://support.sas.com/rnd/base/ods/odsmarkup/excelxp_help.html

Полный пример, который сгенерируетодна вкладка:

ods tagsets.excelxp file='C:\_localdata\demo.xls' options(sheet_interval='none');
proc sort data=sashelp.cars out=cars;
by origin;
run;

proc reg data=cars outest=demo tableout;
by origin;
model mpg_city = mpg_highway invoice cylinders;
ods output parameterEstimates=want;
run;

ods tagsets.excelxp close;