xsl 1,0 поле суммы в мюнхенской сумме для каждого составного ключа - PullRequest
Новая
       6

xsl 1,0 поле суммы в мюнхенской сумме для каждого составного ключа

0 голосов
/ 27 декабря 2018

Для сопоставления SAP PO xsl 1.0 мне нужно сопоставить «экзотический» файл, поступающий с нашего склада, где мне нужно сгруппировать / суммировать по заказу (RECH) поле QTY на комбинации идентификатора строки (MASTER_PO_LINE_NO) иАртикул (SKU).Каждая строка (RECL) находится в заголовке (RECH).

INPUT: 

    <?xml version="1.0" encoding="UTF-8"?>
<ns0:Messages xmlns:ns0="http://sap.com/xi/XI/SplitAndMerge">
   <ns0:Message1>
<MARCXML>
  <RCIC>
    <RECH>
      <SALESID>24000</SALESID>
      <RECL>
        <LINE_NO>1</LINE_NO>
        <QTY_EXPE>1592</QTY_EXPE>
        <SKU>11207-210</SKU>
        <MASTER_PO_LINE_NO>10</MASTER_PO_LINE_NO>
      </RECL>
      <RECL>
        <LINE_NO>2</LINE_NO>
        <QTY_EXPE>1000</QTY_EXPE>
        <SKU>11207-210</SKU>
        <MASTER_PO_LINE_NO>10</MASTER_PO_LINE_NO>
      </RECL>
      <RECL>
        <LINE_NO>3</LINE_NO>
        <QTY_EXPE>175</QTY_EXPE>
        <SKU>11207-210</SKU>
        <MASTER_PO_LINE_NO>20</MASTER_PO_LINE_NO>
      </RECL>
    </RECH>
    <RECH>
      <SALESID>25001</SALESID>
      <RECL>
        <LINE_NO>1</LINE_NO>
        <QTY_EXPE>440</QTY_EXPE>
        <SKU>20000-210</SKU>
        <MASTER_PO_LINE_NO>10</MASTER_PO_LINE_NO>
      </RECL>
    </RECH>
  </RCIC>
</MARCXML>
 </ns0:Message1>
</ns0:Messages>

Требуемый ВЫХОД (Кол-во для 11207-210 = 1592 + 1000): 

<?xml version="1.0" encoding="UTF-8"?>
<ns0:Messages xmlns:ns0="http://sap.com/xi/XI/SplitAndMerge">
   <ns0:Message1>
<MARCXML>
  <RCIC>
    <RECH>
      <SALESID>24000</SALESID>
      <RECL>
        <LINE_NO>1</LINE_NO>
        <QTY_EXPE>2592</QTY_EXPE>
        <SKU>11207-210</SKU>
        <MASTER_PO_LINE_NO>10</MASTER_PO_LINE_NO>
      </RECL>
      <RECL>
        <LINE_NO>3</LINE_NO>
        <QTY_EXPE>175</QTY_EXPE>
        <SKU>11207-210</SKU>
        <MASTER_PO_LINE_NO>20</MASTER_PO_LINE_NO>
      </RECL>
    </RECH>
    <RECH>
      <SALESID>25001</SALESID>
      <RECL>
        <LINE_NO>1</LINE_NO>
        <QTY_EXPE>440</QTY_EXPE>
        <SKU>20000-210</SKU>
        <MASTER_PO_LINE_NO>10</MASTER_PO_LINE_NO>
      </RECL>
    </RECH>
  </RCIC>
</MARCXML>
 </ns0:Message1>
</ns0:Messages>

Существует множество примеров группировок мюнхенцев, но мне пока не удалось выполнить мое требование.Честно говоря, я дошел до: 

<?xml version="1.0" encoding="UTF-8"?>
<ns0:Messages xmlns:ns0="http://sap.com/xi/XI/SplitAndMerge">
   <ns0:Message1>
      <MARCXML>
         <RCIC>
            <RECH>5284</RECH>
            <RECH>5284</RECH>
            <RECH>5284</RECH>
         </RCIC>
      </MARCXML>
   </ns0:Message1>
</ns0:Messages>

Со следующим xsl: 

<?xml version="1.0" encoding="UTF-8"?>


<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>


    <xsl:key name="kMSTR_PO_LN_SKU" match="RECL"
     use="concat(MASTER_PO_LINE_NO, '#', SKU)"/>


    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="RECH">
        <xsl:copy>
            <xsl:value-of select="sum(//MARCXML/RCIC/RECH/RECL/QTY_CHECKED_IN)" />

            <xsl:for-each select="/RECL[generate-id()=generate-id(key('kMSTR_PO_LN_SKU',concat(MASTER_PO_LINE_NO,'-',SKU))[1])]">
                <xsl:copy>
                    <SKU>
                        <xsl:value-of select="SKU"/>
                    </SKU>
                    <Quantity>
                        <xsl:value-of select="sum(key('kMSTR_PO_LN_SKU',concat(MASTER_PO_LINE_NO,'-',RECL))/QTY_EXPE)"/>
                    </Quantity>
                </xsl:copy>
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

Надеюсь, кто-нибудь может помочь мне на моем пути сюда

1 Ответ

0 голосов
/ 27 декабря 2018

AFAICT, это производит требуемый результат - но имея только один пример с несколько неоднозначными правилами, это может быть совпадением.В любом случае он должен предоставить вам начальную точку.

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="k1" match="RECL" use="concat(MASTER_PO_LINE_NO, '|', SKU)"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="RECH">
    <xsl:copy>
        <xsl:copy-of select="SALESID"/>
        <xsl:for-each select="RECL[generate-id()=generate-id(key('k1', concat(MASTER_PO_LINE_NO,'|',SKU))[1])]">
            <xsl:copy>
                <xsl:copy-of select="LINE_NO"/>
                <QTY_EXPE>
                    <xsl:value-of select="sum(key('k1', concat(MASTER_PO_LINE_NO,'|',SKU))/QTY_EXPE)" />
                </QTY_EXPE>
                <xsl:copy-of select="SKU | MASTER_PO_LINE_NO"/>
            </xsl:copy>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Добавлено:

Для того, чтобыСуммируйте каждый заказ (RECH) отдельно, необходимо добавить идентификатор ключа к ключу:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="k1" match="RECL" use="concat(MASTER_PO_LINE_NO, '|', SKU, '|', generate-id(..))"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="RECH">
    <xsl:copy>
        <xsl:copy-of select="SALESID"/>
        <xsl:for-each select="RECL[generate-id()=generate-id(key('k1', concat(MASTER_PO_LINE_NO,'|',SKU, '|', generate-id(..)))[1])]">
            <xsl:copy>
                <xsl:copy-of select="LINE_NO"/>
                <QTY_EXPE>
                    <xsl:value-of select="sum(key('k1', concat(MASTER_PO_LINE_NO,'|',SKU, '|', generate-id(..)))/QTY_EXPE)" />
                </QTY_EXPE>
                <xsl:copy-of select="SKU | MASTER_PO_LINE_NO"/>
            </xsl:copy>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>
...