Формула DAX, чтобы найти разницу MIN и% - PullRequest
Новая
       13

Формула DAX, чтобы найти разницу MIN и%

0 голосов
/ 19 сентября 2019

Мне нужна помощь с использованием правильной формулы DAX, чтобы найти минимальное значение в столбце, а затем оценить каждое значение строки на основе этого минимума (насколько выше каждое число в%).

Моя таблица выглядит какследующим образом:

https://1drv.ms/u/s!AlRG3cDrsAZTgeF4aurEanDadvVa3w?e=NKWlRQ

Я пытаюсь получить результаты в третьем и четвертом столбцах, которые основаны на втором столбце.

1 Ответ

2 голосов
/ 19 сентября 2019

DAX вычисляемые столбцы: 

Minimum = MIN ( 'Table'[Sedan] )

% Difference = ( 'Table'[Sedan] - 'Table'[Minimum] ) / 'Table'[Sedan]

Убедитесь, что для формата данных столбца установлено значение% для секунды.

Агрегированные функции не зависят от контекста строки, поэтому примы определяем «Таблица» [Минимум], это просто захват всей таблицы мин.Затем мы можем просто использовать недавно вычисленный столбец в простой% разницы с существующей «Таблицей» [Седан].В контексте строки ссылки на столбцы являются значениями для текущей строки.

EDIT : для комментариев целью является взаимодействие с фильтрами, поэтому оно не может находиться в вычисляемом столбце.

Меры ниже:

Ваш мин будет зависеть от того, как вы создаете свои визуальные эффекты и отчеты, которыми вы не поделились с нами.Две версии ниже: 

//v1
Minimum = MIN ( 'Table'[Sedan] )

//v2
Minimum = CALCULATE ( MIN ( 'Table'[Sedan] ), ALLSELECTED ( 'Table' ) )

И разница в%.Опять же, это будет зависеть от того, как вы создаете отчеты, которыми вы не поделились.Первая версия работает с первой версией выше, предполагая, что вы просматриваете много строк одновременно и хотите получить среднюю разницу в процентах: 

//v1
% Difference =
VAR MinValue = [Minimum]
RETURN
  AVERAGEX (
    'Table',
    ( 'Table'[Sedan] - MinValue ) / MinValue
  )

Со второй версией, я полагаю, вы ставите 'Таблица '[Седан] в визуальном, так что вы видите различные значения: 

//v2
% Difference =
VAR CurrentSedan = SELECTEDVALUE ( 'Table'[Sedan] )
VAR MinValue = [Minimum]
RETURN
  (CurrentSedan - MinValue) / MinValue
...