Каков наилучший способ создания атрибута класса в Moose? - PullRequest
Новая
       12

Каков наилучший способ создания атрибута класса в Moose?

12 голосов
/ 29 июня 2009

Мне нужен атрибут класса в Moose. Прямо сейчас я говорю: 

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;
use MooseX::Declare;

class User {
    has id      => (isa => "Str", is => 'ro', builder => '_get_id');
    has name    => (isa => "Str", is => 'ro');
    has balance => (isa => "Num", is => 'rw', default => 0);

    #FIXME: this should use a database  
    method _get_id {
        state $id = 0; #I would like this to be a class attribute
        return $id++;
    }
}

my @users;
for my $name (qw/alice bob charlie/) {
    push @users, User->new(name => $name);
};

for my $user (@users) {
    print $user->name, " has an id of ", $user->id, "\n";
}

Ответы [ 2 ]

8 голосов
/ 29 июня 2009

Я нашел MooseX :: ClassAttribute, но выглядит уродливо. Это самый чистый способ? 

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;
use MooseX::Declare;

class User {
    use MooseX::ClassAttribute;

    class_has id_pool => (isa => "Int", is => 'rw', default => 0);

    has id      => (isa => "Str", is => 'ro', builder => '_get_id');
    has name    => (isa => "Str", is => 'ro');
    has balance => (isa => "Num", is => 'rw', default => 0);

    #FIXME: this should use a database  
    method _get_id {
        return __PACKAGE__->id_pool(__PACKAGE__->id_pool+1);
    }
}

my @users;
for my $name (qw/alice bob charlie/) {
    push @users, User->new(name => $name);
};

for my $user (@users) {
    print $user->name, " has an id of ", $user->id, "\n";
}
2 голосов
/ 29 июня 2009

Честно говоря, я не думаю, что все эти проблемы нужны для атрибутов класса. Для атрибутов класса только для чтения я просто использую подпрограмму, которая возвращает константу. Для атрибутов чтения-записи простая переменная состояния в пакете обычно делает свое дело (я еще не сталкивался ни с одним сценарием, где мне нужно что-то более сложное). 

state $count = 0;
method _get_id { 
    return ++$count;
}

При необходимости совместимости до 5.10 можно использовать приватный блок с лексическим значением.

...