(Рекурсия-2) Автоинкремент для всех элементов уровня глубины и сохранение наследственности пути - PullRequest
Новая
       26

(Рекурсия-2) Автоинкремент для всех элементов уровня глубины и сохранение наследственности пути

0 голосов
/ 08 апреля 2020

Примечание. Это продолжение двух других вопросов: Ограничение рекурсии одним глубоким l oop и присвоение точного идентификатора всем элементам и Добавление общего атрибута ко всем цепям в рекурсии

Но в постановке задачи вопрос идентичен следующему: (рекурсия) автоинкремент для всех элементов уровня глубины и сохранение пути наследственности в цепочке

Таким образом, формулировка настоящего вопроса остается той же, только в отношении реалий нового XSLT-кода, который отличается.

  • auto -инкрементация для всех элементов уровня глубины и сохранение пути наследственности в цепочке
  • (например) рекурсия глубины 3 уровня, например, она будет выглядеть как "1/1/1" или "1/1/2" - если на третьем уровне есть брат или сестра

1-источник 

<root>
  <object id="a" id-3="COMMON-ID-1"/>
  <object id="b" id-3="COMMON-ID-2"/>
  <object id="c" id-3="COMMON-ID-3"/>

  <object id="aa" parent-id="a" id-3="value"/>
  <object id="bb" parent-id="b" id-3="value"/>
  <object id="cc" parent-id="c" id-3="value"/>


  <object id="aaa" parent-id="aa" id-3="value"/>
  <object id="aaaa" parent-id="aa" id-3="value"/>
  <object id="bbb" parent-id="bb" id-3="value"/>
  <object id="ccc" parent-id="cc" id-3="value"/>
  <object id="bbbb" parent-id="bbb" id-3="value"/>
  <object id="cccc" parent-id="ccc" id-3="value"/>
  <object id="bbbbb" parent-id="bbbb" id-3="value"/>
</root>

2-XSLT 

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:key name="child" match="object" use="@parent-id" />

  <xsl:template match="/root">
    <!-- generate chains -->
    <xsl:variable name="chains">
      <xsl:apply-templates select="object[not(@parent-id)]"/>
    </xsl:variable>
    <!-- find the longest chain -->
    <root>
      <xsl:for-each select="exsl:node-set($chains)/object">
        <xsl:sort select="count(descendant::object)" data-type="number" order="descending"/>
        <xsl:if test="position()">
          <xsl:copy-of select="."/>
        </xsl:if>
      </xsl:for-each>
    </root>
  </xsl:template>

  <xsl:template match="object">
    <xsl:param name="common-id" select="@id-3"/>
    <xsl:copy>
      <xsl:copy-of select="@*"/>
      <xsl:attribute name="COMMON-ID">
        <xsl:value-of select="$common-id"/>
      </xsl:attribute>
    </xsl:copy>
    <xsl:apply-templates select="key('child', @id)">
      <xsl:with-param name="common-id" select="$common-id"/>
    </xsl:apply-templates>
  </xsl:template>

</xsl:stylesheet>

3- вывод 

<?xml version="1.0" encoding="utf-16"?>
<root>
  <object id="a" id-3="COMMON-ID-1" STATUS="0" COMMON-ID="COMMON-ID-1" path="1"/>
  <object id="aa" parent-id="a" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-1" path="1/1"/>
  <object id="aaa" parent-id="aa" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-1" path="1/1/1"/>

  <object id="b" id-3="COMMON-ID-2" COMMON-ID="COMMON-ID-2" path="2"/>
  <object id="bb" parent-id="b" id-3="value" COMMON-ID="COMMON-ID-2" path="2/1"/>
  <object id="bbb" parent-id="bb" id-3="value" COMMON-ID="COMMON-ID-2" path="2/1/1"/>
  <object id="bbbb" parent-id="bbb" id-3="value" COMMON-ID="COMMON-ID-2" path="2/1/1/1"/>
  <object id="bbbbb" parent-id="bbbb" id-3="value" COMMON-ID="COMMON-ID-2" path="2/1/1/1/1"/>

  <object id="c" id-3="COMMON-ID-3" COMMON-ID="COMMON-ID-3" path="3"/>
  <object id="cc" parent-id="c" id-3="value" COMMON-ID="COMMON-ID-3" path="3/1"/>
  <object id="ccc" parent-id="cc" id-3="value" COMMON-ID="COMMON-ID-3" path="3/1/1"/>
  <object id="cccc" parent-id="ccc" id-3="value" COMMON-ID="COMMON-ID-3" path="3/1/1/1"/>
</root>

1 Ответ

1 голос
/ 08 апреля 2020

Я полагаю, что это даст результат, очень близкий к тому, который вы хотите:

XSLT 1.0 

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="child" match="object" use="@parent-id" />

<xsl:template match="/root">
    <root>
        <xsl:apply-templates select="object[not(@parent-id)]"/>
    </root>
</xsl:template>

<xsl:template match="object">
    <xsl:param name="common-id" select="@id-3"/>
    <xsl:param name="path"/>
    <xsl:variable name="new-path" select="concat($path, '/', position())"/>
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:attribute name="COMMON-ID">
            <xsl:value-of select="$common-id"/>
        </xsl:attribute>
        <xsl:attribute name="path">
            <xsl:value-of select="$new-path"/>
        </xsl:attribute>
    </xsl:copy>
    <xsl:apply-templates select="key('child', @id)">
        <xsl:with-param name="common-id" select="$common-id"/>
        <xsl:with-param name="path" select="$new-path"/>
   </xsl:apply-templates>
</xsl:template>

</xsl:stylesheet>

AFAICT, единственное отличие состоит в том, что все пути начинаются с символа /. Если это проблема, вы можете сделать: 

    <xsl:attribute name="path">
        <xsl:value-of select="substring($new-path, 2)"/>
    </xsl:attribute>

.

...