Google Sheets Match / Query из нескольких Dynami c выпадающих

Question

У меня есть лист, который мне нужен для запроса данных из другой вкладки, чтобы соответствовать 4, если / или динамические c раскрывающиеся списки и 1, если / и динамические c раскрывающиеся. Это глупо с моей стороны. Я приложил лист, а также 4-минутное видео объяснения. Заранее спасибо!

Лист:

https://docs.google.com/spreadsheets/d/1rUtTJkvFKFI8Q6lnRtxNpky5bYe9u8BZBok0M8hwZ7o/edit?usp=sharing

Видео:

https://www.loom.com/share/392fd41c5c0844d6ad7df308d1af9f6c

Answer 1

попробовать:

=ARRAY_CONSTRAIN(QUERY({'Sub List'!A2:AE, 
 TRANSPOSE(QUERY(TRANSPOSE('Sub List'!L2:U),,999^99)), 
 TRANSPOSE(QUERY(TRANSPOSE('Sub List'!V2:AE),,999^99))},
 "where "&TEXTJOIN(" and ", 1, 
 IF(B1="",,"Col32 contains '"&B1&"'"), 
 IF(B2="",,"Col32 contains '"&B2&"'"), 
 IF(B3="",,"Col32 contains '"&B3&"'"), 
 IF(B4="",,"Col32 contains '"&B4&"'"), 
 IF(B6="",,"Col33 contains '"&B6&"'"))&""), 999^99, 31)

---

для OR logi c использование:

=ARRAY_CONSTRAIN(QUERY({'Sub List'!A2:AE, 
 TRANSPOSE(QUERY(TRANSPOSE('Sub List'!L2:U),,999^99)), 
 TRANSPOSE(QUERY(TRANSPOSE('Sub List'!V2:AE),,999^99))},
 "where "&TEXTJOIN(" or ", 1, 
 IF(B1="",,"Col32 contains '"&B1&"'"), 
 IF(B2="",,"Col32 contains '"&B2&"'"), 
 IF(B3="",,"Col32 contains '"&B3&"'"), 
 IF(B4="",,"Col32 contains '"&B4&"'"), 
 IF(B6="",,"Col33 contains '"&B6&"'"))&""), 999^99, 31)

---

для комбо (OR между желтыми ячейками и AND для зеленой ячейки)

=ARRAY_CONSTRAIN(QUERY({'Sub List'!A2:AE, 
 TRANSPOSE(QUERY(TRANSPOSE('Sub List'!L2:U),,999^99)), 
 TRANSPOSE(QUERY(TRANSPOSE('Sub List'!V2:AE),,999^99))},
 "where ("&TEXTJOIN(" or ", 1, 
 IF(B1="",,"Col32 contains '"&B1&"'"), 
 IF(B2="",,"Col32 contains '"&B2&"'"), 
 IF(B3="",,"Col32 contains '"&B3&"'"), 
 IF(B4="",,"Col32 contains '"&B4&"'"))&")"&
 IF(B6="",," and Col33 contains '"&B6&"'"), 0), 999^99, 31)