Вот полезный трюк, который использует стиль трехмерного изображения with zerror
, а затем устанавливает угол обзора так, чтобы он выглядел как двухмерный график x / y. Мне не хватает ваших данных, чтобы воспроизвести график, который вы показываете, поэтому я использую файл ненужных данных только для того, чтобы показать, как работает график:
# 3D plot style "with zerror" takes 5 columns of input
# x y z zlow zhigh
# We will choose a view angle such that "z/zlow/zhigh" is the horizontal axis
# "x" is the vertical axis
# "y" is unused because it is along the line of sight
# For your data as described
rho1 = 1 # column 1
rho2 = 2 # column 2
c = 3 # nominal y value, we use it for X
junk = 0 # unused constant coordinate
rhomean(c) = (column(rho1) + column(rho2)) / 2.
set view 270, 0
set view azimuth -90
unset ytics
set zlabel "ρ" # horizontal axis in this projection
set xlabel "C" # vertical axis in this projection
set zrange [0:50] # Note how this affects the horizontal axis!
splot "data" using c:(junk):(rhomean(c)):rho1:rho2 with zerror lt black fc "gold"
Стиль графика with zerror
и команда set view azimuth
требуют разумно текущей версии gnuplot.