XSLT позиция предшествующего брата с условием - PullRequest
Новая
       16

XSLT позиция предшествующего брата с условием

1 голос
/ 05 ноября 2019

Мне нужно понять, как я могу получить положение параллельного элемента с аналогичным значением в подэлементе, выбранном с помощью XSL. У меня есть строки элементов, перечисленные с определенной ссылкой как подэлемент, а затем у меня есть строки подэлементов, которые должны быть связаны в строки элементов на основе значения подэлемента. Строки подпунктов должны указывать положение строк элементов с похожей ссылкой

. Я пробовал несколько предыдущих подходов с разными условиями в скобках [], но пока безуспешно. Я могу использовать только xslt 1.0

У меня есть XML с такой структурой: 

<goods>
    <item>
        <ref>a</ref>
    </item>
    <item>
        <ref>b</ref>
    </item>
    <item>
        <ref>c</ref>
    </item>
    <item>
        <ref>d</ref>
    </item>
    <subitem>
        <subref>c</subref>
    </subitem>
    <subitem>
        <subref>a</subref>
    </subitem>
</goods>

и мой xsl (1.0): 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
    <xsl:output method="text" version="1.0" encoding="ISO-8859-1" indent="yes"/>
    <xsl:template match="/">
        <xsl:call-template name="Line"/>
    </xsl:template>
    <xsl:template name="Line">
        <xsl:for-each select="goods/item">
            <xsl:value-of select="position()"/>
            <xsl:text>;</xsl:text>
            <xsl:value-of select="ref"/>
            <xsl:text>&#xD;</xsl:text>
        </xsl:for-each>
        <xsl:for-each select="goods/subitem">
            <xsl:text>0;</xsl:text>
            <xsl:value-of select="subref"/>
            <xsl:text>;</xsl:text>
            here would be some kind of conditional preceeding select needed
            <xsl:text>&#xD;</xsl:text>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Желаемый результат будет: 

1;a
2;b
3;c
4;d
0;c;3
0;a;1

, где 2 последние строки являются подпунктами, а последнее число должно указывать мне позицию элемента-элемента, где указана та же ссылка. В примере ссылка 'c' находится внутри элемента item с позицией 3 (третий элемент-элемент имеет 'c' в подэлементе 'ref'), поэтому подэлемент со значением subref 'c' должен быть связан, например, с позицией 3 элемента.

То же самое будет с каждой строкой подпункта: все с подпунктом / subref = a должны иметь позицию 1, все с позицией 'b' 2 и т. Д.

1 Ответ

2 голосов
/ 05 ноября 2019

Вот один из способов посмотреть на это:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:key name="item" match="item" use="ref" />

<xsl:template match="/goods">
    <xsl:for-each select="item">
        <xsl:value-of select="position()" />
        <xsl:text>;</xsl:text>
        <xsl:value-of select="ref"/>
        <xsl:text>&#xD;</xsl:text>
    </xsl:for-each>
    <xsl:for-each select="subitem">
        <xsl:text>0;</xsl:text>
        <xsl:value-of select="subref"/>
        <xsl:text>;</xsl:text>
        <xsl:value-of select="count(key('item', subref)/preceding-sibling::item) +1" />
        <xsl:text>&#xD;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

Обратите внимание, что это предполагает, что каждый subref имеет соответствующийitem с соответствующим значением ref.

...