Создайте файл Tiff Bitmap из DatagridView - PullRequest
Новая
       18

Создайте файл Tiff Bitmap из DatagridView

3 голосов
/ 07 января 2020

Я хочу создать файл Tiff из Datagridview. Я смог получить Datagridview в файл Tiff, однако мне просто нужны строки и столбцы и ничего больше.

Возможно ли это без использования стороннего инструмента? 

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    DataGridView1.Rows.Add(New String() {"Value1", "Value2", "Value3"})


    Dim height As Integer = DataGridView1.Height
    DataGridView1.Height = DataGridView1.RowCount * DataGridView1.RowTemplate.Height

    Dim bitmap As Bitmap = New Bitmap(Me.DataGridView1.Width - 1, Me.DataGridView1.Height - 1)
    DataGridView1.DrawToBitmap(bitmap, New Rectangle(0, 0, Me.DataGridView1.Width - 1, Me.DataGridView1.Height - 1))

    'Save the Bitmap to folder.
    bitmap.Save("C:Development\DataGridView.Tiff")

End Sub

Я не хочу выделенного

enter image description here

1 Ответ

4 голосов
/ 07 января 2020

Есть несколько вещей, на которые следует обратить внимание:

  1. Строки и столбцы DataGridView должны быть видны, когда элемент управления отображается на растровом изображении,
  2. Полосы прокрутки могут присутствовать,
  3. Высота строк может быть разной, поэтому мы должны суммировать высоту всех строк,
  4. То же самое для столбцов, поскольку каждый столбец имеет свою ширину,
  5. CellFormatting может быть на месте, поэтому нам нужно обновить sh DataGridView перед его рисованием: строки, которые не видны, возможно, еще не отформатированы,
  6. Существует ограничение (32 767) в измерениях Bitmap.

Вызовите этот метод следующим образом, указав, хотите ли вы включить заголовки строки или столбца или исключить оба, передав True / False в качестве ColumnHeaders и RowHeaders arguments.
Аргумент dgv - это, конечно, экземпляр элемента управления DataGridView, который будет отрисован: 

' Prints the DataGridView including the Columns' Headers only
Dim dgvBitmap = DataGridViewToBitmap(DataGridView1, True, False)
Dim imagePath = Path.Combine(AppContext.BaseDirectory, $"{NameOf(DataGridView1)}.tiff")
dgvBitmap.Save(imagePath, ImageFormat.Tiff)

' Dispose of the Bitmap or set it as the PictureBox.Image, dispose of it later.  
dgvBitmap.Dispose()

Private Function DataGridViewToBitmap(dgv As DataGridView, ColumnHeaders As Boolean, RowHeaders As Boolean) As Bitmap
    dgv.ClearSelection()
    Dim originalSize = dgv.Size
    dgv.Height = dgv.Rows.OfType(Of DataGridViewRow).Sum(Function(r) r.Height) + dgv.ColumnHeadersHeight
    dgv.Width = dgv.Columns.OfType(Of DataGridViewColumn).Sum(Function(c) c.Width) + dgv.RowHeadersWidth
    dgv.Refresh()

    Dim dgvPosition = New Point(If(RowHeaders, 0, dgv.RowHeadersWidth), If(ColumnHeaders, 0, dgv.ColumnHeadersHeight))
    Dim dgvSize = New Size(dgv.Width, dgv.Height)
    If dgvSize.Height > 32760 OrElse dgvSize.Width > 32760 Then Return Nothing

    Dim rect As Rectangle = New Rectangle(Point.Empty, dgvSize)
    Using bmp As Bitmap = New Bitmap(dgvSize.Width, dgvSize.Height)
        dgv.DrawToBitmap(bmp, rect)
        If (dgv.Width > originalSize.Width) AndAlso dgv.ScrollBars.HasFlag(ScrollBars.Vertical) Then
            dgvSize.Width -= SystemInformation.VerticalScrollBarWidth
        End If
        If (dgv.Height > originalSize.Height) AndAlso dgv.ScrollBars.HasFlag(ScrollBars.Horizontal) Then
            dgvSize.Height -= SystemInformation.HorizontalScrollBarHeight
        End If
        dgvSize = New Size(dgvSize.Width - dgvPosition.X, dgvSize.Height - dgvPosition.Y)

        dgv.Size = originalSize
        Return bmp.Clone(New Rectangle(dgvPosition, dgvSize), PixelFormat.Format32bppArgb)
    End Using
End Function
...