Запрос листов Google выберите, когда определенные значения - PullRequest
Новая
       27

Запрос листов Google выберите, когда определенные значения

0 голосов
/ 27 февраля 2019

Я пытаюсь заставить приведенную ниже формулу работать следующим образом: Получить значения для A, когда B совпадает со значениями для E (для выборки это будет 1,2,4,5,7,8).

=QUERY({IMPORTRANGE("1Cg9gx2IhBUYwElNXprNJnihixbMLJcK1DKzIClQDNwc";"DATA!A2:C")};"select Col1 Where Col3 >= date '"&TEXT(TODAY;"yyyy-mm-dd")&"'and Col3 <= date '"&TEXT(TODAY;"yyyy-mm-dd")&"'and Col2="&(E1:E2)&"";0)

пример данных: 

A   B   C           E
1   X   27/02/2019  X
2   Y   27/02/2019  Y
3   Z   27/02/2019  
4   X   27/02/2019  
5   Y   27/02/2019  
6   Z   27/02/2019  
7   X   27/02/2019  
8   Y   27/02/2019

Как мне это сделать?

Ответы [ 2 ]

0 голосов
/ 27 февраля 2019
  • QUERY не может обработать массив / диапазон внутри указанной части
  • TODAY должно быть с () как TODAY()
  • сегодня 28 февраля(по крайней мере, где мой лист живет) 
=QUERY(IMPORTRANGE("1Cg9gx2IhBUYwElNXprNJnihixbMLJcK1DKzIClQDNwc"; "DATA!A2:C");
 "select Col1 
  where Col3 >= date '"&TEXT(TODAY(); "yyyy-MM-dd")&"'
    and Col3 <= date '"&TEXT(TODAY(); "yyyy-MM-dd")&"'
    and (Col2 = '"&E1&"'
     or  Col2 = '"&E2&"')"; 0)

или попробуйте так, если у вас есть массив / диапазон значений: 

=QUERY(FILTER(IMPORTRANGE("1Cg9gx2IhBUYwElNXprNJnihixbMLJcK1DKzIClQDNwc"; "DATA!A2:C100"); 
 COUNTIF(E1:E100; "="&
 IMPORTRANGE("1Cg9gx2IhBUYwElNXprNJnihixbMLJcK1DKzIClQDNwc"; "DATA!B2:B100"))); 
 "select Col1 
   where Col3 >= date '"&TEXT(TODAY(); "yyyy-MM-dd")&"' 
     and Col3 <= date '"&TEXT(TODAY(); "yyyy-MM-dd")&"'"; 0)
0 голосов
/ 27 февраля 2019

Попробуйте для предложения "где": 

where  Col2='"&E3&"' or Col2 ='"&E2&"'

SO54912607 example

...