Линии графика с использованием разных стилей без файла данных - PullRequest
Новая
       5

Линии графика с использованием разных стилей без файла данных

0 голосов
/ 06 января 2020

Следующий код создает сюжет. Мой вопрос: как можно создать эти две строки, используя разные стили, не помещая их в файл данных и не используя plot 'plotting_data.dat' index 0 with linespoints linestyle 1, '' index 1 with linespoints linestyle 2

set style line 1 \
    linecolor rgb '#0060ad' \
    linetype 1 linewidth 2 \
    pointtype 7 pointsize 1.5
set style line 2 \
    linecolor rgb '#dd181f' \
    linetype 1 linewidth 2 \
    pointtype 5 pointsize 1.5

# THIS WON'T WORK
# plot '-' index 0 with linespoints linestyle 1, \
#      '-' index 1 with linespoints linestyle 2

# THIS CREATES A PLOT
plot '-' with linespoints linestyle 1
# First data block (index 0)
# X   Y
  1   2
  2   3


# Second index block (index 1)
# X   Y
  3   2
  4   1

Заранее спасибо.

1 Ответ

2 голосов
/ 06 января 2020

Вы не указываете, если вам абсолютно необходимо построить данные через '-'. Если вам нужно два графика с данными через '-', вам нужно предоставить данные дважды. Проверьте help data.

Существует еще один способ «доставки» данных вместе с кодом gnuplot путем определения блоков данных. Чек help datablocks. 

### data in code included
reset session

set style line 1 \
    linecolor rgb '#0060ad' \
    linetype 1 linewidth 2 \
    pointtype 7 pointsize 1.5
set style line 2 \
    linecolor rgb '#dd181f' \
    linetype 1 linewidth 2 \
    pointtype 5 pointsize 1.5

$Data <<EOD
# First data block (index 0)
# X   Y
  1   2
  2   3


# Second index block (index 1)
# X   Y
  3   2
  4   1
EOD

plot $Data index 0 with linespoints linestyle 1, \
     $Data index 1 with linespoints linestyle 2
### end of code
...