загрузка больших объемов данных, похожих на линейный сюжет Python для matplotlib-seaborn - PullRequest
Новая
       93

загрузка больших объемов данных, похожих на линейный сюжет Python для matplotlib-seaborn

0 голосов
/ 01 октября 2019

У меня есть большой набор данных, который берет возрасты до начальной загрузки и строит график с линейным сюжетом Seaborn . Я хочу попробовать построить это с Gnuplot. Как представ можно экспортировать набор данных fmri морского происхождения: 

import seaborn as sns; sns.set()
fmri = sns.load_dataset("fmri")
fmr.to_csv('out.csv')

         <img src="https://seaborn.pydata.org/_images/seaborn-lineplot-1.png" width="500">
                              image courtesy of pydata.org.

Буду признателен, если вы поможете мне узнать, возможно ли это сделать в Gnuplot,

1 Ответ

1 голос
/ 01 октября 2019

Для создания этого графика я использовал файл с именем data.dat, содержащий 4 столбца. 

#  x      y    ylow   yhigh
 0.000  0.004  0.004  0.005
 1.000  0.029  0.024  0.022
 2.000  0.137  0.089  0.063
 3.000  0.414  0.176  0.116
 4.000  0.806  0.185  0.148
 5.000  1.011  0.154  0.154
 6.000  0.821  0.192  0.153
 7.000  0.445  0.188  0.129
 8.000  0.189  0.109  0.085
 9.000  0.110  0.056  0.054
10.000  0.118  0.049  0.051
11.000  0.152  0.061  0.061
12.000  0.189  0.076  0.075
13.000  0.221  0.089  0.088
14.000  0.242  0.097  0.097
15.000  0.250  0.100  0.100
16.000  0.242  0.097  0.097
17.000  0.221  0.089  0.088
18.000  0.189  0.076  0.075
19.000  0.152  0.061  0.060
20.000  0.114  0.045  0.046

Сценарий gnuplot: 

reset
# Setting encoding
set encoding utf8
# Setting terminal
set terminal wxt font "Ubuntu,10"
# Turn-off the key/legend
unset key
# Setting the grid 
set grid ls -1 lw 1 lc "white" back
# Setting the tick marks
set tics scale 0.001
# Axes' ranges
set xrange [-1:21]
set yrange [-0.1:1.25]
# Axes' labels
set xlabel "timepoint"
set ylabel "signal"
# Formats to ticks
set format x "%.1f"
set format y "%.2f"
# Force the entire area enclosed by the axes to have background color gray
set object rectangle from graph 0,0 to graph 1,1 fc rgb "gray" fs transp solid 0.5 noborder behind
# Styles to line and filledcurves
set style line 1 lc rgb "#0060ad" lt 1 lw 1.5 # -> blue
set style fill transparent solid 0.5
# The graph itself
plot \
    "data.dat" u 1:($2-$3):($2+$4) w filledcurves ls 1,\
    "data.dat" u 1:2 w lines ls 1

Результат:

graph

...