Суммирование - выражение Gnuplot

Question

Я пытаюсь использовать выражение суммирования в Gnuplot, но оно не работает должным образом. У меня есть следующая структура данных с большим количеством строк:

t x1 y1 z1 x2 y2 z2 x3 y3 z3 ... x98 y98 z98

Я хотел бы построить следующее уравнение:

u = (sqrt (сумма (x) ** 2 + сумма (y) ** 2 + сумма (z) ** 2)) / 98

98 - это количество точек (x, y, z).

То, что у меня есть до сих пор, - это как построить среднее значение столбцов x1, x2, x3 .. следующим образом:

plot 'data file' u 1:((sum[i=0:ColCount-1] column(i*ColStep+ColStart))/ColCount) w lines ls 4 notitle

Where ColCount = 98, ColStep = 3 and ColStart=2.

Но я пытался построить уравнение, но оно не работает. Я был бы очень признателен за любую помощь.

Answer 1

Что делает следующий скрипт: Он принимает квадрат root от суммы (x1+x2+x3)**2 и (y1+y2+y3)**2 и (z1+z2+z3)**2. Это вы можете адаптировать к вашим номерам столбцов. Но я все еще не уверен, хотите ли вы этого. Пожалуйста, уточните.

Код:

### summing up columns
reset session

$Data <<EOD
#t   x1   y1   z1   x2   y2   z2   x3   y3   z3
 1 1.11 1.21 1.31 2.11 2.21 2.31 3.11 3.21 3.31
 2 1.12 1.22 1.32 2.12 2.22 2.32 3.12 3.22 3.32
 3 1.13 1.23 1.33 2.13 2.23 2.33 3.13 3.23 3.33
 4 1.14 1.24 1.34 2.14 2.24 2.34 3.14 3.24 3.34
 5 1.15 1.25 1.35 2.15 2.25 2.35 3.15 3.25 3.35
 6 1.16 1.26 1.36 2.16 2.26 2.36 3.16 3.26 3.36
 7 1.17 1.27 1.37 2.17 2.27 2.37 3.17 3.27 3.37
 8 1.18 1.28 1.38 2.18 2.28 2.38 3.18 3.28 3.38
 9 1.19 1.29 1.39 2.19 2.29 2.39 3.19 3.29 3.39
EOD

ColStep = 3
ColCount = 3

mySum(ColStart) = sum[i=0:ColCount-1] column(i*ColStep+ColStart)

plot $Data u 1:(sqrt(mySum(2)**2 + mySum(3)**2 + mySum(4)**2)) w lp pt 7 notitle
### end of code

Результат: