Мне нужна помощь в преобразовании этого 2D шейдера неба в 3D

Question

Я нашел эту функцию шейдера на github и смог заставить ее работать в GameMaker Studio 2, моем текущем наборе программ. Однако это 2D-эффект, который не учитывает вектор включения камеры или fov. Есть ли в любом случае, что может быть добавлено в это? Я только промежуточный уровень квалификации, когда дело доходит до шейдеров, поэтому я не уверен, какой именно маршрут выбрать, стоит ли его вообще считать стоящим на данный момент, или мне следует начать с другого примера.

uniform vec3 u_sunPosition;
varying vec2 v_vTexcoord;
varying vec4 v_vColour;
varying vec3 v_vPosition;

#define PI 3.141592
#define iSteps 16
#define jSteps 8

vec2 rsi(vec3 r0, vec3 rd, float sr) {
    // ray-sphere intersection that assumes
    // the sphere is centered at the origin.
    // No intersection when result.x > result.y
    float a = dot(rd, rd);
    float b = 2.0 * dot(rd, r0);
    float c = dot(r0, r0) - (sr * sr);
    float d = (b*b) - 4.0*a*c;
    if (d < 0.0) return vec2(1e5,-1e5);
    return vec2(
        (-b - sqrt(d))/(2.0*a),
        (-b + sqrt(d))/(2.0*a)
    );
}

vec3 atmosphere(vec3 r, vec3 r0, vec3 pSun, float iSun, float rPlanet, float rAtmos, vec3 kRlh, float kMie, float shRlh, float shMie, float g) {
    // Normalize the sun and view directions.
    pSun = normalize(pSun);
    r = normalize(r);

    // Calculate the step size of the primary ray.
    vec2 p = rsi(r0, r, rAtmos);
    if (p.x > p.y) return vec3(0,0,0);
    p.y = min(p.y, rsi(r0, r, rPlanet).x);
    float iStepSize = (p.y - p.x) / float(iSteps);

    // Initialize the primary ray time.
    float iTime = 0.0;

    // Initialize accumulators for Rayleigh and Mie scattering.
    vec3 totalRlh = vec3(0,0,0);
    vec3 totalMie = vec3(0,0,0);

    // Initialize optical depth accumulators for the primary ray.
    float iOdRlh = 0.0;
    float iOdMie = 0.0;

    // Calculate the Rayleigh and Mie phases.
    float mu = dot(r, pSun);
    float mumu = mu * mu;
    float gg = g * g;
    float pRlh = 3.0 / (16.0 * PI) * (1.0 + mumu);
    float pp = 1.0 + gg - 2.0 * mu * g;
    float pMie = 3.0 / (8.0 * PI) * ((1.0 - gg) * (mumu + 1.0)) / (sign(pp)*pow(abs(pp), 1.5) * (2.0 + gg));

    // Sample the primary ray.
    for (int i = 0; i < iSteps; i++) {

        // Calculate the primary ray sample position.
        vec3 iPos = r0 + r * (iTime + iStepSize * 0.5);

        // Calculate the height of the sample.
        float iHeight = length(iPos) - rPlanet;

        // Calculate the optical depth of the Rayleigh and Mie scattering for this step.
        float odStepRlh = exp(-iHeight / shRlh) * iStepSize;
        float odStepMie = exp(-iHeight / shMie) * iStepSize;

        // Accumulate optical depth.
        iOdRlh += odStepRlh;
        iOdMie += odStepMie;

        // Calculate the step size of the secondary ray.
        float jStepSize = rsi(iPos, pSun, rAtmos).y / float(jSteps);

        // Initialize the secondary ray time.
        float jTime = 0.0;

        // Initialize optical depth accumulators for the secondary ray.
        float jOdRlh = 0.0;
        float jOdMie = 0.0;

        // Sample the secondary ray.
        for (int j = 0; j < jSteps; j++) {

            // Calculate the secondary ray sample position.
            vec3 jPos = iPos + pSun * (jTime + jStepSize * 0.5);

            // Calculate the height of the sample.
            float jHeight = length(jPos) - rPlanet;

            // Accumulate the optical depth.
            jOdRlh += exp(-jHeight / shRlh) * jStepSize;
            jOdMie += exp(-jHeight / shMie) * jStepSize;

            // Increment the secondary ray time.
            jTime += jStepSize;
        }

        // Calculate attenuation.
        vec3 attn = exp(-(kMie * (iOdMie + jOdMie) + kRlh * (iOdRlh + jOdRlh)));

        // Accumulate scattering.
        totalRlh += odStepRlh * attn;
        totalMie += odStepMie * attn;

        // Increment the primary ray time.
        iTime += iStepSize;

    }

    // Calculate and return the final color.
    return iSun * (pRlh * kRlh * totalRlh + pMie * kMie * totalMie);
}

