Как создать подтаблицу с XSLT-1.0 - PullRequest
Новая
       7

Как создать подтаблицу с XSLT-1.0

0 голосов
/ 02 марта 2019

Я пытаюсь создать эту таблицу с XSLT и предоставленным XML: желаемая таблица

Это XML-код: 

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="baile.xsl"?>
<academia nombre="Trassierra">
    <curso id="C1" inicio="2019/10/01" fin="2020/06/30" nivel="intermedio">
        <baile>tango</baile>
        <imagen>imagenes/tango.jpeg</imagen>
        <profesor>Ricardo Buenos Aires</profesor>
        <sala>1</sala>
        <plazas>10</plazas>
        <horario>
            <dia>lunes</dia>
            <hora>17:00:00</hora>
            <dia>miercoles</dia>
            <hora>18:30:00</hora>
            <dia>viérnes</dia>
            <hora>18:00:00</hora>            
        </horario>
        <precio cuota="trimestral">55</precio>
        <matriculas>
            <alumno>
                <dni>30987123Z</dni>
                <nombre>Jose Maria Ortiz Ots</nombre>
            </alumno>
            <alumno>
                <dni>29876013J</dni>
                <nombre>Maria Gonzalo Hernandez</nombre>
            </alumno>
        </matriculas>        
    </curso>   
    <curso id="C2" inicio="2019/01/01" fin="2019/06/30" nivel="intermedio">
        <baile>salsa</baile>
        <imagen>imagenes/salsa.jpeg</imagen>
        <profesor>Raquel Langa</profesor>
        <sala>2</sala>
        <plazas>15</plazas>
        <horario>
            <dia>martes</dia>
            <hora>19:00:00</hora>
            <dia>jueves</dia>
            <hora>19:00:00</hora>            
        </horario>
        <precio cuota="mensual">20</precio>
        <matriculas>
            <alumno>
                <dni>30983123B</dni>
                <nombre>Jose Antonio Casado Alcaide</nombre>
            </alumno>
            <alumno>
                <dni>34987245H</dni>
                <nombre>Maria Angeles Luque Montes</nombre>
            </alumno>
        </matriculas>        
    </curso>    
    <curso id="C3" inicio="2019/03/01" fin="2019/03/30" nivel="iniciacion">
        <baile>bachata</baile>
        <imagen>imagenes/bachata.jpeg</imagen>
        <profesor>Raquel Langa</profesor>
        <sala>3</sala>
        <plazas>10</plazas>
        <horario>
            <dia>viernes</dia>
            <hora>19:00:00</hora>
        </horario>
        <matriculas>
            <alumno>
                <dni>39283827A</dni>
                <nombre>Manuel Jimenez Luque</nombre>
            </alumno>
            <alumno>
                <dni>29098373H</dni>
                <nombre>Luisa Medina Ortega</nombre>
            </alumno>
        </matriculas>        
    </curso>
    <curso id="C4" inicio="2019/07/01" fin="2019/08/30" nivel="intermedio">
        <baile>zumba</baile>
        <profesor>Antonio Rodríguez Luanda</profesor>
        <sala>1</sala>
        <plazas>5</plazas>
        <horario>
            <dia>viérnes</dia>
            <hora>21:00:00</hora>
            <dia>sábado</dia>
            <hora>22:00:00</hora>
        </horario>
        <matriculas>
            <alumno>
                <dni>30987092K</dni>
                <nombre>Marisa Paredes Sanchez</nombre>                
            </alumno>
            <alumno>
                <dni>29087296R</dni>
                <nombre>Maribel Henández Pons</nombre>
            </alumno>
            <alumno>
                <dni>29098373A</dni>
                <nombre>Luisa Medina Ortega</nombre>
            </alumno>
        </matriculas>        
    </curso>
</academia>

