Обработка кузнечика с помощью oscP5 - PullRequest
Новая
       52

Обработка кузнечика с помощью oscP5

0 голосов
/ 30 декабря 2018

Я пытаюсь понять, могу ли я связать набросок, сделанный в процессе обработки, с кузнечиком, используя oscP5.Эскиз - это сфера точек, очерченных в первой половине этого видео Coding Train:

https://www.youtube.com/watch?v=RkuBWEkBrZA

Код до того, как я начал связывать его с oscP5, работает нормально: 

import peasy.*;

PeasyCam cam;

PVector[][] globe;
int total = 20;

void setup() {
  size(600, 600, P3D);
  cam = new PeasyCam(this, 500);

  globe = new PVector[total+1][total+1];
}

void draw() {
  background(0);
  fill(255);
  lights();

  float r = 200;

  for (int i = 0; i < total+1; i++) {
    float lat = map(i, 0, total, 0, PI);
    for (int j = 0; j < total+1; j++) {
      float lon = map(j, 0, total, 0, TWO_PI);
      float x = r * sin(lat) * cos(lon);
      float y = r * sin(lat) * sin(lon);
      float z = r * cos(lat);   
      globe[i][j] = new PVector(x, y, z);        
    }
  }
  noFill();   
  for (int i = 0; i < total; i++) {
    beginShape(TRIANGLE_STRIP); 
    for (int j = 0; j < total+1; j++) {
      PVector v1 = globe[i][j];
      stroke(255);
      strokeWeight(2);
      vertex(v1.x, v1.y, v1.z);   

      PVector v2 = globe[i+1][j];
      vertex(v2.x, v2.y, v2.z); 
    }
    endShape();
  }
}

Однако, когда я пытаюсь реализовать oscP5, он не совсем работает.Мой файл кузнечика получает скепсис нормально, но точки не верны, поэтому у меня должна быть проблема с тем, с какими данными я отправляю, но я не могу понять, что я должен отправлять вместо этого.Код берет значения указанного радиуса, долготы и широты и преобразует их в координаты x, y, z, и я пытался заставить oscP5 отправить эти координаты x, y, z.

У кого-нибудь есть идеи?Код ниже приведен ниже. 

//import necessary libraries
import oscP5.*;
import netP5.*;

OscP5 oscP5;
NetAddress myRemoteLocation;

//import camera
import peasy.*;

PeasyCam cam;

// message to send
String message;

PVector[][] sphere;
int total = 20;

float lat;
float lon;

void setup() {
  size(600, 600, P3D);
  cam = new PeasyCam(this, 500);

  sphere = new PVector[total+1][total+1];

//send message from this port
  oscP5 = new OscP5(this,12000);      
//send message to this port
  myRemoteLocation = new NetAddress("127.0.0.1",12001);
}

void draw() {
  background(0);
  fill(255);
  lights();

  float r = 200;

  for (int i = 0; i < total+1; i++) {
    float lat = map(i, 0, total, 0, PI);
    for (int j = 0; j < total+1; j++) {
      float lon = map(j, 0, total, 0, TWO_PI);
      float x = r * sin(lat) * cos(lon);
      float y = r * sin(lat) * sin(lon);
      float z = r * cos(lat);   
      sphere[i][j] = new PVector(x, y, z);        
    }
  }
  noFill();    
  for (int i = 0; i < total; i++) {
    beginShape(TRIANGLE_STRIP); 
    for (int j = 0; j < total+1; j++) {
      PVector v1 = sphere[i][j];
      stroke(255);
      strokeWeight(2);
      vertex(v1.x, v1.y, v1.z);   

      PVector v2 = sphere[i+1][j];
      vertex(v2.x, v2.y, v2.z); 
    }
    endShape();
  }

// osc message
  OscMessage myMessage = new OscMessage("/hello world");


for (int j = 0; j < total+1; j++) {
//message to send 
message  = "x = " + String.valueOf(r * sin(lat) * cos(lon)) + "; " + 
           "y = " + String.valueOf(r * sin(lat) * sin(lon))+ "; " +
           "z = " + String.valueOf(r * cos(lat))+ "; " ;

    myMessage.add(String.valueOf(r * sin(lat) * cos(lon)));
    myMessage.add(String.valueOf(r * sin(lat) * sin(lon))); 
    myMessage.add(String.valueOf(r * cos(lat))); 
  }

//print message
  println(message);
//send message
  oscP5.send(myMessage, myRemoteLocation);
}

Я считаю, что ошибка в этом разделе кода 

for (int j = 0; j < total+1; j++) {
//message to send 
message  = "x = " + String.valueOf(r * sin(lat) * cos(lon)) + "; " + 
           "y = " + String.valueOf(r * sin(lat) * sin(lon))+ "; " +
           "z = " + String.valueOf(r * cos(lat))+ "; " ;

    myMessage.add(String.valueOf(r * sin(lat) * cos(lon)));
    myMessage.add(String.valueOf(r * sin(lat) * sin(lon))); 
    myMessage.add(String.valueOf(r * cos(lat))); 
  }

Любая помощь будет удивительной.

1 Ответ

0 голосов
/ 31 декабря 2018

Значения глобальных переменных float lat; никогда не устанавливаются float lon;, поскольку во вложенных циклах for объявлены 2 новые локальные переменные (в областях блоков цикла): 

for (int i = 0; i < total+1; i++) {
float lat = map(i, 0, total, 0, PI);
    for (int j = 0; j < total+1; j++) {
        float lon = map(j, 0, total, 0, TWO_PI);

        // [...]
    }
}

Примечание, float lat = ... объявляет новую переменную, lat = ... будет присваиванием существующей переменной lat.

Но использование глобальных переменных вместо установки новых ничего не изменит, потому чтокогда сообщение отправлено, переменные lat и lon будут иметь значение последней итерации вложенных циклов.

Вы должны реализовать 2 новых цикла и пересчитать значения для lat и lon.Оператор print после цикла не имеет никакого смысла, поскольку он будет печатать только последние координаты.

Код должен выглядеть примерно так: 

// osc message
OscMessage myMessage = new OscMessage("/hello world");

for (int i = 0; i < total+1; i++) {
    float lat = map(i, 0, total, 0, PI);
    for (int j = 0; j < total+1; j++) {
        float lon = map(j, 0, total, 0, TWO_PI);

        float x = r * sin(lat) * cos(lon);
        float y = r * sin(lat) * sin(lon);
        float z = r * cos(lat);
        println("(", i, ",", j, ") : x =" , x, "y = ", y, "z = ", z);

        myMessage.add(String.valueOf(x));
        myMessage.add(String.valueOf(y)); 
        myMessage.add(String.valueOf(z)); 
    }
}

//send message
oscP5.send(myMessage, myRemoteLocation);
...