XSLT конвертирует XML в Txt с разделителями по трубам - транспонирует строки в столбцы

Question

Мне нужна помощь в преобразовании элементов строки в столбцы с использованием XSLT и создании текстового файла с разделителями. Обратите внимание, что количество элементов wd: Pay_Input для каждого wd: Report_Entry является переменным.

XML:

<wd:Report_Data xmlns:wd="urn:com.workday.report/ERP-PAY-CR-ELEMENT_ENTRY">
<wd:Report_Entry>
<wd:UNIQUE_IDENTIFIER>2204052</wd:UNIQUE_IDENTIFIER>
<wd:ASSIGNMENT_NUMBER>2204052-08012016</wd:ASSIGNMENT_NUMBER>
<wd:Pay_Input>
<wd:ELEMENT_NAME>ADDN</wd:ELEMENT_NAME>
<wd:INPUT_VALUE>0.23</wd:INPUT_VALUE>
</wd:Pay_Input>
<wd:Pay_Input>
<wd:ELEMENT_NAME>ASTDSB</wd:ELEMENT_NAME>
<wd:INPUT_VALUE>28.08</wd:INPUT_VALUE>
</wd:Pay_Input>
<wd:Pay_Input>
<wd:ELEMENT_NAME>LIFEN</wd:ELEMENT_NAME>
<wd:INPUT_VALUE>1.73</wd:INPUT_VALUE>
</wd:Pay_Input>
<wd:Pay_Input>
<wd:ELEMENT_NAME>MEDB</wd:ELEMENT_NAME>
<wd:INPUT_VALUE>34.04</wd:INPUT_VALUE>
</wd:Pay_Input>
</wd:Report_Entry>
<wd:Report_Entry>
<wd:UNIQUE_IDENTIFIER>2127766</wd:UNIQUE_IDENTIFIER>
<wd:ASSIGNMENT_NUMBER>2127766-02052000</wd:ASSIGNMENT_NUMBER>
<wd:Pay_Input>
<wd:ELEMENT_NAME>ADDN</wd:ELEMENT_NAME>
<wd:INPUT_VALUE>1.52</wd:INPUT_VALUE>
</wd:Pay_Input>
<wd:Pay_Input>
<wd:ELEMENT_NAME>ADDN</wd:ELEMENT_NAME>
<wd:INPUT_VALUE>1.9</wd:INPUT_VALUE>
</wd:Pay_Input>
<wd:Pay_Input>
<wd:ELEMENT_NAME>LIFEN</wd:ELEMENT_NAME>
<wd:INPUT_VALUE>25.89</wd:INPUT_VALUE>
</wd:Pay_Input>
</wd:Report_Entry>
</wd:Report_Data>

Ожидаемый результат:

UNIQUE_IDENTIFIER|ASSIGNMENT_NUMBER|ELEMENT_NAME|INPUT_VALUE|ELEMENT_NAME2|INPUT_VALUE2|ELEMENT_NAME3|INPUT_VALUE3|ELEMENT_NAME4|INPUT_VALUE4
2204052|2204052-08012016|ADDN|0.23|ASTDSB|28.08|LIFEN|1.73|MEDB|34.04
2127766|2127766-02052000|ADDN|1.52|ADDN|1.9|LIFEN|25.89

Добавление примера кода, который, кажется, работает для моего требования. Пожалуйста, дайте мне знать, если необходимо внести какие-либо исправления.

<xsl:stylesheet version="1.0" xmlns:wd="urn:com.workday.report/ERP-PAY-CR-ELEMENT_ENTRY"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" encoding="UTF-8"/>

    <xsl:template match="/">
        <xsl:text>UNIQUE_IDENTIFIER</xsl:text>
        <xsl:value-of select="'|'"/>
        <xsl:text>ASSIGNMENT_NUMBER</xsl:text>
        <xsl:value-of select="'|'"/>
        <xsl:for-each select="(//node())[4 >= position()]">
            <xsl:variable name="i" select="position()"/>
            <xsl:value-of select="concat('ELEMENT_NAME',$i)"/>
            <xsl:value-of select="'|'"/>
            <xsl:value-of select="concat('INPUT_VALUE',$i)"/>
            <xsl:choose>
                <xsl:when test="position()!=last()">
                    <xsl:value-of select="'|'"/>
                </xsl:when>
                <xsl:when test="position()=last()">
                    <xsl:text>&#10;</xsl:text>
                </xsl:when>

            </xsl:choose>
        </xsl:for-each>
        <xsl:for-each select="wd:Report_Data/wd:Report_Entry">
            <xsl:value-of select="wd:UNIQUE_IDENTIFIER"/>
            <xsl:value-of select="'|'"/>
            <xsl:value-of select="wd:ASSIGNMENT_NUMBER"/>
            <xsl:value-of select="'|'"/>

            <xsl:for-each select="wd:Pay_Input">
                <xsl:value-of select="wd:ELEMENT_NAME"/>
                <xsl:value-of select="'|'"/>
                <xsl:value-of select="wd:INPUT_VALUE"/>
                <xsl:value-of select="'|'"/>
            </xsl:for-each>
            <xsl:text>&#10;</xsl:text>
        </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

Answer 1

Если вы знаете, что максимальное количество элементов wd:Pay_Input равно 4, тогда вы можете создать свой заголовок гораздо проще:

<xsl:text>UNIQUE_IDENTIFIER|ASSIGNMENT_NUMBER|ELEMENT_NAME1|INPUT_VALUE1|ELEMENT_NAME2|INPUT_VALUE2|ELEMENT_NAME3|INPUT_VALUE3|ELEMENT_NAME4|INPUT_VALUE4&#10;</xsl:text>   

---

Если нет, вы можете сделать это динамическим:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:wd="urn:com.workday.report/ERP-PAY-CR-ELEMENT_ENTRY">
<xsl:output method="text"/>

<xsl:template match="wd:Report_Data">
    <!-- header -->
    <xsl:text>UNIQUE_IDENTIFIER|ASSIGNMENT_NUMBER</xsl:text>
    <!-- find the entry with max number of elements -->
    <xsl:for-each select="wd:Report_Entry">
        <xsl:sort select="count(wd:Pay_Input)" data-type="number" order="descending"/>
        <xsl:if test="position()=1">
            <!-- generate header labels -->
            <xsl:for-each select="wd:Pay_Input">
                <xsl:text>|ELEMENT_NAME</xsl:text>  
                <xsl:value-of select="position()"/>
                <xsl:text>|INPUT_VALUE</xsl:text>   
                <xsl:value-of select="position()"/>
            </xsl:for-each>
        </xsl:if>
    </xsl:for-each>
    <xsl:text>&#10;</xsl:text>  
    <!-- data -->
    <xsl:for-each select="wd:Report_Entry">
        <xsl:value-of select="wd:UNIQUE_IDENTIFIER"/>
        <xsl:text>|</xsl:text>  
        <xsl:value-of select="wd:ASSIGNMENT_NUMBER"/>
        <xsl:for-each select="wd:Pay_Input">
            <xsl:text>|</xsl:text>  
            <xsl:value-of select="wd:ELEMENT_NAME"/>
            <xsl:text>|</xsl:text>  
            <xsl:value-of select="wd:INPUT_VALUE"/>
        </xsl:for-each> 
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each> 
</xsl:template>

</xsl:stylesheet>