И эточто я пытаюсь сделать с XSLT-1.0 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="html"/>
    <xsl:template match="/">
        <html style="color: #369;">
            <head>
                <title>baile.xsl</title>
            </head>
            <body>
                <h1>
                    <strong>Curso de tango</strong>
                </h1>
                <p>
                    <img src="imagenes/tango.jpeg"  align="center"  height="100"/>
                </p>
                <table border="1" style="border-collapse">
                    <thead> 
                        <strong>
                            <th style="text-aling:center">Profesor</th>
                            <th style="text-aling:center">Nº Plazas</th>
                            <th colspan="2" style="text-aling:center">Horario</th>
                        </strong>
                    </thead>
                    <tbody> 
                        <xsl:for-each select="academia/curso" >
                            <xsl:if test="baile='tango'">
                                <tr>
                                    <td rowspan="4">
                                        <xsl:value-of select="profesor"/>
                                    </td>
                                    <td rowspan="4">
                                        <xsl:value-of select="plazas"/>
                                    </td>
                                    <td>
                                        <table> 

                                            <tr>
                                                <xsl:for-each select="horario"> 



                                                    <tr>     
                                                        <xsl:for-each select="dia"> 
                                                          <td>
                                                                <xsl:value-of select="/."/> 

                                                            </td>  
                                                        </xsl:for-each>
                                                        <xsl:for-each select="hora"> 
                                                            <td>
                                                                <xsl:value-of select="/."/> 

                                                            </td>
                                                        </xsl:for-each>
                                                    </tr>


                                                </xsl:for-each>

                                            </tr>

                                        </table>
                                    </td>
                                </tr>
                            </xsl:if>
                        </xsl:for-each>
                    </tbody> 
                </table>                         
                <h2>Matriculados</h2>
                <table border="1" style="border-collapse:separate;border-spacing:2px">
                    <xsl:for-each select="academia/curso/baile/matriculas">
                        <xsl:if test="baile='tango'">
                            <tr>
                                <td>
                                    <xsl:value-of select="nombre"/>
                                </td>
                                <td>
                                    <xsl:value-of select="dni"/>
                                </td>
                            </tr>
                        </xsl:if>
                    </xsl:for-each>
                </table> 
            </body>
        </html>
    </xsl:template>
</xsl:stylesheet>

Вывод таблицы "horario" - все в одну строку, я знаю, что, возможно, мне придется перебирать "horario" и извлекать каждый "день""и" час ", но я не могу знать, как это сделать, я могу получить только одну пару или все в одной строке.

Любая помощь?

Большое спасибо, иС уважением

1 Ответ

0 голосов
/ 03 марта 2019

Я отладил и реорганизовал вашу таблицу стилей XSLT:

  • У вас была опечатка: text-aling:center должно было быть text-align:center
  • td не нужноrowspan="4" attribute
  • Вы по ошибке поместили тег <strong> в блок тегов таблицы вместо одного текстового тега.

  • Я разбил ваш шаблон на две части:

    • часть HTML
    • часть curso

Таким образом, изменение XSLT на следующее должно улучшить ваш результат:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="html"/>

  <xsl:template match="/academia">
    <html style="color: #369;">
      <head>
        <title>baile.xsl</title>
      </head>
      <body>
        <h1>
          <strong>Curso de tango</strong>
        </h1>
        <p>
          <img src="imagenes/tango.jpeg" align="center" height="100"/>
        </p>
        <table border="1" style="border-collapse">
          <thead>
            <th style="text-align:center">Profesor</th>
            <th style="text-align:center">Nº Plazas</th>
            <th colspan="2" style="text-align:center">Horario</th>
          </thead>
          <xsl:apply-templates select="curso"/>
        </table>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="curso">
    <tr>
      <td rowspan="1">
        <xsl:value-of select="profesor"/>
      </td>
      <td rowspan="1" style="text-align:center">
        <xsl:value-of select="plazas"/>
      </td>
      <td>
        <table border="1">
          <xsl:for-each select="horario">
            <xsl:for-each select="dia">
              <tr>
                <td>
                  <xsl:value-of select="."/>
                </td>
                <td>
                  <xsl:value-of select="following-sibling::hora[1]"/>
                </td>
              </tr>
            </xsl:for-each>
          </xsl:for-each>
        </table>
      </td>
    </tr>
    <h2>Matriculados</h2>
    <table border="1" style="border-collapse:separate;border-spacing:2px">
      <xsl:for-each select="matriculas/alumno[../../baile='tango']">
        <tr>
          <td>
            <xsl:value-of select="nombre"/>
          </td>
          <td>
            <xsl:value-of select="dni"/>
          </td>
        </tr>
      </xsl:for-each>
    </table>
  </xsl:template>

</xsl:stylesheet>

Частичный вывод:

enter image description here

...