vec3 ACESFilm( vec3 x )
{
    float tA = 2.51;
    float tB = 0.03;
    float tC = 2.43;
    float tD = 0.59;
    float tE = 0.14;
    return clamp((x*(tA*x+tB))/(x*(tC*x+tD)+tE),0.0,1.0);
}

void main() {
    vec3 color = atmosphere(
        normalize( v_vPosition ),           // normalized ray direction
        vec3(0,6372e3,0),               // ray origin
        u_sunPosition,                        // position of the sun
        22.0,                           // intensity of the sun
        6371e3,                         // radius of the planet in meters
        6471e3,                         // radius of the atmosphere in meters
        vec3(5.5e-6, 13.0e-6, 22.4e-6), // Rayleigh scattering coefficient
        21e-6,                          // Mie scattering coefficient
        8e3,                            // Rayleigh scale height
        1.2e3,                          // Mie scale height
        0.758                           // Mie preferred scattering direction
    );

    // Apply exposure.
    color = ACESFilm( color );

    gl_FragColor = vec4(color, 1.0);
}

Answer 1

Однако это двумерный эффект, который не учитывает вектор включения камеры и fov.

Если вы хотите нарисовать небо в 3D, то вы должны нарисовать на обратной плоскости нормализованного пространства устройства. Нормализованное пространство устройства - это куб с левой, нижней частью рядом с (-1, -1, -1) и правой верхней частью, f ar (1, 1, 1).
Задняя плоскость - это quad with:

bottom left:  -1, -1, 1
bottom right:  1, -1, 1
top right:    -1, -1, 1
top left:     -1, -1, 1

Отобразить этот квад. Обратите внимание, что координаты вершины не должны быть преобразованы какой-либо матрицей, потому что это нормализованные координаты пространства устройства. Но вы должны преобразовать луч, который используется для неба (направление, которое передается в atmosphere).
Этот луч должен быть направлением в мировом пространстве, от положения камеры к небу. По координате вершины квадра можно получить луч в нормированном пространстве устройства. Вы должны превратить этот луч в мировое пространство. Матрица обратной проекции (MATRIX_PROJECTION) преобразуется из нормализованного пространства устройств в пространство просмотра, а матрица обратной проекции (MATRIX_VIEW) преобразует пространство вида в мировое пространство. Используйте следующие матрицы в вершинном шейдере:

attribute vec3 in_Position;
varying   vec3 v_world_ray;

void main()
{
    gl_Position = vec4(inPos, 1.0);

    vec3 proj_ray = vec3(inverse(gm_Matrices[MATRIX_PROJECTION]) * vec4(inPos.xyz, 1.0));
    v_world_ray   = vec3(inverse(gm_Matrices[MATRIX_VIEW]) * vec4(proj_ray.xyz, 0.0));
}

В фрагментном шейдере вы должны повернуть луч на 90 ° вокруг оси x, но это вызвано только тем, как луч интерпретируется функцией atmosphere:

varying vec3 v_world_ray;

// [...]

void main() {

    vec3 world_ray = vec3(v_world_ray.x, v_world_ray.z, -v_world_ray.y);

    vec3 color = atmosphere(
        normalize( world_ray.xyz ),     // normalized ray direction
        vec3(0,6372e3,0),               // ray origin
        u_sunPosition,                  // position of the sun
        22.0,                           // intensity of the sun
        6371e3,                         // radius of the planet in meters
        6471e3,                         // radius of the atmosphere in meters
        vec3(5.5e-6, 13.0e-6, 22.4e-6), // Rayleigh scattering coefficient
        21e-6,                          // Mie scattering coefficient
        8e3,                            // Rayleigh scale height
        1.2e3,                          // Mie scale height
        0.758                           // Mie preferred scattering direction
    );

    // Apply exposure.
    color = ACESFilm( color );

    fragColor = vec4(color.rgb, 1.0);
}