Разделите регионы в соответствии с физическими особенностями - PullRequest
Новая
       50

Разделите регионы в соответствии с физическими особенностями

1 голос
/ 11 марта 2020

Я работаю над меньшим проектом и застрял в проблеме, я не совсем уверен, возможно ли ее решить в NetLo go, но я хочу дать StackOverflow go!

У меня есть модель, которая делит мир на разные части и случайным образом добавляет физические особенности (например, реки). Если функция проходит через весь регион, я хочу разделить регион и разделить его на два региона. Например, на рисунке ниже я хочу разделить фиолетовую область на две уникальные области в соответствии с физическим элементом (черный).

1

Код, который я использовал для создания рисунка выше, можно найти ниже. 

to setup
  ca

  ;Setting world.
  resize-world 0 19 0 19

  ;Creating regions. 
  let x 5
  let y 5
  let col 45
  while [y <= max-pycor + 1][
    while [x <= max-pxcor + 1 ][
      ask patches with [pxcor < x and pxcor >= x - 5 and pycor < y and pycor >= y - 5][
        set pcolor col
      ]
      set x x + 5
      set col col + 10
    ]
    set x 5
    set y y + 5
  ]

  ;Generating physical features.    
  ask n-of 5 patches[ sprout 1[
    set pcolor black]
  ]

  let i 0
  while [ i < (max-pycor * 2 )][
    ask turtles [
      fd 1
      set pcolor black
      ifelse (random 20 <= 1)
      [
        rt one-of [-90 0 90]      
        forward 1
      ]
            [
        fd 1
        set pcolor black
        fd 1
        set pcolor black
      ]
      set pcolor black
      set i i + 1]
  ]

  ask turtles [die]
end

1 Ответ

1 голос
/ 11 марта 2020

Моя стратегия для решения этой проблемы заключается в том, чтобы понять, что все, что нам действительно нужно сделать, это «залить» патч цветом и пометить все найденные соседние патчи, а затем повторить для любых немаркированных, не черных патчей, пока они не будут все готово.

NetLo go не имеет команды "флуд", чтобы получить все патчи, смежные с патчем, отвечающим критериям, поэтому мы создаем наш собственный специальный репортер для его обработки, patches-adjacent. Тогда просто попросить этих patches-adjacent установить region для выбранного в данный момент региона.

Мне не нравится этот код, он немного привередливый и будет склонен к бесконечным циклам, если его неправильно настроить. , но это должно работать. Могу поспорить, что есть более чистый способ сделать это, о котором я сейчас не думаю. 

; add a variable to track the different regions
; the default value will be `0` for each patch when `clear-all` is called
patches-own [ region ]

to set-regions 
  let current-region 1
  ; only act on non-black patches that haven't yet been assigned a region
  let untagged patches with [ region = 0 and pcolor != black ]
  while [any? untagged] [
    ask one-of untagged [
      ask patches-adjacent [
        set region current-region 
      ]
    ]
    ; update the region and the untagged patches we have left to process
    set current-region current-region + 1 
    set untagged patches with [ region = 0 and pcolor != black ]
  ]
  ; this is just to get a view of the regions to quickly see if our code worked, it can be removed
  ask patches [ set plabel region ]
end

to-report patches-adjacent
  report patches-adjacent-ex (patch-set self) pcolor
end

to-report patches-adjacent-ex [found pc]
  let newly-found neighbors4 with [ (not member? self found) and pcolor = pc and region = 0 and pcolor != black ]
  set found (patch-set found newly-found)
  ask newly-found [
    ; use recursion to find the patches adjacent to each newly-found one
    ; relying on updating the `found` agentset as we go to avoid duplicates
    ; or looping forwarder
    set found (patches-adjacent-ex found pc) 
  ]
  report found
end
...