Можно ли сместить позицию одного xtic / ytic?

Question

Можно ли сместить положение одного xtic / ytic в gnuplot?

В моей ситуации у меня есть (традиционный стиль) ось x / y, и xtic / ytic "0" заканчиваетсяна соответствующей оси. Вместо двух «0» (один для x, один для y) я хотел бы иметь только один «0», который расположен к юго-западу (внизу слева) от источника, чтобы он не мешал оси.

Код, который я использую:

reset
set xrange [-5:5];
set yrange [-5:5];

set size ratio 1
set xzeroaxis
set yzeroaxis
set border 0

set grid x2tics y2tics noxtics noytics
set x2tics 0.5 format "" scale 0
set y2tics 0.5 format "" scale 0
set xtics axis 1 
set ytics axis 1 

set arrow 1 from 0,-5.3 to 0,5.3 lt -1 filled head
set arrow 2 from -5.3,0 to 5.3,0 lt -1 filled head

plot 1/0

Answer 1

А как насчет этого?

Код:

### xtics, ytics only one zero
reset session
set xrange [-5:5]
set yrange [-5:5]

set size ratio 1
set xzeroaxis
set yzeroaxis
set border 0

set grid x2tics y2tics noxtics noytics
set x2tics 0.5 format "" scale 0
set y2tics 0.5 format "" scale 0
set xtics axis 1 
set ytics axis 1 
set xtics add ("" 0)
set ytics add ("" 0)
set label 1 "0" at 0,0 offset -1.5,-0.5

set arrow 1 from 0,-5.3 to 0,5.3 lt -1 filled head
set arrow 2 from -5.3,0 to 5.3,0 lt -1 filled head

plot 1/0
### end of code

Результат: